configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [0])
  21 m4_define([libguestfs_release], [71])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 gl_EARLY
  41 gl_INIT
  42
  43 AC_PROG_LIBTOOL
  44
  45 dnl Check for basic C environment.
  46 AC_PROG_CC_STDC
  47 AC_PROG_INSTALL
  48 AC_PROG_CPP
  49
  50 AC_ARG_ENABLE([gcc-warnings],
  51   [AS_HELP_STRING([--enable-gcc-warnings],
  52                   [turn on lots of GCC warnings (for developers)])],
  53   [case $enableval in
  54      yes|no) ;;
  55      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  56    esac
  57    gl_gcc_warnings=$enableval],
  58   [gl_gcc_warnings=no]
  59 )
  60
  61 if test "$gl_gcc_warnings" = yes; then
  62   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  63   AC_SUBST([WERROR_CFLAGS])
  64
  65   nw=
  66   # This, $nw, is the list of warnings we disable.
  67   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  68   nw="$nw -Waggregate-return"       # anachronistic
  69   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  70   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  71   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  72   nw="$nw -Wcast-qual"              # Too many warnings for now
  73   nw="$nw -Wconversion"             # Too many warnings for now
  74   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  75   nw="$nw -Wsign-conversion"        # Too many warnings for now
  76   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  77   nw="$nw -Wunreachable-code"       # Too many warnings for now
  78   nw="$nw -Wpadded"                 # Our structs are not padded
  79   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  80   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  81   nw="$nw -Wvla"                    # two warnings in mount.c
  82   # things I might fix soon:
  83   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
  84   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
  85   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
  86   # ?? -Wstrict-overflow
  87   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
  88                                     # was not possible, safe to ignore
  89
  90   gl_MANYWARN_ALL_GCC([ws])
  91   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  92   for w in $ws; do
  93     gl_WARN_ADD([$w])
  94   done
  95   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
  96   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
  97   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
  98
  99   # In spite of excluding -Wlogical-op above, it is enabled, as of
 100   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 101   gl_WARN_ADD([-Wno-logical-op])
 102
 103   gl_WARN_ADD([-fdiagnostics-show-option])
 104
 105   AC_SUBST([WARN_CFLAGS])
 106
 107   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 108   AC_DEFINE([_FORTIFY_SOURCE], [2],
 109     [enable compile-time and run-time bounds-checking, and some warnings])
 110   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 111 fi
 112
 113 AC_C_PROTOTYPES
 114 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 115
 116 AM_PROG_CC_C_O
 117
 118 dnl Check support for 64 bit file offsets.
 119 AC_SYS_LARGEFILE
 120
 121 dnl Check sizeof long.
 122 AC_CHECK_SIZEOF([long])
 123
 124 dnl Headers.
 125 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h])
 126
 127 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 128 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 129 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 130 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 131         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 132         ])
 133
 134 dnl Check for pod2man and pod2text.
 135 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 136 test "x$POD2MAN" = "xno" &&
 137      AC_MSG_ERROR([pod2man must be installed])
 138 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 139 test "x$POD2TEXT" = "xno" &&
 140      AC_MSG_ERROR([pod2text must be installed])
 141
 142 dnl Check for mkisofs.
 143 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 144         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 145 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 146
 147 dnl Check for QEMU for running binaries on this $host_cpu, fall
 148 dnl back to basic 'qemu'.  Allow the user to override it.
 149 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 150 AC_ARG_WITH([qemu],
 151         [AS_HELP_STRING([--with-qemu],
 152           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 153         [],
 154         [with_qemu="$default_qemu"])
 155 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 156         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 157 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 158 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 159
 160 dnl Check that the chosen qemu has vmchannel support or we can
 161 dnl fallback to null vmchannel (still using SLIRP).  See the
 162 dnl discussion in the README file.
 163 if test "x$vmchannel_test" != "xno"; then
 164     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 165     if $QEMU --help | grep -sq guestfwd; then
 166         AC_MSG_RESULT([yes])
 167         vmchannel_guestfwd=guestfwd
 168     else
 169         AC_MSG_RESULT([no])
 170         # Note that this test must be conditional on the previous
 171         # test failing.  This is because recent qemu will throw
 172         # up an SDL window and hang if we try to run this test.
 173         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 174         vmchannelout=`$QEMU -net channel /dev/zero 2>&1 ||:`
 175         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 176         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 177             AC_MSG_RESULT([yes])
 178             vmchannel_guestfwd=net_channel
 179         else
 180             AC_MSG_RESULT([no])
 181             vmchannel_guestfwd=no
 182         fi
 183     fi
 184
 185     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 186     if $QEMU --help | grep -sq -- "-net user"; then
 187         AC_MSG_RESULT([yes])
 188         vmchannel_net_user=yes
 189     else
 190         AC_MSG_RESULT([no])
 191         vmchannel_net_user=no
 192     fi
 193
 194     if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
 195         AC_MSG_FAILURE(
 196 [I did not find user mode network or vmchannel support in
 197 $QEMU.
 198
 199 Either user mode networking or vmchannel support is vital for
 200 libguestfs to operate.
 201
 202 Please read the relevant section in the README file for more
 203 information about this.
 204
 205 You can override this test by setting the environment variable
 206 vmchannel_test=no  However if you don't have the right support
 207 in your qemu, then this just delays the pain.
 208
 209 If I am using the wrong qemu or you want to compile qemu from source
 210 and install it in another location, then you should configure with
 211 the --with-qemu option.
 212 ])
 213     fi
 214 fi
 215
 216 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 217 dnl ('-drive ...,if=...' option to qemu).
 218 dnl
 219 dnl NB. We will change the default in future to virtio, but at the
 220 dnl moment this causes a performance problem, RHBZ#509383.
 221 AC_ARG_WITH([drive-if],
 222         [AS_HELP_STRING([--with-drive-if],
 223           [set default driver (ide|scsi|virtio) @<:@default=ide@:>@])],
 224         [],
 225         [with_drive_if=ide])
 226 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 227
 228 dnl Set interface used by the network.  Normally you should
 229 dnl leave this at the default (virtio) but you can use the
 230 dnl alternative (ne2k_pci) because of bugs in virtio networking
 231 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 232 AC_ARG_WITH([net-if],
 233         [AS_HELP_STRING([--with-net-if],
 234           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 235         [],
 236         [with_net_if=virtio])
 237 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 238
 239 dnl Check for febootstrap etc.
 240 AC_CHECK_PROG([FEBOOTSTRAP],
 241         [febootstrap],[febootstrap],[no])
 242 if test "x$FEBOOTSTRAP" != "xno"; then
 243   AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 244         [febootstrap-run],[febootstrap-run],[no])
 245   test "x$FEBOOTSTRAP_RUN" = "xno" && \
 246      AC_MSG_ERROR([febootstrap-run must be installed])
 247   AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 248         [febootstrap-install],[febootstrap-install],[no])
 249   test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 250      AC_MSG_ERROR([febootstrap-install must be installed])
 251   AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 252         [febootstrap-minimize],[febootstrap-minimize],[no])
 253   test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 254      AC_MSG_ERROR([febootstrap-minimize must be installed])
 255   AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 256         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 257   test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 258      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 259
 260   dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 261   dnl of febootstrap, but old versions will fail with yum).
 262   AC_CHECK_PROG([FAKECHROOT],
 263         [fakechroot],[fakechroot],[no])
 264   test "x$FAKECHROOT" = "xno" && \
 265     AC_MSG_ERROR([fakechroot must be installed])
 266
 267   AC_MSG_CHECKING([fakechroot version])
 268   fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 269   if test -z "$fakechroot_version"; then
 270     AC_MSG_RESULT([failed])
 271     AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 272   else
 273     AC_MSG_RESULT([$fakechroot_version])
 274     fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 275     fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 276     if test "$fakechroot_major" -lt 2 -o \
 277             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 278         AC_MSG_ERROR([fakechroot version must be >= 2.9])
 279     fi
 280   fi
 281   DIST="REDHAT"
 282 else
 283   # check for debootstrap and debirf
 284   AC_CHECK_PROG([DEBOOTSTRAP],
 285         [debootstrap],[debootstrap],[no])
 286   test "x$DEBOOTSTRAP" = "xno" && \
 287         AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 288   AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 289   test "x$DEBIRF" = "xno" &&
 290         AC_MSG_ERROR([debirf must be installed])
 291   DIST="DEBIAN"
 292   case "$host_cpu" in
 293       *86)
 294           DEBIAN_KERNEL_ARCH=486
 295           ;;
 296       x86_64)
 297           DEBIAN_KERNEL_ARCH=amd64
 298           ;;
 299       *)
 300          DEBIAN_KERNEL_ARCH=$host_cpu
 301          ;;
 302    esac
 303    AC_SUBST(DEBIAN_KERNEL_ARCH)
 304 fi
 305 AC_SUBST(DIST)
 306
 307
 308 dnl --with-repo to specify a Fedora repository.
 309 AC_ARG_WITH([repo],
 310         [AS_HELP_STRING([--with-repo],
 311           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 312         [],
 313         [with_repo=fedora-11])
 314 REPO="$with_repo"
 315 AC_SUBST(REPO)
 316 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 317
 318 dnl --with-updates to specify a Fedora updates repository.
 319 AC_ARG_WITH([updates],
 320         [AS_HELP_STRING([--with-updates],
 321           [set name of Fedora updates repository @<:@default=updates-released-f11@:>@])],
 322         [],
 323         [with_updates=updates-released-f11])
 324 UPDATES="$with_updates"
 325 AC_SUBST(UPDATES)
 326
 327 dnl Define a symbol for the host CPU architecture.
 328 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 329
 330 dnl --with-mirror to specify a local Fedora mirror.
 331 AC_ARG_WITH([mirror],
 332         [AS_HELP_STRING([--with-mirror],
 333           [set URI of a local Fedora mirror])],
 334         [],
 335         [with_mirror=])
 336 MIRROR="$with_mirror"
 337 AC_SUBST(MIRROR)
 338
 339 dnl Build the supermin appliance?  Please see README file before
 340 dnl enabling this option.
 341 AC_ARG_ENABLE([supermin],
 342         [AS_HELP_STRING([--enable-supermin],
 343           [enable supermin appliance (see README) @<:@default=no@:>@])],
 344         [],
 345         [enable_supermin=no])
 346 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 347
 348 if test "x$enable_supermin" = "xyes"; then
 349     dnl Check febootstrap-to-initramfs accepts the --files option
 350     dnl (febootstrap >= 2.2).
 351     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 352     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 353     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 354     if ! echo "$out" | grep -sq -e --files ; then
 355         AC_MSG_RESULT([no])
 356         AC_MSG_FAILURE(
 357 [febootstrap-to-initramfs does not support the --files option.
 358
 359 To build the supermin appliance, you need to upgrade to the latest
 360 version of febootstrap.
 361 ])
 362     fi
 363     AC_MSG_RESULT([yes])
 364
 365     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 366     dnl (febootstrap >= 2.3).
 367     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 368     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 369     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 370     if ! echo "$out" | grep -sq -e --nocompress ; then
 371         AC_MSG_RESULT([no])
 372         AC_MSG_FAILURE(
 373 [febootstrap-to-initramfs does not support the --nocompress option.
 374
 375 To build the supermin appliance, you need to upgrade to the latest
 376 version of febootstrap.
 377 ])
 378     fi
 379     AC_MSG_RESULT([yes])
 380 fi
 381
 382 dnl Enable packet dumps when in verbose mode.  This generates lots
 383 dnl of debug info, only useful for people debugging the RPC mechanism.
 384 AC_ARG_ENABLE([packet-dump],
 385         [AS_HELP_STRING([--enable-packet-dump],
 386           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 387         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 388         [])
 389
 390 dnl Readline.
 391 AC_ARG_WITH([readline],
 392     [AS_HELP_STRING([--with-readline],
 393         [support fancy command line editing @<:@default=check@:>@])],
 394     [],
 395     [with_readline=check])
 396
 397 LIBREADLINE=
 398 AS_IF([test "x$with_readline" != xno],
 399     [AC_CHECK_LIB([readline], [main],
 400         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 401          AC_DEFINE([HAVE_LIBREADLINE], [1],
 402                    [Define if you have libreadline])
 403         ],
 404         [if test "x$with_readline" != xcheck; then
 405          AC_MSG_FAILURE(
 406              [--with-readline was given, but test for readline failed])
 407          fi
 408         ], -lncurses)])
 409
 410 dnl For i18n.
 411 AM_GNU_GETTEXT([external])
 412 AM_GNU_GETTEXT_VERSION([0.17])
 413
 414 dnl Check for OCaml (optional, for OCaml bindings).
 415 AC_PROG_OCAML
 416 AC_PROG_FINDLIB
 417 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 418
 419 dnl Check for Perl (optional, for Perl bindings).
 420 dnl XXX This isn't quite right, we should check for Perl devel library.
 421 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 422
 423 dnl Check for Perl modules that must be present to compile and
 424 dnl test the Perl bindings.
 425 missing_perl_modules=no
 426 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 427     AC_MSG_CHECKING([for $pm])
 428     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 429         AC_MSG_RESULT([no])
 430         missing_perl_modules=yes
 431     else
 432         AC_MSG_RESULT([yes])
 433     fi
 434 done
 435 if test "x$missing_perl_modules" = "xyes"; then
 436     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 437 fi
 438
 439 AM_CONDITIONAL([HAVE_PERL],
 440     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 441
 442 dnl Check for Python (optional, for Python bindings).
 443 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 444
 445 PYTHON_PREFIX=
 446 PYTHON_VERSION=
 447 PYTHON_INCLUDEDIR=
 448 PYTHON_SITE_PACKAGES=
 449
 450 if test "x$PYTHON" != "xno"; then
 451     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 452     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 453     for d in \
 454         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 455         /usr/include/python$PYTHON_VERSION \
 456         /usr/local/include/python$PYTHON_VERSION
 457     do
 458         AC_MSG_CHECKING([Python.h in $d])
 459         if test -r "$d/Python.h"; then
 460             AC_MSG_RESULT([found])
 461             PYTHON_INCLUDEDIR=$d
 462             break
 463         fi
 464         AC_MSG_RESULT([not found])
 465     done
 466     for d in \
 467         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 468         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 469         /usr/lib64/python$PYTHON_VERSION/site-packages \
 470         /usr/lib/python$PYTHON_VERSION/site-packages \
 471         /usr/local/lib/python$PYTHON_VERSION/site-packages
 472     do
 473         AC_MSG_CHECKING([for $d])
 474         if test -d "$d"; then
 475             AC_MSG_RESULT([found])
 476             PYTHON_SITE_PACKAGES=$d
 477             break
 478         fi
 479         AC_MSG_RESULT([not found])
 480     done
 481 fi
 482
 483 AC_SUBST(PYTHON_PREFIX)
 484 AC_SUBST(PYTHON_VERSION)
 485 AC_SUBST(PYTHON_INCLUDEDIR)
 486 AC_SUBST(PYTHON_SITE_PACKAGES)
 487
 488 AM_CONDITIONAL([HAVE_PYTHON],
 489     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 490
 491 dnl Check for Ruby and rake (optional, for Ruby bindings).
 492 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 493 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 494
 495 AM_CONDITIONAL([HAVE_RUBY],
 496     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 497
 498 dnl Check for Java.
 499 AC_ARG_WITH(java_home,
 500     [AS_HELP_STRING([--with-java-home],
 501         [specify path to JDK directory @<:@default=check@:>@])],
 502     [],
 503     [with_java_home=check])
 504
 505 if test "x$with_java_home" != "xno"; then
 506     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 507     then
 508         # Reject unsafe characters in $JAVA_HOME
 509         jh_lf='
 510 '
 511         case $JAVA_HOME in
 512           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 513             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 514         esac
 515         if test -d "$with_java_home"; then
 516             JAVA_HOME="$with_java_home"
 517         else
 518             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 519         fi
 520     fi
 521
 522     if test "x$JAVA_HOME" = "x"; then
 523         # Look for Java in some likely locations.
 524         for d in \
 525             /usr/lib/jvm/java \
 526             /usr/lib/jvm/java-6-openjdk
 527         do
 528             if test -d $d -a -f $d/bin/java; then
 529                 JAVA_HOME=$d
 530                 break
 531             fi
 532         done
 533     fi
 534
 535     if test "x$JAVA_HOME" != "x"; then
 536         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 537         if test ! -x "$JAVA_HOME/bin/java"; then
 538             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 539         else
 540             JAVA="$JAVA_HOME/bin/java"
 541         fi
 542         if test ! -x "$JAVA_HOME/bin/javac"; then
 543             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 544         else
 545             JAVAC="$JAVA_HOME/bin/javac"
 546         fi
 547         if test ! -x "$JAVA_HOME/bin/javah"; then
 548             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 549         else
 550             JAVAH="$JAVA_HOME/bin/javah"
 551         fi
 552         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 553             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 554         else
 555             JAVADOC="$JAVA_HOME/bin/javadoc"
 556         fi
 557         if test ! -x "$JAVA_HOME/bin/jar"; then
 558             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 559         else
 560             JAR="$JAVA_HOME/bin/jar"
 561         fi
 562         java_version=`$JAVA -version 2>&1 | grep "java version"`
 563         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 564
 565         dnl Find jni.h.
 566         AC_MSG_CHECKING([for jni.h])
 567         if test -f "$JAVA_HOME/include/jni.h"; then
 568             JNI_CFLAGS="-I$JAVA_HOME/include"
 569         else
 570             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 571                 head=`find $JAVA_HOME -name jni.h | tail -1`
 572                 dir=`dirname "$head"`
 573                 JNI_CFLAGS="-I$dir"
 574             else
 575                 AC_MSG_FAILURE([missing jni.h header file])
 576             fi
 577         fi
 578         AC_MSG_RESULT([$JNI_CFLAGS])
 579
 580         dnl Find jni_md.h.
 581         AC_MSG_CHECKING([for jni_md.h])
 582         case "$build_os" in
 583         *linux*) system="linux" ;;
 584         *SunOS*) system="solaris" ;;
 585         *cygwin*) system="win32" ;;
 586         *) system="$build_os" ;;
 587         esac
 588         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 589             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 590         else
 591             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 592                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 593                 dir=`dirname "$head"`
 594                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 595             else
 596                 AC_MSG_FAILURE([missing jni_md.h header file])
 597             fi
 598         fi
 599         AC_MSG_RESULT([$JNI_CFLAGS])
 600
 601         dnl Need extra version flag?
 602         AC_MSG_CHECKING([extra javac flags])
 603         JAVAC_FLAGS=
 604         javac_version=`$JAVAC -version 2>&1`
 605         case "$javac_version" in
 606         *Eclipse*)
 607             JAVAC_FLAGS="-source 1.5" ;;
 608         esac
 609         AC_MSG_RESULT([$JAVAC_FLAGS])
 610
 611         dnl Where to install jarfiles.
 612         dnl XXX How to make it configurable?
 613         JAR_INSTALL_DIR=\${prefix}/share/java
 614         JNI_INSTALL_DIR=\${libdir}
 615
 616         dnl JNI version.
 617         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 618         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 619         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 620         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 621     fi
 622 fi
 623
 624 AC_SUBST(JAVA_HOME)
 625 AC_SUBST(JAVA)
 626 AC_SUBST(JAVAC)
 627 AC_SUBST(JAVAH)
 628 AC_SUBST(JAVADOC)
 629 AC_SUBST(JAR)
 630 AC_SUBST(JNI_CFLAGS)
 631 AC_SUBST(JAVAC_FLAGS)
 632 AC_SUBST(JAR_INSTALL_DIR)
 633 AC_SUBST(JNI_INSTALL_DIR)
 634 AC_SUBST(JNI_VERSION_INFO)
 635
 636 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 637
 638 dnl Check for Haskell (GHC).
 639 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 640
 641 AM_CONDITIONAL([HAVE_HASKELL],
 642     [test "x$GHC" != "xno"])
 643
 644 dnl Check for Perl modules needed by virt-df, inspector, etc.
 645 missing_perl_modules=no
 646 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain; do
 647     AC_MSG_CHECKING([for $pm])
 648     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 649         AC_MSG_RESULT([no])
 650         missing_perl_modules=yes
 651     else
 652         AC_MSG_RESULT([yes])
 653     fi
 654 done
 655 if test "x$missing_perl_modules" = "xyes"; then
 656     AC_MSG_WARN([some Perl modules required to compile virt-cat, virt-df, virt-inspector and virt-rescue are missing])
 657 fi
 658
 659 AM_CONDITIONAL([HAVE_CAT],
 660     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 661 AM_CONDITIONAL([HAVE_DF],
 662     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 663 AM_CONDITIONAL([HAVE_INSPECTOR],
 664     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 665 AM_CONDITIONAL([HAVE_RESCUE],
 666     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 667
 668 dnl Library versioning.
 669 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 670 AC_SUBST(MAX_PROC_NR)
 671
 672 dnl Run in subdirs.
 673 AC_CONFIG_SUBDIRS([daemon])
 674
 675 dnl Produce output files.
 676 AC_CONFIG_HEADERS([config.h])
 677 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 678 AC_CONFIG_FILES([appliance/make.sh],
 679                 [chmod +x appliance/make.sh])
 680 AC_CONFIG_FILES([appliance/update.sh],
 681                 [chmod +x appliance/update.sh])
 682 AC_CONFIG_FILES([appliance/supermin-split.sh],
 683                 [chmod +x appliance/supermin-split.sh])
 684 AC_CONFIG_FILES([appliance/supermin-make.sh],
 685                 [chmod +x appliance/supermin-make.sh])
 686 AC_CONFIG_FILES([appliance/libguestfs-supermin-helper],
 687                 [chmod +x appliance/libguestfs-supermin-helper])
 688 AC_CONFIG_FILES([Makefile
 689                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 690                  appliance/Makefile
 691                  appliance/debian/debirf.conf
 692                  images/Makefile
 693                  capitests/Makefile
 694                  regressions/Makefile
 695                  test-tool/Makefile
 696                  ocaml/Makefile ocaml/examples/Makefile
 697                  perl/Makefile
 698                  python/Makefile
 699                  ruby/Makefile ruby/Rakefile
 700                  java/Makefile
 701                  haskell/Makefile
 702                  cat/Makefile
 703                  df/Makefile
 704                  inspector/Makefile
 705                  rescue/Makefile
 706                  libguestfs.pc
 707                  gnulib/lib/Makefile
 708                  gnulib/tests/Makefile
 709                  ocaml/META perl/Makefile.PL])
 710 AC_OUTPUT
 711
 712 dnl Produce summary.
 713 echo
 714 echo
 715 echo "------------------------------------------------------------"
 716 echo "Thank you for downloading $PACKAGE_STRING"
 717 echo
 718 echo "This is how we have configured the optional components for you today:"
 719 echo
 720 echo    "QEMU ................................ $QEMU"
 721 echo -n "OCaml bindings ...................... "
 722 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 723 echo -n "Perl bindings ....................... "
 724 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 725 echo -n "Python bindings ..................... "
 726 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 727 echo -n "Ruby bindings ....................... "
 728 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 729 echo -n "Java bindings ....................... "
 730 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 731 echo -n "Haskell bindings .................... "
 732 if test "x$HAVE_HASKELL" = "x"; then echo "yes"; else echo "no"; fi
 733 echo -n "virt-cat ............................ "
 734 if test "x$HAVE_CAT" = "x"; then echo "yes"; else echo "no"; fi
 735 echo -n "virt-df ............................. "
 736 if test "x$HAVE_DF" = "x"; then echo "yes"; else echo "no"; fi
 737 echo -n "virt-inspector ...................... "
 738 if test "x$HAVE_INSPECTOR" = "x"; then echo "yes"; else echo "no"; fi
 739 echo -n "virt-rescue ......................... "
 740 if test "x$HAVE_RESCUE" = "x"; then echo "yes"; else echo "no"; fi
 741 echo "supermin appliance .................. $enable_supermin"
 742 echo
 743 echo "If any optional component is configured 'no' when you expected 'yes'"
 744 echo "then you should check the preceeding messages."
 745 echo
 746 echo "Please report bugs back to the mailing list:"
 747 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 748 echo
 749 echo "Next you should type 'make' to build the package,"
 750 echo "then 'make check' to run the tests."
 751 echo "------------------------------------------------------------"