configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [5])
  21 m4_define([libguestfs_release], [0])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Die if the user tries to configure as root, see:
  57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  58 AC_MSG_CHECKING([if you are trying to configure as root])
  59 AS_IF([test "`id -u`" = 0 ],[
  60             AC_MSG_RESULT([yes])
  61             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  62       ],[
  63             AC_MSG_RESULT([no])
  64       ])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 114                                     # was not possible, safe to ignore
 115   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 116   nw="$nw -Wlong-long"              # Allow long long since it's required
 117                                     # by Python, Ruby and xstrtoll.
 118
 119   gl_MANYWARN_ALL_GCC([ws])
 120   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 121   for w in $ws; do
 122     gl_WARN_ADD([$w])
 123   done
 124   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 125   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 126   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 127
 128   # In spite of excluding -Wlogical-op above, it is enabled, as of
 129   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 130   gl_WARN_ADD([-Wno-logical-op])
 131
 132   gl_WARN_ADD([-fdiagnostics-show-option])
 133
 134   AC_SUBST([WARN_CFLAGS])
 135
 136   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 137   AC_DEFINE([_FORTIFY_SOURCE], [2],
 138     [enable compile-time and run-time bounds-checking, and some warnings])
 139   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 140 fi
 141
 142 AC_C_PROTOTYPES
 143 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 144
 145 AM_PROG_CC_C_O
 146
 147 dnl Work out how to specify the linker script to the linker.
 148 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 149 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 150     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 151 AC_SUBST(VERSION_SCRIPT_FLAGS)
 152
 153 dnl Check support for 64 bit file offsets.
 154 AC_SYS_LARGEFILE
 155
 156 dnl Check sizeof long.
 157 AC_CHECK_SIZEOF([long])
 158
 159 dnl Define a C symbol for the host CPU architecture.
 160 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 161
 162 dnl Headers.
 163 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 164
 165 dnl Functions.
 166 AC_CHECK_FUNCS([posix_fallocate])
 167
 168 dnl Build the daemon?
 169 AC_MSG_CHECKING([if we should build the daemon])
 170 AC_ARG_ENABLE([daemon],
 171         [AS_HELP_STRING([--enable-daemon],
 172           [enable building the daemon @<:@default=yes@:>@])],
 173         [],
 174         [enable_daemon=yes])
 175 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 176 AC_MSG_RESULT([$enable_daemon])
 177
 178 dnl Build the appliance?
 179 AC_MSG_CHECKING([if we should build the appliance])
 180 AC_ARG_ENABLE([appliance],
 181         [AS_HELP_STRING([--enable-appliance],
 182           [enable building the appliance @<:@default=yes@:>@])],
 183         [],
 184         [enable_appliance=yes])
 185 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 186 AC_MSG_RESULT([$enable_appliance])
 187
 188 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 189 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 190 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 191 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 192         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 193         ])
 194
 195 dnl Check for pod2man and pod2text.
 196 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 197 test "x$POD2MAN" = "xno" &&
 198      AC_MSG_ERROR([pod2man must be installed])
 199 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 200 test "x$POD2TEXT" = "xno" &&
 201      AC_MSG_ERROR([pod2text must be installed])
 202
 203 dnl Check for mkisofs.
 204 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 205         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 206 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 207
 208 dnl Check for optional xmllint.
 209 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 210 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 211
 212 dnl Check for QEMU for running binaries on this $host_cpu, fall
 213 dnl back to basic 'qemu'.  Allow the user to override it.
 214 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 215 AC_ARG_WITH([qemu],
 216         [AS_HELP_STRING([--with-qemu],
 217           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 218         [],
 219         [with_qemu="$default_qemu"])
 220 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 221         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 222 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 223 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 224
 225 dnl Check that the chosen qemu has vmchannel support or we can
 226 dnl fallback to null vmchannel (still using SLIRP).  See the
 227 dnl discussion in the README file.
 228 if test "x$vmchannel_test" != "xno"; then
 229     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 230     if $QEMU -nographic --help | grep -sq guestfwd; then
 231         AC_MSG_RESULT([yes])
 232         vmchannel_guestfwd=guestfwd
 233     else
 234         AC_MSG_RESULT([no])
 235         # Note that this test must be conditional on the previous
 236         # test failing.  This is because recent qemu will throw
 237         # up an SDL window and hang if we try to run this test.
 238         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 239         vmchannelout=`$QEMU -nographic -net channel /dev/zero 2>&1 ||:`
 240         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 241         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 242             AC_MSG_RESULT([yes])
 243             vmchannel_guestfwd=net_channel
 244         else
 245             AC_MSG_RESULT([no])
 246             vmchannel_guestfwd=no
 247         fi
 248     fi
 249
 250     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 251     if $QEMU -nographic --help | grep -sq -- "-net user"; then
 252         AC_MSG_RESULT([yes])
 253         vmchannel_net_user=yes
 254     else
 255         AC_MSG_RESULT([no])
 256         vmchannel_net_user=no
 257     fi
 258
 259     if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
 260         AC_MSG_FAILURE(
 261 [I did not find user mode network or vmchannel support in
 262 $QEMU.
 263
 264 Either user mode networking or vmchannel support is vital for
 265 libguestfs to operate.
 266
 267 Please read the relevant section in the README file for more
 268 information about this.
 269
 270 You can override this test by setting the environment variable
 271 vmchannel_test=no  However if you don't have the right support
 272 in your qemu, then this just delays the pain.
 273
 274 If I am using the wrong qemu or you want to compile qemu from source
 275 and install it in another location, then you should configure with
 276 the --with-qemu option.
 277 ])
 278     fi
 279 fi
 280
 281 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 282 dnl ('-drive ...,if=...' option to qemu).
 283 dnl
 284 dnl If you encounter performance problems with virtio (RHBZ#509383)
 285 dnl then try '--with-drive-if=ide'.
 286 AC_ARG_WITH([drive-if],
 287         [AS_HELP_STRING([--with-drive-if],
 288           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 289         [],
 290         [with_drive_if=virtio])
 291 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 292
 293 dnl Set interface used by the network.  Normally you should
 294 dnl leave this at the default (virtio) but you can use the
 295 dnl alternative (ne2k_pci) because of bugs in virtio networking
 296 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 297 AC_ARG_WITH([net-if],
 298         [AS_HELP_STRING([--with-net-if],
 299           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 300         [],
 301         [with_net_if=virtio])
 302 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 303
 304 dnl Check for febootstrap etc.
 305 if test "x$enable_appliance" = "xyes"; then
 306     AC_CHECK_PROG([FEBOOTSTRAP],
 307                   [febootstrap],[febootstrap],[no])
 308     if test "x$FEBOOTSTRAP" != "xno"; then
 309       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 310                     [febootstrap-run],[febootstrap-run],[no])
 311       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 312           AC_MSG_ERROR([febootstrap-run must be installed])
 313       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 314                     [febootstrap-install],[febootstrap-install],[no])
 315       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 316           AC_MSG_ERROR([febootstrap-install must be installed])
 317       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 318                     [febootstrap-minimize],[febootstrap-minimize],[no])
 319       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 320           AC_MSG_ERROR([febootstrap-minimize must be installed])
 321       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 322                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 323       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 324           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 325       AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
 326                     [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
 327       test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
 328           AC_MSG_ERROR([febootstrap-to-supermin must be installed])
 329
 330       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 331       dnl of febootstrap, but old versions will fail with yum).
 332       AC_CHECK_PROG([FAKECHROOT],
 333                     [fakechroot],[fakechroot],[no])
 334       test "x$FAKECHROOT" = "xno" && \
 335          AC_MSG_ERROR([fakechroot must be installed])
 336
 337       AC_MSG_CHECKING([fakechroot version])
 338       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 339       if test -z "$fakechroot_version"; then
 340         AC_MSG_RESULT([failed])
 341         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 342       else
 343         AC_MSG_RESULT([$fakechroot_version])
 344         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 345         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 346         if test "$fakechroot_major" -lt 2 -o \
 347             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 348           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 349         fi
 350       fi
 351       DIST="REDHAT"
 352     else
 353       # check for debootstrap and debirf
 354       AC_CHECK_PROG([DEBOOTSTRAP],
 355                     [debootstrap],[debootstrap],[no])
 356       test "x$DEBOOTSTRAP" = "xno" && \
 357           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 358       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 359       test "x$DEBIRF" = "xno" &&
 360           AC_MSG_ERROR([debirf must be installed])
 361       DIST="DEBIAN"
 362       case "$host_cpu" in
 363       *86)
 364           DEBIAN_KERNEL_ARCH=486
 365           ;;
 366       x86_64)
 367           DEBIAN_KERNEL_ARCH=amd64
 368           ;;
 369       *)
 370          DEBIAN_KERNEL_ARCH=$host_cpu
 371          ;;
 372       esac
 373       AC_SUBST(DEBIAN_KERNEL_ARCH)
 374     fi
 375     AC_SUBST(DIST)
 376
 377     dnl --with-updates to specify a Fedora updates repository.
 378     AC_ARG_WITH([updates],
 379         [AS_HELP_STRING([--with-updates],
 380           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 381         [],
 382         [with_updates=updates-released-f12])
 383     UPDATES="$with_updates"
 384     AC_SUBST(UPDATES)
 385
 386     dnl --with-mirror to specify a local Fedora mirror.
 387     AC_ARG_WITH([mirror],
 388         [AS_HELP_STRING([--with-mirror],
 389           [set URI of a local Fedora mirror])],
 390         [],
 391         [with_mirror=])
 392     MIRROR="$with_mirror"
 393     AC_SUBST(MIRROR)
 394 fi
 395
 396 dnl --with-repo to specify a Fedora repository.
 397 AC_ARG_WITH([repo],
 398         [AS_HELP_STRING([--with-repo],
 399           [set name of Fedora repository @<:@default=fedora-12@:>@])],
 400         [],
 401         [with_repo=fedora-12])
 402 REPO="$with_repo"
 403 AC_SUBST(REPO)
 404 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 405
 406 dnl Build the supermin appliance?  Please see README file before
 407 dnl enabling this option.
 408 AC_ARG_ENABLE([supermin],
 409         [AS_HELP_STRING([--enable-supermin],
 410           [enable supermin appliance (see README) @<:@default=no@:>@])],
 411         [],
 412         [enable_supermin=no])
 413 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 414
 415 dnl Enable packet dumps when in verbose mode.  This generates lots
 416 dnl of debug info, only useful for people debugging the RPC mechanism.
 417 AC_ARG_ENABLE([packet-dump],
 418         [AS_HELP_STRING([--enable-packet-dump],
 419           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 420         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 421         [])
 422
 423 dnl Readline.
 424 AC_ARG_WITH([readline],
 425     [AS_HELP_STRING([--with-readline],
 426         [support fancy command line editing @<:@default=check@:>@])],
 427     [],
 428     [with_readline=check])
 429
 430 LIBREADLINE=
 431 AS_IF([test "x$with_readline" != xno],
 432     [AC_CHECK_LIB([readline], [main],
 433         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 434          AC_DEFINE([HAVE_LIBREADLINE], [1],
 435                    [Define if you have libreadline])
 436         ],
 437         [if test "x$with_readline" != xcheck; then
 438          AC_MSG_FAILURE(
 439              [--with-readline was given, but test for readline failed])
 440          fi
 441         ], -lncurses)
 442      old_LIBS="$LIBS"
 443      LIBS="$LIBS $LIBREADLINE"
 444      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 445      LIBS="$old_LIBS"
 446     ])
 447
 448 dnl For i18n.
 449 AM_GNU_GETTEXT([external])
 450 AM_GNU_GETTEXT_VERSION([0.17])
 451
 452 dnl hivex library (highly recommended).
 453 dnl This used to be a part of libguestfs, but was spun off into its
 454 dnl own separate upstream project in libguestfs 1.0.85.
 455 HAVE_HIVEX=yes
 456 PKG_CHECK_MODULES([HIVEX], [hivex],,[
 457         HAVE_HIVEX=no
 458         AC_MSG_WARN([Hivex library and headers are missing, so optional Windows Registry tools won't be built])])
 459 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HAVE_HIVEX" = "xyes"])
 460 AC_SUBST([HIVEX_CFLAGS])
 461 AC_SUBST([HIVEX_LIBS])
 462
 463 dnl FUSE is optional to build the FUSE module.
 464 HAVE_FUSE=yes
 465 PKG_CHECK_MODULES([FUSE],[fuse],,[
 466         HAVE_FUSE=no
 467         AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
 468 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
 469
 470 dnl Check for OCaml (optional, for OCaml bindings).
 471 AC_PROG_OCAML
 472 AC_PROG_FINDLIB
 473 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 474
 475 dnl Optional xml-light for running the generator.
 476 OCAML_PKG_xml_light=no
 477 if test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"; then
 478     AC_CHECK_OCAML_PKG([xml-light])
 479 fi
 480 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 481
 482 dnl Build the OCaml viewer example.  This has a lengthy list of
 483 dnl dependencies and we don't attempt to detect them all.  Read
 484 dnl the top of ocaml/examples/viewer.ml before enabling this.
 485 AC_ARG_ENABLE([ocaml-viewer],
 486         [AS_HELP_STRING([--enable-ocaml-viewer],
 487           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 488         [],
 489         [enable_ocaml_viewer=no])
 490 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 491
 492 dnl Check for Perl (optional, for Perl bindings).
 493 dnl XXX This isn't quite right, we should check for Perl devel library.
 494 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 495
 496 dnl Check for Perl modules that must be present to compile and
 497 dnl test the Perl bindings.
 498 missing_perl_modules=no
 499 for pm in Test::More ExtUtils::MakeMaker; do
 500     AC_MSG_CHECKING([for $pm])
 501     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 502         AC_MSG_RESULT([no])
 503         missing_perl_modules=yes
 504     else
 505         AC_MSG_RESULT([yes])
 506     fi
 507 done
 508 if test "x$missing_perl_modules" = "xyes"; then
 509     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 510 fi
 511
 512 AM_CONDITIONAL([HAVE_PERL],
 513     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 514
 515 dnl Check for Python (optional, for Python bindings).
 516 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 517
 518 PYTHON_PREFIX=
 519 PYTHON_VERSION=
 520 PYTHON_INCLUDEDIR=
 521 PYTHON_SITE_PACKAGES=
 522
 523 if test "x$PYTHON" != "xno"; then
 524     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 525     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 526     for d in \
 527         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 528         /usr/include/python$PYTHON_VERSION \
 529         /usr/local/include/python$PYTHON_VERSION
 530     do
 531         AC_MSG_CHECKING([Python.h in $d])
 532         if test -r "$d/Python.h"; then
 533             AC_MSG_RESULT([found])
 534             PYTHON_INCLUDEDIR=$d
 535             break
 536         fi
 537         AC_MSG_RESULT([not found])
 538     done
 539     for d in \
 540         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 541         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 542         /usr/lib64/python$PYTHON_VERSION/site-packages \
 543         /usr/lib/python$PYTHON_VERSION/site-packages \
 544         /usr/local/lib/python$PYTHON_VERSION/site-packages
 545     do
 546         AC_MSG_CHECKING([for $d])
 547         if test -d "$d"; then
 548             AC_MSG_RESULT([found])
 549             PYTHON_SITE_PACKAGES=$d
 550             break
 551         fi
 552         AC_MSG_RESULT([not found])
 553     done
 554 fi
 555
 556 AC_SUBST(PYTHON_PREFIX)
 557 AC_SUBST(PYTHON_VERSION)
 558 AC_SUBST(PYTHON_INCLUDEDIR)
 559 AC_SUBST(PYTHON_SITE_PACKAGES)
 560
 561 AM_CONDITIONAL([HAVE_PYTHON],
 562     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 563
 564 dnl Check for Ruby and rake (optional, for Ruby bindings).
 565 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 566 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 567
 568 AM_CONDITIONAL([HAVE_RUBY],
 569     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 570
 571 dnl Check for Java.
 572 AC_ARG_WITH(java_home,
 573     [AS_HELP_STRING([--with-java-home],
 574         [specify path to JDK directory @<:@default=check@:>@])],
 575     [],
 576     [with_java_home=check])
 577
 578 if test "x$with_java_home" != "xno"; then
 579     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 580     then
 581         # Reject unsafe characters in $JAVA_HOME
 582         jh_lf='
 583 '
 584         case $JAVA_HOME in
 585           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 586             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 587         esac
 588         if test -d "$with_java_home"; then
 589             JAVA_HOME="$with_java_home"
 590         else
 591             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 592         fi
 593     fi
 594
 595     if test "x$JAVA_HOME" = "x"; then
 596         # Look for Java in some likely locations.
 597         for d in \
 598             /usr/lib/jvm/java \
 599             /usr/lib/jvm/java-6-openjdk
 600         do
 601             if test -d $d -a -f $d/bin/java; then
 602                 JAVA_HOME=$d
 603                 break
 604             fi
 605         done
 606     fi
 607
 608     if test "x$JAVA_HOME" != "x"; then
 609         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 610         if test ! -x "$JAVA_HOME/bin/java"; then
 611             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 612         else
 613             JAVA="$JAVA_HOME/bin/java"
 614         fi
 615         if test ! -x "$JAVA_HOME/bin/javac"; then
 616             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 617         else
 618             JAVAC="$JAVA_HOME/bin/javac"
 619         fi
 620         if test ! -x "$JAVA_HOME/bin/javah"; then
 621             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 622         else
 623             JAVAH="$JAVA_HOME/bin/javah"
 624         fi
 625         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 626             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 627         else
 628             JAVADOC="$JAVA_HOME/bin/javadoc"
 629         fi
 630         if test ! -x "$JAVA_HOME/bin/jar"; then
 631             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 632         else
 633             JAR="$JAVA_HOME/bin/jar"
 634         fi
 635         java_version=`$JAVA -version 2>&1 | grep "java version"`
 636         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 637
 638         dnl Find jni.h.
 639         AC_MSG_CHECKING([for jni.h])
 640         if test -f "$JAVA_HOME/include/jni.h"; then
 641             JNI_CFLAGS="-I$JAVA_HOME/include"
 642         else
 643             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 644                 head=`find $JAVA_HOME -name jni.h | tail -1`
 645                 dir=`dirname "$head"`
 646                 JNI_CFLAGS="-I$dir"
 647             else
 648                 AC_MSG_FAILURE([missing jni.h header file])
 649             fi
 650         fi
 651         AC_MSG_RESULT([$JNI_CFLAGS])
 652
 653         dnl Find jni_md.h.
 654         AC_MSG_CHECKING([for jni_md.h])
 655         case "$build_os" in
 656         *linux*) system="linux" ;;
 657         *SunOS*) system="solaris" ;;
 658         *cygwin*) system="win32" ;;
 659         *) system="$build_os" ;;
 660         esac
 661         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 662             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 663         else
 664             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 665                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 666                 dir=`dirname "$head"`
 667                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 668             else
 669                 AC_MSG_FAILURE([missing jni_md.h header file])
 670             fi
 671         fi
 672         AC_MSG_RESULT([$JNI_CFLAGS])
 673
 674         dnl Need extra version flag?
 675         AC_MSG_CHECKING([extra javac flags])
 676         JAVAC_FLAGS=
 677         javac_version=`$JAVAC -version 2>&1`
 678         case "$javac_version" in
 679         *Eclipse*)
 680             JAVAC_FLAGS="-source 1.5" ;;
 681         esac
 682         AC_MSG_RESULT([$JAVAC_FLAGS])
 683
 684         dnl Where to install jarfiles.
 685         dnl XXX How to make it configurable?
 686         JAR_INSTALL_DIR=\${prefix}/share/java
 687         JNI_INSTALL_DIR=\${libdir}
 688
 689         dnl JNI version.
 690         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 691         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 692         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 693         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 694     fi
 695 fi
 696
 697 AC_SUBST(JAVA_HOME)
 698 AC_SUBST(JAVA)
 699 AC_SUBST(JAVAC)
 700 AC_SUBST(JAVAH)
 701 AC_SUBST(JAVADOC)
 702 AC_SUBST(JAR)
 703 AC_SUBST(JNI_CFLAGS)
 704 AC_SUBST(JAVAC_FLAGS)
 705 AC_SUBST(JAR_INSTALL_DIR)
 706 AC_SUBST(JNI_INSTALL_DIR)
 707 AC_SUBST(JNI_VERSION_INFO)
 708
 709 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 710
 711 dnl Check for Haskell (GHC).
 712 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 713
 714 AM_CONDITIONAL([HAVE_HASKELL],
 715     [test "x$GHC" != "xno"])
 716
 717 dnl Check for Perl modules needed by virt-df, inspector, etc.
 718 missing_perl_modules=no
 719 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
 720     AC_MSG_CHECKING([for $pm])
 721     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 722         AC_MSG_RESULT([no])
 723         missing_perl_modules=yes
 724     else
 725         AC_MSG_RESULT([yes])
 726     fi
 727 done
 728 if test "x$missing_perl_modules" = "xyes"; then
 729     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 730 fi
 731
 732 AM_CONDITIONAL([HAVE_INSPECTOR],
 733     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 734 AM_CONDITIONAL([HAVE_TOOLS],
 735     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 736
 737 dnl Library versioning.
 738 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 739 AC_SUBST(MAX_PROC_NR)
 740
 741 dnl Run in subdirs.
 742 if test "x$enable_daemon" = "xyes"; then
 743     AC_CONFIG_SUBDIRS([daemon])
 744 fi
 745
 746 dnl Produce output files.
 747 AC_CONFIG_HEADERS([config.h])
 748 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 749 AC_CONFIG_FILES([appliance/update.sh],
 750                 [chmod +x appliance/update.sh])
 751 AC_CONFIG_FILES([Makefile
 752                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 753                  appliance/Makefile
 754                  appliance/debian/debirf.conf
 755                  images/Makefile
 756                  capitests/Makefile
 757                  regressions/Makefile
 758                  test-tool/Makefile
 759                  ocaml/Makefile ocaml/examples/Makefile
 760                  perl/Makefile
 761                  python/Makefile
 762                  ruby/Makefile ruby/Rakefile
 763                  java/Makefile
 764                  haskell/Makefile
 765                  inspector/Makefile
 766                  tools/Makefile
 767                  libguestfs.pc
 768                  gnulib/lib/Makefile
 769                  gnulib/tests/Makefile
 770                  fuse/Makefile
 771                  ocaml/META perl/Makefile.PL])
 772 AC_OUTPUT
 773
 774 dnl Produce summary.
 775 echo
 776 echo
 777 echo "------------------------------------------------------------"
 778 echo "Thank you for downloading $PACKAGE_STRING"
 779 echo
 780 echo "This is how we have configured the optional components for you today:"
 781 echo
 782 echo    "Daemon .............................. $enable_daemon"
 783 echo    "Appliance ........................... $enable_appliance"
 784 echo    "QEMU ................................ $QEMU"
 785 echo -n "OCaml bindings ...................... "
 786 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 787 echo -n "Perl bindings ....................... "
 788 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 789 echo -n "Python bindings ..................... "
 790 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 791 echo -n "Ruby bindings ....................... "
 792 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 793 echo -n "Java bindings ....................... "
 794 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 795 echo -n "Haskell bindings .................... "
 796 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 797 echo -n "virt-inspector ...................... "
 798 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 799 echo -n "virt-* tools ........................ "
 800 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 801 echo "supermin appliance .................. $enable_supermin"
 802 echo "FUSE filesystem ..................... $HAVE_FUSE"
 803 echo
 804 echo "If any optional component is configured 'no' when you expected 'yes'"
 805 echo "then you should check the preceeding messages."
 806 echo
 807 echo "Please report bugs back to the mailing list:"
 808 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 809 echo
 810 echo "Next you should type 'make' to build the package,"
 811 echo "then 'make check' to run the tests."
 812 echo "------------------------------------------------------------"