configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [7])
  21 m4_define([libguestfs_release], [12])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Die if the user tries to configure as root, see:
  57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  58 AC_MSG_CHECKING([if you are trying to configure as root])
  59 AS_IF([test "`id -u`" = 0 ],[
  60             AC_MSG_RESULT([yes])
  61             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  62       ],[
  63             AC_MSG_RESULT([no])
  64       ])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 114                                     # was not possible, safe to ignore
 115   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 116   nw="$nw -Wlong-long"              # Allow long long since it's required
 117                                     # by Python, Ruby and xstrtoll.
 118
 119   gl_MANYWARN_ALL_GCC([ws])
 120   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 121   for w in $ws; do
 122     gl_WARN_ADD([$w])
 123   done
 124   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 125   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 126   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 127
 128   # In spite of excluding -Wlogical-op above, it is enabled, as of
 129   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 130   gl_WARN_ADD([-Wno-logical-op])
 131
 132   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 133   gl_WARN_ADD([-Wno-strict-overflow])
 134
 135   gl_WARN_ADD([-fdiagnostics-show-option])
 136
 137   AC_SUBST([WARN_CFLAGS])
 138
 139   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 140   AC_DEFINE([_FORTIFY_SOURCE], [2],
 141     [enable compile-time and run-time bounds-checking, and some warnings])
 142   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 143 fi
 144
 145 AC_C_PROTOTYPES
 146 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 147
 148 AM_PROG_CC_C_O
 149
 150 dnl Work out how to specify the linker script to the linker.
 151 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 152 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 153     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 154 AC_SUBST(VERSION_SCRIPT_FLAGS)
 155
 156 dnl Check support for 64 bit file offsets.
 157 AC_SYS_LARGEFILE
 158
 159 dnl Check sizeof long.
 160 AC_CHECK_SIZEOF([long])
 161
 162 dnl Define a C symbol for the host CPU architecture.
 163 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 164
 165 dnl Headers.
 166 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 167
 168 dnl Functions.
 169 AC_CHECK_FUNCS([posix_fallocate])
 170
 171 dnl Build the daemon?
 172 AC_MSG_CHECKING([if we should build the daemon])
 173 AC_ARG_ENABLE([daemon],
 174         [AS_HELP_STRING([--enable-daemon],
 175           [enable building the daemon @<:@default=yes@:>@])],
 176         [],
 177         [enable_daemon=yes])
 178 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 179 AC_MSG_RESULT([$enable_daemon])
 180
 181 dnl Build the appliance?
 182 AC_MSG_CHECKING([if we should build the appliance])
 183 AC_ARG_ENABLE([appliance],
 184         [AS_HELP_STRING([--enable-appliance],
 185           [enable building the appliance @<:@default=yes@:>@])],
 186         [],
 187         [enable_appliance=yes])
 188 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 189 AC_MSG_RESULT([$enable_appliance])
 190
 191 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 192 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 193 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 194 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 195         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 196         ])
 197
 198 dnl Check for cpio which isn't in the default Pardus install amazingly.
 199 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 200 test "x$CPIO" = "xno" &&
 201      AC_MSG_ERROR([cpio must be installed])
 202
 203 dnl Check for gperf.
 204 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 205 test "x$GPERF" = "xno" &&
 206      AC_MSG_ERROR([gperf must be installed])
 207
 208 dnl Check for pod2man and pod2text.
 209 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 210 test "x$POD2MAN" = "xno" &&
 211      AC_MSG_ERROR([pod2man must be installed])
 212 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 213 test "x$POD2TEXT" = "xno" &&
 214      AC_MSG_ERROR([pod2text must be installed])
 215
 216 dnl Check for mkisofs.
 217 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 218         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 219 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 220
 221 dnl Check for optional xmllint.
 222 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 223 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 224
 225 dnl po4a for translating man pages and POD files (optional).
 226 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 227 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 228
 229 dnl Check for db_dump, db_load (optional).
 230 AC_CHECK_PROGS([DB_DUMP],[db_dump db4_dump db4.8_dump],[no])
 231 AC_CHECK_PROGS([DB_LOAD],[db_load db4_load db4.8_load],[no])
 232 if test "x$DB_DUMP" != "xno"; then
 233     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 234 fi
 235 if test "x$DB_LOAD" != "xno"; then
 236     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 237 fi
 238
 239 dnl Check for QEMU for running binaries on this $host_cpu, fall
 240 dnl back to basic 'qemu'.  Allow the user to override it.
 241 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 242 AC_ARG_WITH([qemu],
 243         [AS_HELP_STRING([--with-qemu],
 244           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 245         [],
 246         [with_qemu="$default_qemu"])
 247 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 248         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 249 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 250 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 251
 252 dnl Check that the chosen qemu has virtio-serial support.
 253 if test "x$vmchannel_test" != "xno"; then
 254     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 255     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 256         AC_MSG_RESULT([yes])
 257         vmchannel_guestfwd=guestfwd
 258     else
 259         AC_MSG_RESULT([no])
 260         AC_MSG_FAILURE(
 261 [I did not find virtio-serial support in
 262 $QEMU.
 263
 264 virtio-serial support in qemu or KVM is essential for libguestfs
 265 to operate.
 266
 267 Usually this means that you have to install a newer version of qemu
 268 and/or KVM.  Please read the relevant section in the README file for
 269 more information about this.
 270
 271 You can override this test by setting the environment variable
 272 vmchannel_test=no  However if you don't have the right support
 273 in your qemu, then this just delays the pain.
 274
 275 If I am using the wrong qemu or you want to compile qemu from source
 276 and install it in another location, then you should configure with
 277 the --with-qemu option.
 278 ])
 279     fi
 280 fi
 281
 282 dnl Set default drive interface used by the guestfs_add_drive_opts call
 283 dnl ('-drive ...,if=...' option to qemu).
 284 dnl
 285 dnl If you encounter performance problems with virtio (RHBZ#509383)
 286 dnl then try '--with-drive-if=ide'.
 287 AC_ARG_WITH([drive-if],
 288         [AS_HELP_STRING([--with-drive-if],
 289           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 290         [],
 291         [with_drive_if=virtio])
 292 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 293
 294 dnl Set interface used by the network.  Normally you should
 295 dnl leave this at the default (virtio-net-pci) but you can use the
 296 dnl alternative (ne2k_pci) because of bugs in virtio networking
 297 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 298 AC_ARG_WITH([net-if],
 299         [AS_HELP_STRING([--with-net-if],
 300           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 301         [],
 302         [with_net_if=virtio-net-pci])
 303 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 304
 305 dnl Check for febootstrap etc.
 306 if test "x$enable_appliance" = "xyes"; then
 307     AC_CHECK_PROG([FEBOOTSTRAP],
 308                   [febootstrap],[febootstrap],[no])
 309     if test "x$FEBOOTSTRAP" != "xno"; then
 310       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 311                     [febootstrap-run],[febootstrap-run],[no])
 312       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 313           AC_MSG_ERROR([febootstrap-run must be installed])
 314       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 315                     [febootstrap-install],[febootstrap-install],[no])
 316       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 317           AC_MSG_ERROR([febootstrap-install must be installed])
 318       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 319                     [febootstrap-minimize],[febootstrap-minimize],[no])
 320       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 321           AC_MSG_ERROR([febootstrap-minimize must be installed])
 322       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 323                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 324       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 325           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 326       AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
 327                     [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
 328       test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
 329           AC_MSG_ERROR([febootstrap-to-supermin must be installed])
 330
 331       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 332       dnl of febootstrap, but old versions will fail with yum).
 333       AC_CHECK_PROG([FAKECHROOT],
 334                     [fakechroot],[fakechroot],[no])
 335       test "x$FAKECHROOT" = "xno" && \
 336          AC_MSG_ERROR([fakechroot must be installed])
 337
 338       AC_MSG_CHECKING([fakechroot version])
 339       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 340       if test -z "$fakechroot_version"; then
 341         AC_MSG_RESULT([failed])
 342         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 343       else
 344         AC_MSG_RESULT([$fakechroot_version])
 345         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 346         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 347         if test "$fakechroot_major" -lt 2 || \
 348           ( test "$fakechroot_major" -eq 2 && test "$fakechroot_minor" -lt 9 ); then
 349           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 350         fi
 351       fi
 352       DIST="REDHAT"
 353     else
 354       # check for debootstrap and debirf
 355       AC_CHECK_PROG([DEBOOTSTRAP],
 356                     [debootstrap],[debootstrap],[no])
 357       test "x$DEBOOTSTRAP" = "xno" && \
 358           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 359       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 360       test "x$DEBIRF" = "xno" &&
 361           AC_MSG_ERROR([debirf must be installed])
 362       DIST="DEBIAN"
 363       case "$host_cpu" in
 364       *86)
 365           DEBIAN_KERNEL_ARCH=486
 366           ;;
 367       x86_64)
 368           DEBIAN_KERNEL_ARCH=amd64
 369           ;;
 370       *)
 371          DEBIAN_KERNEL_ARCH=$host_cpu
 372          ;;
 373       esac
 374       AC_SUBST(DEBIAN_KERNEL_ARCH)
 375     fi
 376     AC_SUBST(DIST)
 377
 378     dnl --with-updates to specify a Fedora updates repository.
 379     AC_ARG_WITH([updates],
 380         [AS_HELP_STRING([--with-updates],
 381           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 382         [],
 383         [with_updates=updates-released-f12])
 384     UPDATES="$with_updates"
 385     AC_SUBST(UPDATES)
 386
 387     dnl --with-mirror to specify a local Fedora mirror.
 388     AC_ARG_WITH([mirror],
 389         [AS_HELP_STRING([--with-mirror],
 390           [set URI of a local Fedora mirror])],
 391         [],
 392         [with_mirror=])
 393     MIRROR="$with_mirror"
 394     AC_SUBST(MIRROR)
 395 fi
 396
 397 dnl --with-repo to specify a repository.
 398 AC_ARG_WITH([repo],
 399         [AS_HELP_STRING([--with-repo],
 400           [set name of Fedora repository @<:@default=fedora-13@:>@])],
 401         [],
 402         [with_repo=fedora-13])
 403 REPO="$with_repo"
 404 AC_SUBST(REPO)
 405 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of software repository.])
 406
 407 dnl Build the supermin appliance?  Please see README file before
 408 dnl enabling this option.
 409 AC_ARG_ENABLE([supermin],
 410         [AS_HELP_STRING([--enable-supermin],
 411           [enable supermin appliance (see README) @<:@default=no@:>@])],
 412         [AC_DEFINE([ENABLE_SUPERMIN],[1],[Supermin appliance enabled.])],
 413         [enable_supermin=no])
 414 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 415
 416 dnl Enable packet dumps when in verbose mode.  This generates lots
 417 dnl of debug info, only useful for people debugging the RPC mechanism.
 418 AC_ARG_ENABLE([packet-dump],
 419         [AS_HELP_STRING([--enable-packet-dump],
 420           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 421         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 422         [])
 423
 424 dnl Readline.
 425 AC_ARG_WITH([readline],
 426     [AS_HELP_STRING([--with-readline],
 427         [support fancy command line editing @<:@default=check@:>@])],
 428     [],
 429     [with_readline=check])
 430
 431 LIBREADLINE=
 432 AS_IF([test "x$with_readline" != xno],
 433     [AC_CHECK_LIB([readline], [main],
 434         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 435          AC_DEFINE([HAVE_LIBREADLINE], [1],
 436                    [Define if you have libreadline])
 437         ],
 438         [if test "x$with_readline" != xcheck; then
 439          AC_MSG_FAILURE(
 440              [--with-readline was given, but test for readline failed])
 441          fi
 442         ], -lncurses)
 443      old_LIBS="$LIBS"
 444      LIBS="$LIBS $LIBREADLINE"
 445      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 446      LIBS="$old_LIBS"
 447     ])
 448
 449 dnl For i18n.
 450 AM_GNU_GETTEXT([external])
 451 AM_GNU_GETTEXT_VERSION([0.17])
 452
 453 dnl libmagic (highly recommended)
 454 AC_CHECK_LIB([magic],[magic_file],
 455         [AC_CHECK_HEADER([magic.h],
 456                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 457                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 458                 ], [])
 459         ],
 460         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 461
 462 dnl Check for PCRE (highly recommended)
 463 PKG_CHECK_MODULES([PCRE], [libpcre],
 464         [AC_SUBST([PCRE_CFLAGS])
 465          AC_SUBST([PCRE_LIBS])
 466          AC_DEFINE([HAVE_PCRE],[1],[PCRE found at compile time.])
 467         ],
 468         [AC_MSG_WARN([PCRE not found, some core features will be disabled])])
 469
 470 dnl libvirt (highly recommended)
 471 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 472         [AC_SUBST([LIBVIRT_CFLAGS])
 473          AC_SUBST([LIBVIRT_LIBS])
 474          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 475         ],
 476         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 477 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 478
 479 dnl libxml2 (highly recommended)
 480 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 481         [AC_SUBST([LIBXML2_CFLAGS])
 482          AC_SUBST([LIBXML2_LIBS])
 483          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 484         ],
 485         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 486 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 487
 488 dnl hivex library (highly recommended)
 489 dnl This used to be a part of libguestfs, but was spun off into its
 490 dnl own separate upstream project in libguestfs 1.0.85.
 491 PKG_CHECK_MODULES([HIVEX], [hivex],
 492         [AC_SUBST([HIVEX_CFLAGS])
 493          AC_SUBST([HIVEX_LIBS])
 494          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 495         ],
 496         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 497
 498 dnl FUSE is optional to build the FUSE module.
 499 AC_ARG_ENABLE([fuse],
 500         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 501         [],
 502         [enable_fuse=yes])
 503 AS_IF([test "x$enable_fuse" != "xno"],
 504         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 505                 enable_fuse=no
 506                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 507 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 508
 509 dnl Check for OCaml (optional, for OCaml bindings).
 510 OCAMLC=no
 511 OCAMLFIND=no
 512 AC_ARG_ENABLE([ocaml],
 513         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 514         [],
 515         [enable_ocaml=yes])
 516 AS_IF([test "x$enable_ocaml" != "xno"],
 517         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 518          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 519          OCAMLC=
 520          OCAMLFIND=
 521          AC_PROG_OCAML
 522          AC_PROG_FINDLIB
 523         ])
 524 AM_CONDITIONAL([HAVE_OCAML],
 525                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 526
 527 dnl Check for Perl (optional, for Perl bindings).
 528 PERL=no
 529 AC_ARG_ENABLE([perl],
 530         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 531         [],
 532         [enable_perl=yes])
 533 AS_IF([test "x$enable_perl" != "xno"],
 534         [
 535         PERL=
 536         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 537
 538         dnl Check for Perl modules that must be present to compile and
 539         dnl test the Perl bindings.
 540         missing_perl_modules=no
 541         for pm in Test::More ExtUtils::MakeMaker; do
 542             AC_MSG_CHECKING([for $pm])
 543             if ! perl -M$pm -e1 >/dev/null 2>&1; then
 544                 AC_MSG_RESULT([no])
 545                 missing_perl_modules=yes
 546             else
 547                 AC_MSG_RESULT([yes])
 548             fi
 549         done
 550         if test "x$missing_perl_modules" = "xyes"; then
 551             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 552         fi
 553         ])
 554 AM_CONDITIONAL([HAVE_PERL],
 555     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 556
 557 dnl Check for Python (optional, for Python bindings).
 558 PYTHON_PREFIX=
 559 PYTHON_VERSION=
 560 PYTHON_INCLUDEDIR=
 561 PYTHON_SITE_PACKAGES=
 562
 563 AC_ARG_ENABLE([python],
 564         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 565         [],
 566         [enable_python=yes])
 567 AS_IF([test "x$enable_python" != "xno"],
 568         [
 569         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 570
 571         if test "x$PYTHON" != "xno"; then
 572             PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 573             PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 574             for d in \
 575                 $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 576                 /usr/include/python$PYTHON_VERSION \
 577                 /usr/local/include/python$PYTHON_VERSION
 578             do
 579                 AC_MSG_CHECKING([Python.h in $d])
 580                 if test -r "$d/Python.h"; then
 581                     AC_MSG_RESULT([found])
 582                     PYTHON_INCLUDEDIR=$d
 583                     break
 584                 fi
 585                 AC_MSG_RESULT([not found])
 586             done
 587             if test "x$PYTHON_INCLUDEDIR" = "x"; then
 588                 AC_MSG_WARN([Python include directory not found])
 589             fi
 590
 591             for d in \
 592                 $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 593                 $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 594                 /usr/lib64/python$PYTHON_VERSION/site-packages \
 595                 /usr/lib/python$PYTHON_VERSION/site-packages \
 596                 /usr/local/lib/python$PYTHON_VERSION/site-packages
 597             do
 598                 AC_MSG_CHECKING([for $d])
 599                 if test -d "$d"; then
 600                     AC_MSG_RESULT([found])
 601                     PYTHON_SITE_PACKAGES=$d
 602                     break
 603                 fi
 604                 AC_MSG_RESULT([not found])
 605             done
 606             if test "x$PYTHON_SITE_PACKAGES" = "x"; then
 607                 AC_MSG_WARN([Python site-packages directory not found])
 608             fi
 609
 610             old_LIBS="$LIBS"
 611             LIBS="$LIBS -lpython$PYTHON_VERSION"
 612             AC_CHECK_FUNCS([PyCapsule_New])
 613             LIBS="$old_LIBS"
 614         fi
 615
 616         AC_SUBST(PYTHON_PREFIX)
 617         AC_SUBST(PYTHON_VERSION)
 618         AC_SUBST(PYTHON_INCLUDEDIR)
 619         AC_SUBST(PYTHON_SITE_PACKAGES)
 620         ])
 621 AM_CONDITIONAL([HAVE_PYTHON],
 622     [test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_SITE_PACKAGES" != "x"])
 623
 624 dnl Check for Ruby and rake (optional, for Ruby bindings).
 625 AC_ARG_ENABLE([ruby],
 626         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 627         [],
 628         [enable_ruby=yes])
 629 AS_IF([test "x$enable_ruby" != "xno"],
 630         [
 631         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 632         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 633         ])
 634 AM_CONDITIONAL([HAVE_RUBY],
 635     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 636
 637 dnl Check for Java.
 638 AC_ARG_WITH(java_home,
 639     [AS_HELP_STRING([--with-java-home],
 640         [specify path to JDK directory @<:@default=check@:>@])],
 641     [],
 642     [with_java_home=check])
 643
 644 if test "x$with_java_home" != "xno"; then
 645     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 646     then
 647         # Reject unsafe characters in $JAVA_HOME
 648         jh_lf='
 649 '
 650         case $JAVA_HOME in
 651           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 652             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 653         esac
 654         if test -d "$with_java_home"; then
 655             JAVA_HOME="$with_java_home"
 656         else
 657             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 658         fi
 659     fi
 660
 661     if test "x$JAVA_HOME" = "x"; then
 662         # Look for Java in some likely locations.
 663         for d in \
 664             /usr/lib/jvm/java \
 665             /usr/lib/jvm/java-6-openjdk
 666         do
 667             if test -d $d && test -f $d/bin/java; then
 668                 JAVA_HOME=$d
 669                 break
 670             fi
 671         done
 672     fi
 673
 674     if test "x$JAVA_HOME" != "x"; then
 675         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 676         if test ! -x "$JAVA_HOME/bin/java"; then
 677             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 678         else
 679             JAVA="$JAVA_HOME/bin/java"
 680         fi
 681         if test ! -x "$JAVA_HOME/bin/javac"; then
 682             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 683         else
 684             JAVAC="$JAVA_HOME/bin/javac"
 685         fi
 686         if test ! -x "$JAVA_HOME/bin/javah"; then
 687             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 688         else
 689             JAVAH="$JAVA_HOME/bin/javah"
 690         fi
 691         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 692             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 693         else
 694             JAVADOC="$JAVA_HOME/bin/javadoc"
 695         fi
 696         if test ! -x "$JAVA_HOME/bin/jar"; then
 697             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 698         else
 699             JAR="$JAVA_HOME/bin/jar"
 700         fi
 701         java_version=`$JAVA -version 2>&1 | grep "java version"`
 702         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 703
 704         dnl Find jni.h.
 705         AC_MSG_CHECKING([for jni.h])
 706         if test -f "$JAVA_HOME/include/jni.h"; then
 707             JNI_CFLAGS="-I$JAVA_HOME/include"
 708         else
 709             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 710                 head=`find $JAVA_HOME -name jni.h | tail -1`
 711                 dir=`dirname "$head"`
 712                 JNI_CFLAGS="-I$dir"
 713             else
 714                 AC_MSG_FAILURE([missing jni.h header file])
 715             fi
 716         fi
 717         AC_MSG_RESULT([$JNI_CFLAGS])
 718
 719         dnl Find jni_md.h.
 720         AC_MSG_CHECKING([for jni_md.h])
 721         case "$build_os" in
 722         *linux*) system="linux" ;;
 723         *SunOS*) system="solaris" ;;
 724         *cygwin*) system="win32" ;;
 725         *) system="$build_os" ;;
 726         esac
 727         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 728             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 729         else
 730             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 731                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 732                 dir=`dirname "$head"`
 733                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 734             else
 735                 AC_MSG_FAILURE([missing jni_md.h header file])
 736             fi
 737         fi
 738         AC_MSG_RESULT([$JNI_CFLAGS])
 739
 740         dnl Need extra version flag?
 741         AC_MSG_CHECKING([extra javac flags])
 742         JAVAC_FLAGS=
 743         javac_version=`$JAVAC -version 2>&1`
 744         case "$javac_version" in
 745         *Eclipse*)
 746             JAVAC_FLAGS="-source 1.5" ;;
 747         esac
 748         AC_MSG_RESULT([$JAVAC_FLAGS])
 749
 750         dnl Where to install jarfiles.
 751         dnl XXX How to make it configurable?
 752         JAR_INSTALL_DIR=\${prefix}/share/java
 753         JNI_INSTALL_DIR=\${libdir}
 754
 755         dnl JNI version.
 756         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 757         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 758         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 759         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 760     fi
 761 fi
 762
 763 AC_SUBST(JAVA_HOME)
 764 AC_SUBST(JAVA)
 765 AC_SUBST(JAVAC)
 766 AC_SUBST(JAVAH)
 767 AC_SUBST(JAVADOC)
 768 AC_SUBST(JAR)
 769 AC_SUBST(JNI_CFLAGS)
 770 AC_SUBST(JAVAC_FLAGS)
 771 AC_SUBST(JAR_INSTALL_DIR)
 772 AC_SUBST(JNI_INSTALL_DIR)
 773 AC_SUBST(JNI_VERSION_INFO)
 774
 775 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 776
 777 dnl Check for Haskell (GHC).
 778 GHC=no
 779 AC_ARG_ENABLE([haskell],
 780         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 781         [],
 782         [enable_haskell=yes])
 783 AS_IF([test "x$enable_haskell" != "xno"],
 784         [
 785         GHC=
 786         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 787         ])
 788 AM_CONDITIONAL([HAVE_HASKELL],
 789     [test "x$GHC" != "xno"])
 790
 791 dnl PHP
 792 PHP=no
 793 AC_ARG_ENABLE([php],
 794         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 795         [],
 796         [enable_php=yes])
 797 AS_IF([test "x$enable_php" != "xno"],
 798         [
 799         PHP=
 800         AC_CHECK_PROG([PHP],[php],[php],[no])
 801         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 802         ])
 803 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 804
 805 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 806 AS_IF([test "x$PERL" != "xno"],
 807         [
 808         missing_perl_modules=no
 809         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 810             AC_MSG_CHECKING([for $pm])
 811             if ! $PERL -M$pm -e1 >/dev/null 2>&1; then
 812                 AC_MSG_RESULT([no])
 813                 missing_perl_modules=yes
 814             else
 815                 AC_MSG_RESULT([yes])
 816             fi
 817         done
 818         if test "x$missing_perl_modules" = "xyes"; then
 819             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 820         fi
 821         ])
 822
 823 AM_CONDITIONAL([HAVE_TOOLS],
 824     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 825
 826 dnl Library versioning.
 827 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 828 AC_SUBST(MAX_PROC_NR)
 829
 830 dnl Run in subdirs.
 831 if test "x$enable_daemon" = "xyes"; then
 832     AC_CONFIG_SUBDIRS([daemon])
 833 fi
 834
 835 dnl Produce output files.
 836 AC_CONFIG_HEADERS([config.h])
 837 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 838 AC_CONFIG_FILES([appliance/update.sh],
 839                 [chmod +x appliance/update.sh])
 840 AC_CONFIG_FILES([Makefile
 841                  generator/Makefile
 842                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 843                  appliance/Makefile
 844                  appliance/debian/debirf.conf
 845                  images/Makefile
 846                  capitests/Makefile
 847                  regressions/Makefile
 848                  test-tool/Makefile
 849                  ocaml/Makefile ocaml/examples/Makefile
 850                  perl/Makefile
 851                  python/Makefile
 852                  ruby/Makefile ruby/Rakefile
 853                  java/Makefile
 854                  haskell/Makefile
 855                  inspector/Makefile
 856                  tools/Makefile
 857                  libguestfs.pc
 858                  gnulib/lib/Makefile
 859                  gnulib/tests/Makefile
 860                  fuse/Makefile
 861                  po-docs/Makefile
 862                  po-docs/ja/Makefile
 863                  php/Makefile
 864                  csharp/Makefile
 865                  cat/Makefile
 866                  ocaml/META perl/Makefile.PL])
 867 AC_OUTPUT
 868
 869 dnl Produce summary.
 870 echo
 871 echo
 872 echo "------------------------------------------------------------"
 873 echo "Thank you for downloading $PACKAGE_STRING"
 874 echo
 875 echo "This is how we have configured the optional components for you today:"
 876 echo
 877 echo    "Daemon .............................. $enable_daemon"
 878 echo    "Appliance ........................... $enable_appliance"
 879 echo    "QEMU ................................ $QEMU"
 880 echo -n "OCaml bindings ...................... "
 881 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 882 echo -n "Perl bindings ....................... "
 883 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 884 echo -n "Python bindings ..................... "
 885 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 886 echo -n "Ruby bindings ....................... "
 887 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 888 echo -n "Java bindings ....................... "
 889 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 890 echo -n "Haskell bindings .................... "
 891 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 892 echo -n "PHP bindings ........................ "
 893 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 894 echo -n "virt-* tools ........................ "
 895 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 896 echo "supermin appliance .................. $enable_supermin"
 897 echo "FUSE filesystem ..................... $enable_fuse"
 898 echo
 899 echo "If any optional component is configured 'no' when you expected 'yes'"
 900 echo "then you should check the preceeding messages."
 901 echo
 902 echo "Please report bugs back to the mailing list:"
 903 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 904 echo
 905 echo "Next you should type 'make' to build the package,"
 906 echo "then 'make check' to run the tests."
 907 echo "------------------------------------------------------------"