configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [0])
  21 m4_define([libguestfs_release], [70])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 gl_EARLY
  41 gl_INIT
  42
  43 AC_PROG_LIBTOOL
  44
  45 dnl Check for basic C environment.
  46 AC_PROG_CC_STDC
  47 AC_PROG_INSTALL
  48 AC_PROG_CPP
  49
  50 AC_ARG_ENABLE([gcc-warnings],
  51   [AS_HELP_STRING([--enable-gcc-warnings],
  52                   [turn on lots of GCC warnings (for developers)])],
  53   [case $enableval in
  54      yes|no) ;;
  55      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  56    esac
  57    gl_gcc_warnings=$enableval],
  58   [gl_gcc_warnings=no]
  59 )
  60
  61 if test "$gl_gcc_warnings" = yes; then
  62   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  63   AC_SUBST([WERROR_CFLAGS])
  64
  65   nw=
  66   # This, $nw, is the list of warnings we disable.
  67   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  68   nw="$nw -Waggregate-return"       # anachronistic
  69   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  70   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  71   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  72   nw="$nw -Wcast-qual"              # Too many warnings for now
  73   nw="$nw -Wconversion"             # Too many warnings for now
  74   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  75   nw="$nw -Wsign-conversion"        # Too many warnings for now
  76   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  77   nw="$nw -Wunreachable-code"       # Too many warnings for now
  78   nw="$nw -Wpadded"                 # Our structs are not padded
  79   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  80   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  81   nw="$nw -Wvla"                    # two warnings in mount.c
  82   # things I might fix soon:
  83   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
  84   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
  85   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
  86   # ?? -Wstrict-overflow
  87   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
  88                                     # was not possible, safe to ignore
  89
  90   gl_MANYWARN_ALL_GCC([ws])
  91   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  92   for w in $ws; do
  93     gl_WARN_ADD([$w])
  94   done
  95   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
  96   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
  97   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
  98
  99   # In spite of excluding -Wlogical-op above, it is enabled, as of
 100   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 101   gl_WARN_ADD([-Wno-logical-op])
 102
 103   gl_WARN_ADD([-fdiagnostics-show-option])
 104
 105   AC_SUBST([WARN_CFLAGS])
 106
 107   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 108   AC_DEFINE([_FORTIFY_SOURCE], [2],
 109     [enable compile-time and run-time bounds-checking, and some warnings])
 110   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 111 fi
 112
 113 AC_C_PROTOTYPES
 114 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 115
 116 AM_PROG_CC_C_O
 117
 118 dnl Check support for 64 bit file offsets.
 119 AC_SYS_LARGEFILE
 120
 121 dnl Check sizeof long.
 122 AC_CHECK_SIZEOF([long])
 123
 124 dnl Headers.
 125 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h])
 126
 127 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 128 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 129 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 130 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 131         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 132         ])
 133
 134 dnl Check for pod2man and pod2text.
 135 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 136 test "x$POD2MAN" = "xno" &&
 137      AC_MSG_ERROR([pod2man must be installed])
 138 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 139 test "x$POD2TEXT" = "xno" &&
 140      AC_MSG_ERROR([pod2text must be installed])
 141
 142 dnl Check for mkisofs.
 143 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 144         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 145 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 146
 147 dnl Check for QEMU for running binaries on this $host_cpu, fall
 148 dnl back to basic 'qemu'.  Allow the user to override it.
 149 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 150 AC_ARG_WITH([qemu],
 151         [AS_HELP_STRING([--with-qemu],
 152           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 153         [],
 154         [with_qemu="$default_qemu"])
 155 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 156         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 157 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 158 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 159
 160 dnl Check that the chosen qemu has vmchannel support.
 161 dnl http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
 162 if test "x$vmchannel_test" != "xno"; then
 163     AC_MSG_CHECKING([for "guestfwd" support in $QEMU])
 164     if $QEMU --help | grep -sq guestfwd; then
 165         AC_MSG_RESULT([yes])
 166     else
 167         AC_MSG_RESULT([no])
 168         AC_MSG_CHECKING([for "-net channel" support in $QEMU])
 169         vmchannelout=`$QEMU -net channel /dev/zero 2>&1 ||:`
 170         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 171         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 172             AC_MSG_RESULT([yes])
 173         else
 174             AC_MSG_RESULT([no])
 175             AC_MSG_FAILURE(
 176 [I did not find vmchannel support in $QEMU.
 177
 178 vmchannel support is vital for libguestfs to operate.  You need a version
 179 of qemu >= 0.10, or the following patch backported to earlier versions:
 180
 181 http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
 182
 183 You can override this test by setting the environment variable
 184 vmchannel_test=no  However if you don't have vmchannel support
 185 in your qemu, then this just delays the pain.
 186
 187 If I am using the wrong qemu or you want to compile qemu from source
 188 and install it in another location, then you should configure with
 189 the --with-qemu option.
 190 ])
 191         fi
 192     fi
 193 fi
 194
 195 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 196 dnl ('-drive ...,if=...' option to qemu).
 197 dnl
 198 dnl NB. We will change the default in future to virtio, but at the
 199 dnl moment this causes a performance problem, RHBZ#509383.
 200 AC_ARG_WITH([drive-if],
 201         [AS_HELP_STRING([--with-drive-if],
 202           [set default driver (ide|scsi|virtio) @<:@default=ide@:>@])],
 203         [],
 204         [with_drive_if=ide])
 205 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 206
 207 dnl Set interface used by the network.  Normally you should
 208 dnl leave this at the default (virtio) but you can use the
 209 dnl alternative (ne2k_pci) because of bugs in virtio networking
 210 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 211 AC_ARG_WITH([net-if],
 212         [AS_HELP_STRING([--with-net-if],
 213           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 214         [],
 215         [with_net_if=virtio])
 216 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 217
 218 dnl Check for febootstrap etc.
 219 AC_CHECK_PROG([FEBOOTSTRAP],
 220         [febootstrap],[febootstrap],[no])
 221 if test "x$FEBOOTSTRAP" != "xno"; then
 222   AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 223         [febootstrap-run],[febootstrap-run],[no])
 224   test "x$FEBOOTSTRAP_RUN" = "xno" && \
 225      AC_MSG_ERROR([febootstrap-run must be installed])
 226   AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 227         [febootstrap-install],[febootstrap-install],[no])
 228   test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 229      AC_MSG_ERROR([febootstrap-install must be installed])
 230   AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 231         [febootstrap-minimize],[febootstrap-minimize],[no])
 232   test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 233      AC_MSG_ERROR([febootstrap-minimize must be installed])
 234   AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 235         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 236   test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 237      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 238
 239   dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 240   dnl of febootstrap, but old versions will fail with yum).
 241   AC_CHECK_PROG([FAKECHROOT],
 242         [fakechroot],[fakechroot],[no])
 243   test "x$FAKECHROOT" = "xno" && \
 244     AC_MSG_ERROR([fakechroot must be installed])
 245
 246   AC_MSG_CHECKING([fakechroot version])
 247   fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 248   if test -z "$fakechroot_version"; then
 249     AC_MSG_RESULT([failed])
 250     AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 251   else
 252     AC_MSG_RESULT([$fakechroot_version])
 253     fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 254     fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 255     if test "$fakechroot_major" -lt 2 -o \
 256             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 257         AC_MSG_ERROR([fakechroot version must be >= 2.9])
 258     fi
 259   fi
 260   DIST="REDHAT"
 261 else
 262   # check for debootstrap and debirf
 263   AC_CHECK_PROG([DEBOOTSTRAP],
 264         [debootstrap],[debootstrap],[no])
 265   test "x$DEBOOTSTRAP" = "xno" && \
 266         AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 267   AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 268   test "x$DEBIRF" = "xno" &&
 269         AC_MSG_ERROR([debirf must be installed])
 270   DIST="DEBIAN"
 271   case "$host_cpu" in
 272       *86)
 273           DEBIAN_KERNEL_ARCH=486
 274           ;;
 275       x86_64)
 276           DEBIAN_KERNEL_ARCH=amd64
 277           ;;
 278       *)
 279          DEBIAN_KERNEL_ARCH=$host_cpu
 280          ;;
 281    esac
 282    AC_SUBST(DEBIAN_KERNEL_ARCH)
 283 fi
 284 AC_SUBST(DIST)
 285
 286
 287 dnl --with-repo to specify a Fedora repository.
 288 AC_ARG_WITH([repo],
 289         [AS_HELP_STRING([--with-repo],
 290           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 291         [],
 292         [with_repo=fedora-11])
 293 REPO="$with_repo"
 294 AC_SUBST(REPO)
 295 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 296
 297 dnl --with-updates to specify a Fedora updates repository.
 298 AC_ARG_WITH([updates],
 299         [AS_HELP_STRING([--with-updates],
 300           [set name of Fedora updates repository @<:@default=updates-released-f11@:>@])],
 301         [],
 302         [with_updates=updates-released-f11])
 303 UPDATES="$with_updates"
 304 AC_SUBST(UPDATES)
 305
 306 dnl Define a symbol for the host CPU architecture.
 307 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 308
 309 dnl --with-mirror to specify a local Fedora mirror.
 310 AC_ARG_WITH([mirror],
 311         [AS_HELP_STRING([--with-mirror],
 312           [set URI of a local Fedora mirror])],
 313         [],
 314         [with_mirror=])
 315 MIRROR="$with_mirror"
 316 AC_SUBST(MIRROR)
 317
 318 dnl Build the supermin appliance?  Please see README file before
 319 dnl enabling this option.
 320 AC_ARG_ENABLE([supermin],
 321         [AS_HELP_STRING([--enable-supermin],
 322           [enable supermin appliance (see README) @<:@default=no@:>@])],
 323         [],
 324         [enable_supermin=no])
 325 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 326
 327 if test "x$enable_supermin" = "xyes"; then
 328     dnl Check febootstrap-to-initramfs accepts the --files option
 329     dnl (febootstrap >= 2.2).
 330     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 331     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 332     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 333     if ! echo "$out" | grep -sq -e --files ; then
 334         AC_MSG_RESULT([no])
 335         AC_MSG_FAILURE(
 336 [febootstrap-to-initramfs does not support the --files option.
 337
 338 To build the supermin appliance, you need to upgrade to the latest
 339 version of febootstrap.
 340 ])
 341     fi
 342     AC_MSG_RESULT([yes])
 343
 344     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 345     dnl (febootstrap >= 2.3).
 346     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 347     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 348     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 349     if ! echo "$out" | grep -sq -e --nocompress ; then
 350         AC_MSG_RESULT([no])
 351         AC_MSG_FAILURE(
 352 [febootstrap-to-initramfs does not support the --nocompress option.
 353
 354 To build the supermin appliance, you need to upgrade to the latest
 355 version of febootstrap.
 356 ])
 357     fi
 358     AC_MSG_RESULT([yes])
 359 fi
 360
 361 dnl Readline.
 362 AC_ARG_WITH([readline],
 363     [AS_HELP_STRING([--with-readline],
 364         [support fancy command line editing @<:@default=check@:>@])],
 365     [],
 366     [with_readline=check])
 367
 368 LIBREADLINE=
 369 AS_IF([test "x$with_readline" != xno],
 370     [AC_CHECK_LIB([readline], [main],
 371         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 372          AC_DEFINE([HAVE_LIBREADLINE], [1],
 373                    [Define if you have libreadline])
 374         ],
 375         [if test "x$with_readline" != xcheck; then
 376          AC_MSG_FAILURE(
 377              [--with-readline was given, but test for readline failed])
 378          fi
 379         ], -lncurses)])
 380
 381 dnl For i18n.
 382 AM_GNU_GETTEXT([external])
 383 AM_GNU_GETTEXT_VERSION([0.17])
 384
 385 dnl Check for OCaml (optional, for OCaml bindings).
 386 AC_PROG_OCAML
 387 AC_PROG_FINDLIB
 388 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 389
 390 dnl Check for Perl (optional, for Perl bindings).
 391 dnl XXX This isn't quite right, we should check for Perl devel library.
 392 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 393
 394 dnl Check for Perl modules that must be present to compile and
 395 dnl test the Perl bindings.
 396 missing_perl_modules=no
 397 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 398     AC_MSG_CHECKING([for $pm])
 399     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 400         AC_MSG_RESULT([no])
 401         missing_perl_modules=yes
 402     else
 403         AC_MSG_RESULT([yes])
 404     fi
 405 done
 406 if test "x$missing_perl_modules" = "xyes"; then
 407     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 408 fi
 409
 410 AM_CONDITIONAL([HAVE_PERL],
 411     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 412
 413 dnl Check for Python (optional, for Python bindings).
 414 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 415
 416 PYTHON_PREFIX=
 417 PYTHON_VERSION=
 418 PYTHON_INCLUDEDIR=
 419 PYTHON_SITE_PACKAGES=
 420
 421 if test "x$PYTHON" != "xno"; then
 422     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 423     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 424     for d in \
 425         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 426         /usr/include/python$PYTHON_VERSION \
 427         /usr/local/include/python$PYTHON_VERSION
 428     do
 429         AC_MSG_CHECKING([Python.h in $d])
 430         if test -r "$d/Python.h"; then
 431             AC_MSG_RESULT([found])
 432             PYTHON_INCLUDEDIR=$d
 433             break
 434         fi
 435         AC_MSG_RESULT([not found])
 436     done
 437     for d in \
 438         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 439         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 440         /usr/lib64/python$PYTHON_VERSION/site-packages \
 441         /usr/lib/python$PYTHON_VERSION/site-packages \
 442         /usr/local/lib/python$PYTHON_VERSION/site-packages
 443     do
 444         AC_MSG_CHECKING([for $d])
 445         if test -d "$d"; then
 446             AC_MSG_RESULT([found])
 447             PYTHON_SITE_PACKAGES=$d
 448             break
 449         fi
 450         AC_MSG_RESULT([not found])
 451     done
 452 fi
 453
 454 AC_SUBST(PYTHON_PREFIX)
 455 AC_SUBST(PYTHON_VERSION)
 456 AC_SUBST(PYTHON_INCLUDEDIR)
 457 AC_SUBST(PYTHON_SITE_PACKAGES)
 458
 459 AM_CONDITIONAL([HAVE_PYTHON],
 460     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 461
 462 dnl Check for Ruby and rake (optional, for Ruby bindings).
 463 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 464 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 465
 466 AM_CONDITIONAL([HAVE_RUBY],
 467     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 468
 469 dnl Check for Java.
 470 AC_ARG_WITH(java_home,
 471     [AS_HELP_STRING([--with-java-home],
 472         [specify path to JDK directory @<:@default=check@:>@])],
 473     [],
 474     [with_java_home=check])
 475
 476 if test "x$with_java_home" != "xno"; then
 477     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 478     then
 479         # Reject unsafe characters in $JAVA_HOME
 480         jh_lf='
 481 '
 482         case $JAVA_HOME in
 483           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 484             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 485         esac
 486         if test -d "$with_java_home"; then
 487             JAVA_HOME="$with_java_home"
 488         else
 489             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 490         fi
 491     fi
 492
 493     if test "x$JAVA_HOME" = "x"; then
 494         # Look for Java in some likely locations.
 495         for d in \
 496             /usr/lib/jvm/java \
 497             /usr/lib/jvm/java-6-openjdk
 498         do
 499             if test -d $d -a -f $d/bin/java; then
 500                 JAVA_HOME=$d
 501                 break
 502             fi
 503         done
 504     fi
 505
 506     if test "x$JAVA_HOME" != "x"; then
 507         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 508         if test ! -x "$JAVA_HOME/bin/java"; then
 509             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 510         else
 511             JAVA="$JAVA_HOME/bin/java"
 512         fi
 513         if test ! -x "$JAVA_HOME/bin/javac"; then
 514             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 515         else
 516             JAVAC="$JAVA_HOME/bin/javac"
 517         fi
 518         if test ! -x "$JAVA_HOME/bin/javah"; then
 519             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 520         else
 521             JAVAH="$JAVA_HOME/bin/javah"
 522         fi
 523         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 524             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 525         else
 526             JAVADOC="$JAVA_HOME/bin/javadoc"
 527         fi
 528         if test ! -x "$JAVA_HOME/bin/jar"; then
 529             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 530         else
 531             JAR="$JAVA_HOME/bin/jar"
 532         fi
 533         java_version=`$JAVA -version 2>&1 | grep "java version"`
 534         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 535
 536         dnl Find jni.h.
 537         AC_MSG_CHECKING([for jni.h])
 538         if test -f "$JAVA_HOME/include/jni.h"; then
 539             JNI_CFLAGS="-I$JAVA_HOME/include"
 540         else
 541             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 542                 head=`find $JAVA_HOME -name jni.h | tail -1`
 543                 dir=`dirname "$head"`
 544                 JNI_CFLAGS="-I$dir"
 545             else
 546                 AC_MSG_FAILURE([missing jni.h header file])
 547             fi
 548         fi
 549         AC_MSG_RESULT([$JNI_CFLAGS])
 550
 551         dnl Find jni_md.h.
 552         AC_MSG_CHECKING([for jni_md.h])
 553         case "$build_os" in
 554         *linux*) system="linux" ;;
 555         *SunOS*) system="solaris" ;;
 556         *cygwin*) system="win32" ;;
 557         *) system="$build_os" ;;
 558         esac
 559         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 560             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 561         else
 562             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 563                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 564                 dir=`dirname "$head"`
 565                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 566             else
 567                 AC_MSG_FAILURE([missing jni_md.h header file])
 568             fi
 569         fi
 570         AC_MSG_RESULT([$JNI_CFLAGS])
 571
 572         dnl Need extra version flag?
 573         AC_MSG_CHECKING([extra javac flags])
 574         JAVAC_FLAGS=
 575         javac_version=`$JAVAC -version 2>&1`
 576         case "$javac_version" in
 577         *Eclipse*)
 578             JAVAC_FLAGS="-source 1.5" ;;
 579         esac
 580         AC_MSG_RESULT([$JAVAC_FLAGS])
 581
 582         dnl Where to install jarfiles.
 583         dnl XXX How to make it configurable?
 584         JAR_INSTALL_DIR=\${prefix}/share/java
 585         JNI_INSTALL_DIR=\${libdir}
 586
 587         dnl JNI version.
 588         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 589         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 590         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 591         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 592     fi
 593 fi
 594
 595 AC_SUBST(JAVA_HOME)
 596 AC_SUBST(JAVA)
 597 AC_SUBST(JAVAC)
 598 AC_SUBST(JAVAH)
 599 AC_SUBST(JAVADOC)
 600 AC_SUBST(JAR)
 601 AC_SUBST(JNI_CFLAGS)
 602 AC_SUBST(JAVAC_FLAGS)
 603 AC_SUBST(JAR_INSTALL_DIR)
 604 AC_SUBST(JNI_INSTALL_DIR)
 605 AC_SUBST(JNI_VERSION_INFO)
 606
 607 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 608
 609 dnl Check for Haskell (GHC).
 610 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 611
 612 AM_CONDITIONAL([HAVE_HASKELL],
 613     [test "x$GHC" != "xno"])
 614
 615 dnl Check for Perl modules needed by virt-df, inspector, etc.
 616 missing_perl_modules=no
 617 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain; do
 618     AC_MSG_CHECKING([for $pm])
 619     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 620         AC_MSG_RESULT([no])
 621         missing_perl_modules=yes
 622     else
 623         AC_MSG_RESULT([yes])
 624     fi
 625 done
 626 if test "x$missing_perl_modules" = "xyes"; then
 627     AC_MSG_WARN([some Perl modules required to compile virt-cat, virt-df and virt-inspector are missing])
 628 fi
 629
 630 AM_CONDITIONAL([HAVE_CAT],
 631     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 632 AM_CONDITIONAL([HAVE_DF],
 633     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 634 AM_CONDITIONAL([HAVE_INSPECTOR],
 635     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 636
 637 dnl Library versioning.
 638 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 639 AC_SUBST(MAX_PROC_NR)
 640
 641 dnl Run in subdirs.
 642 AC_CONFIG_SUBDIRS([daemon])
 643
 644 dnl Produce output files.
 645 AC_CONFIG_HEADERS([config.h])
 646 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 647 AC_CONFIG_FILES([appliance/make.sh],
 648                 [chmod +x appliance/make.sh])
 649 AC_CONFIG_FILES([appliance/update.sh],
 650                 [chmod +x appliance/update.sh])
 651 AC_CONFIG_FILES([appliance/supermin-split.sh],
 652                 [chmod +x appliance/supermin-split.sh])
 653 AC_CONFIG_FILES([appliance/supermin-make.sh],
 654                 [chmod +x appliance/supermin-make.sh])
 655 AC_CONFIG_FILES([appliance/libguestfs-supermin-helper],
 656                 [chmod +x appliance/libguestfs-supermin-helper])
 657 AC_CONFIG_FILES([Makefile
 658                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 659                  appliance/Makefile
 660                  appliance/debian/debirf.conf
 661                  images/Makefile
 662                  capitests/Makefile
 663                  regressions/Makefile
 664                  test-tool/Makefile
 665                  ocaml/Makefile ocaml/examples/Makefile
 666                  perl/Makefile
 667                  python/Makefile
 668                  ruby/Makefile ruby/Rakefile
 669                  java/Makefile
 670                  haskell/Makefile
 671                  cat/Makefile
 672                  df/Makefile
 673                  inspector/Makefile
 674                  libguestfs.pc
 675                  gnulib/lib/Makefile
 676                  gnulib/tests/Makefile
 677                  ocaml/META perl/Makefile.PL])
 678 AC_OUTPUT
 679
 680 dnl Produce summary.
 681 echo
 682 echo
 683 echo "------------------------------------------------------------"
 684 echo "Thank you for downloading $PACKAGE_STRING"
 685 echo
 686 echo "This is how we have configured the optional components for you today:"
 687 echo
 688 echo    "QEMU ................................ $QEMU"
 689 echo -n "OCaml bindings ...................... "
 690 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 691 echo -n "Perl bindings ....................... "
 692 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 693 echo -n "Python bindings ..................... "
 694 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 695 echo -n "Ruby bindings ....................... "
 696 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 697 echo -n "Java bindings ....................... "
 698 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 699 echo -n "Haskell bindings .................... "
 700 if test "x$HAVE_HASKELL" = "x"; then echo "yes"; else echo "no"; fi
 701 echo -n "virt-cat ............................ "
 702 if test "x$HAVE_CAT" = "x"; then echo "yes"; else echo "no"; fi
 703 echo -n "virt-df ............................. "
 704 if test "x$HAVE_DF" = "x"; then echo "yes"; else echo "no"; fi
 705 echo -n "virt-inspector ...................... "
 706 if test "x$HAVE_INSPECTOR" = "x"; then echo "yes"; else echo "no"; fi
 707 echo "supermin appliance .................. $enable_supermin"
 708 echo
 709 echo "If any optional component is configured 'no' when you expected 'yes'"
 710 echo "then you should check the preceeding messages."
 711 echo
 712 echo "Please report bugs back to the mailing list:"
 713 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 714 echo
 715 echo "Next you should type 'make' to build the package,"
 716 echo "then 'make check' to run the tests."
 717 echo "------------------------------------------------------------"