configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [0])
  21 m4_define([libguestfs_release], [77])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 gl_EARLY
  41 gl_INIT
  42
  43 AC_PROG_LIBTOOL
  44
  45 dnl Check for basic C environment.
  46 AC_PROG_CC_STDC
  47 AC_PROG_INSTALL
  48 AC_PROG_CPP
  49
  50 AC_ARG_ENABLE([gcc-warnings],
  51   [AS_HELP_STRING([--enable-gcc-warnings],
  52                   [turn on lots of GCC warnings (for developers)])],
  53   [case $enableval in
  54      yes|no) ;;
  55      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  56    esac
  57    gl_gcc_warnings=$enableval],
  58   [gl_gcc_warnings=no]
  59 )
  60
  61 if test "$gl_gcc_warnings" = yes; then
  62   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  63   AC_SUBST([WERROR_CFLAGS])
  64
  65   nw=
  66   # This, $nw, is the list of warnings we disable.
  67   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  68   nw="$nw -Waggregate-return"       # anachronistic
  69   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  70   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  71   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  72   nw="$nw -Wcast-qual"              # Too many warnings for now
  73   nw="$nw -Wconversion"             # Too many warnings for now
  74   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  75   nw="$nw -Wsign-conversion"        # Too many warnings for now
  76   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  77   nw="$nw -Wunreachable-code"       # Too many warnings for now
  78   nw="$nw -Wpadded"                 # Our structs are not padded
  79   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  80   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  81   nw="$nw -Wvla"                    # two warnings in mount.c
  82   # things I might fix soon:
  83   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
  84   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
  85   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
  86   # ?? -Wstrict-overflow
  87   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
  88                                     # was not possible, safe to ignore
  89   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
  90
  91   gl_MANYWARN_ALL_GCC([ws])
  92   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  93   for w in $ws; do
  94     gl_WARN_ADD([$w])
  95   done
  96   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
  97   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
  98   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
  99
 100   # In spite of excluding -Wlogical-op above, it is enabled, as of
 101   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 102   gl_WARN_ADD([-Wno-logical-op])
 103
 104   gl_WARN_ADD([-fdiagnostics-show-option])
 105
 106   AC_SUBST([WARN_CFLAGS])
 107
 108   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 109   AC_DEFINE([_FORTIFY_SOURCE], [2],
 110     [enable compile-time and run-time bounds-checking, and some warnings])
 111   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 112 fi
 113
 114 AC_C_PROTOTYPES
 115 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 116
 117 AM_PROG_CC_C_O
 118
 119 dnl Check support for 64 bit file offsets.
 120 AC_SYS_LARGEFILE
 121
 122 dnl Check sizeof long.
 123 AC_CHECK_SIZEOF([long])
 124
 125 dnl Headers.
 126 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 127
 128 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 129 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 130 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 131 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 132         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 133         ])
 134
 135 dnl Check for pod2man and pod2text.
 136 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 137 test "x$POD2MAN" = "xno" &&
 138      AC_MSG_ERROR([pod2man must be installed])
 139 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 140 test "x$POD2TEXT" = "xno" &&
 141      AC_MSG_ERROR([pod2text must be installed])
 142
 143 dnl Check for mkisofs.
 144 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 145         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 146 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 147
 148 dnl Check for optional xmllint.
 149 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 150 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 151
 152 dnl Check for QEMU for running binaries on this $host_cpu, fall
 153 dnl back to basic 'qemu'.  Allow the user to override it.
 154 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 155 AC_ARG_WITH([qemu],
 156         [AS_HELP_STRING([--with-qemu],
 157           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 158         [],
 159         [with_qemu="$default_qemu"])
 160 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 161         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 162 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 163 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 164
 165 dnl Check that the chosen qemu has vmchannel support or we can
 166 dnl fallback to null vmchannel (still using SLIRP).  See the
 167 dnl discussion in the README file.
 168 if test "x$vmchannel_test" != "xno"; then
 169     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 170     if $QEMU --help | grep -sq guestfwd; then
 171         AC_MSG_RESULT([yes])
 172         vmchannel_guestfwd=guestfwd
 173     else
 174         AC_MSG_RESULT([no])
 175         # Note that this test must be conditional on the previous
 176         # test failing.  This is because recent qemu will throw
 177         # up an SDL window and hang if we try to run this test.
 178         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 179         vmchannelout=`$QEMU -net channel /dev/zero 2>&1 ||:`
 180         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 181         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 182             AC_MSG_RESULT([yes])
 183             vmchannel_guestfwd=net_channel
 184         else
 185             AC_MSG_RESULT([no])
 186             vmchannel_guestfwd=no
 187         fi
 188     fi
 189
 190     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 191     if $QEMU --help | grep -sq -- "-net user"; then
 192         AC_MSG_RESULT([yes])
 193         vmchannel_net_user=yes
 194     else
 195         AC_MSG_RESULT([no])
 196         vmchannel_net_user=no
 197     fi
 198
 199     if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
 200         AC_MSG_FAILURE(
 201 [I did not find user mode network or vmchannel support in
 202 $QEMU.
 203
 204 Either user mode networking or vmchannel support is vital for
 205 libguestfs to operate.
 206
 207 Please read the relevant section in the README file for more
 208 information about this.
 209
 210 You can override this test by setting the environment variable
 211 vmchannel_test=no  However if you don't have the right support
 212 in your qemu, then this just delays the pain.
 213
 214 If I am using the wrong qemu or you want to compile qemu from source
 215 and install it in another location, then you should configure with
 216 the --with-qemu option.
 217 ])
 218     fi
 219 fi
 220
 221 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 222 dnl ('-drive ...,if=...' option to qemu).
 223 dnl
 224 dnl NB. We will change the default in future to virtio, but at the
 225 dnl moment this causes a performance problem, RHBZ#509383.
 226 AC_ARG_WITH([drive-if],
 227         [AS_HELP_STRING([--with-drive-if],
 228           [set default driver (ide|scsi|virtio) @<:@default=ide@:>@])],
 229         [],
 230         [with_drive_if=ide])
 231 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 232
 233 dnl Set interface used by the network.  Normally you should
 234 dnl leave this at the default (virtio) but you can use the
 235 dnl alternative (ne2k_pci) because of bugs in virtio networking
 236 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 237 AC_ARG_WITH([net-if],
 238         [AS_HELP_STRING([--with-net-if],
 239           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 240         [],
 241         [with_net_if=virtio])
 242 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 243
 244 dnl Check for febootstrap etc.
 245 AC_CHECK_PROG([FEBOOTSTRAP],
 246         [febootstrap],[febootstrap],[no])
 247 if test "x$FEBOOTSTRAP" != "xno"; then
 248   AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 249         [febootstrap-run],[febootstrap-run],[no])
 250   test "x$FEBOOTSTRAP_RUN" = "xno" && \
 251      AC_MSG_ERROR([febootstrap-run must be installed])
 252   AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 253         [febootstrap-install],[febootstrap-install],[no])
 254   test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 255      AC_MSG_ERROR([febootstrap-install must be installed])
 256   AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 257         [febootstrap-minimize],[febootstrap-minimize],[no])
 258   test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 259      AC_MSG_ERROR([febootstrap-minimize must be installed])
 260   AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 261         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 262   test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 263      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 264
 265   dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 266   dnl of febootstrap, but old versions will fail with yum).
 267   AC_CHECK_PROG([FAKECHROOT],
 268         [fakechroot],[fakechroot],[no])
 269   test "x$FAKECHROOT" = "xno" && \
 270     AC_MSG_ERROR([fakechroot must be installed])
 271
 272   AC_MSG_CHECKING([fakechroot version])
 273   fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 274   if test -z "$fakechroot_version"; then
 275     AC_MSG_RESULT([failed])
 276     AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 277   else
 278     AC_MSG_RESULT([$fakechroot_version])
 279     fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 280     fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 281     if test "$fakechroot_major" -lt 2 -o \
 282             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 283         AC_MSG_ERROR([fakechroot version must be >= 2.9])
 284     fi
 285   fi
 286   DIST="REDHAT"
 287 else
 288   # check for debootstrap and debirf
 289   AC_CHECK_PROG([DEBOOTSTRAP],
 290         [debootstrap],[debootstrap],[no])
 291   test "x$DEBOOTSTRAP" = "xno" && \
 292         AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 293   AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 294   test "x$DEBIRF" = "xno" &&
 295         AC_MSG_ERROR([debirf must be installed])
 296   DIST="DEBIAN"
 297   case "$host_cpu" in
 298       *86)
 299           DEBIAN_KERNEL_ARCH=486
 300           ;;
 301       x86_64)
 302           DEBIAN_KERNEL_ARCH=amd64
 303           ;;
 304       *)
 305          DEBIAN_KERNEL_ARCH=$host_cpu
 306          ;;
 307    esac
 308    AC_SUBST(DEBIAN_KERNEL_ARCH)
 309 fi
 310 AC_SUBST(DIST)
 311
 312
 313 dnl --with-repo to specify a Fedora repository.
 314 AC_ARG_WITH([repo],
 315         [AS_HELP_STRING([--with-repo],
 316           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 317         [],
 318         [with_repo=fedora-11])
 319 REPO="$with_repo"
 320 AC_SUBST(REPO)
 321 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 322
 323 dnl --with-updates to specify a Fedora updates repository.
 324 AC_ARG_WITH([updates],
 325         [AS_HELP_STRING([--with-updates],
 326           [set name of Fedora updates repository @<:@default=updates-released-f11@:>@])],
 327         [],
 328         [with_updates=updates-released-f11])
 329 UPDATES="$with_updates"
 330 AC_SUBST(UPDATES)
 331
 332 dnl Define a symbol for the host CPU architecture.
 333 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 334
 335 dnl --with-mirror to specify a local Fedora mirror.
 336 AC_ARG_WITH([mirror],
 337         [AS_HELP_STRING([--with-mirror],
 338           [set URI of a local Fedora mirror])],
 339         [],
 340         [with_mirror=])
 341 MIRROR="$with_mirror"
 342 AC_SUBST(MIRROR)
 343
 344 dnl Build the supermin appliance?  Please see README file before
 345 dnl enabling this option.
 346 AC_ARG_ENABLE([supermin],
 347         [AS_HELP_STRING([--enable-supermin],
 348           [enable supermin appliance (see README) @<:@default=no@:>@])],
 349         [],
 350         [enable_supermin=no])
 351 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 352
 353 if test "x$enable_supermin" = "xyes"; then
 354     dnl Check febootstrap-to-initramfs accepts the --files option
 355     dnl (febootstrap >= 2.2).
 356     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 357     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 358     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 359     if ! echo "$out" | grep -sq -e --files ; then
 360         AC_MSG_RESULT([no])
 361         AC_MSG_FAILURE(
 362 [febootstrap-to-initramfs does not support the --files option.
 363
 364 To build the supermin appliance, you need to upgrade to the latest
 365 version of febootstrap.
 366 ])
 367     fi
 368     AC_MSG_RESULT([yes])
 369
 370     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 371     dnl (febootstrap >= 2.3).
 372     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 373     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 374     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 375     if ! echo "$out" | grep -sq -e --nocompress ; then
 376         AC_MSG_RESULT([no])
 377         AC_MSG_FAILURE(
 378 [febootstrap-to-initramfs does not support the --nocompress option.
 379
 380 To build the supermin appliance, you need to upgrade to the latest
 381 version of febootstrap.
 382 ])
 383     fi
 384     AC_MSG_RESULT([yes])
 385 fi
 386
 387 dnl Enable packet dumps when in verbose mode.  This generates lots
 388 dnl of debug info, only useful for people debugging the RPC mechanism.
 389 AC_ARG_ENABLE([packet-dump],
 390         [AS_HELP_STRING([--enable-packet-dump],
 391           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 392         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 393         [])
 394
 395 dnl Readline.
 396 AC_ARG_WITH([readline],
 397     [AS_HELP_STRING([--with-readline],
 398         [support fancy command line editing @<:@default=check@:>@])],
 399     [],
 400     [with_readline=check])
 401
 402 LIBREADLINE=
 403 AS_IF([test "x$with_readline" != xno],
 404     [AC_CHECK_LIB([readline], [main],
 405         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 406          AC_DEFINE([HAVE_LIBREADLINE], [1],
 407                    [Define if you have libreadline])
 408         ],
 409         [if test "x$with_readline" != xcheck; then
 410          AC_MSG_FAILURE(
 411              [--with-readline was given, but test for readline failed])
 412          fi
 413         ], -lncurses)])
 414
 415 dnl For i18n.
 416 AM_GNU_GETTEXT([external])
 417 AM_GNU_GETTEXT_VERSION([0.17])
 418
 419 dnl libxml2 is used by the hivex library.
 420 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0])
 421 AC_SUBST([LIBXML2_CFLAGS])
 422 AC_SUBST([LIBXML2_LIBS])
 423
 424 dnl FUSE is optional to build the FUSE module.
 425 HAVE_FUSE=yes
 426 PKG_CHECK_MODULES([FUSE],[fuse],,[
 427         HAVE_FUSE=no
 428         AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
 429 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
 430
 431 dnl Check for OCaml (optional, for OCaml bindings).
 432 AC_PROG_OCAML
 433 AC_PROG_FINDLIB
 434 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 435
 436 dnl Optional xml-light for building virt-inspector language bindings
 437 dnl from the virt-inspector.rng file.
 438 OCAML_PKG_xml_light=no
 439 if test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"; then
 440     AC_CHECK_OCAML_PKG([xml-light])
 441 fi
 442 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 443
 444 dnl Build the OCaml viewer example.  This has a lengthy list of
 445 dnl dependencies and we don't attempt to detect them all.  Read
 446 dnl the top of ocaml/examples/viewer.ml before enabling this.
 447 AC_ARG_ENABLE([ocaml-viewer],
 448         [AS_HELP_STRING([--enable-ocaml-viewer],
 449           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 450         [],
 451         [enable_ocaml_viewer=no])
 452 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 453
 454 dnl Check for Perl (optional, for Perl bindings).
 455 dnl XXX This isn't quite right, we should check for Perl devel library.
 456 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 457
 458 dnl Check for Perl modules that must be present to compile and
 459 dnl test the Perl bindings.
 460 missing_perl_modules=no
 461 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 462     AC_MSG_CHECKING([for $pm])
 463     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 464         AC_MSG_RESULT([no])
 465         missing_perl_modules=yes
 466     else
 467         AC_MSG_RESULT([yes])
 468     fi
 469 done
 470 if test "x$missing_perl_modules" = "xyes"; then
 471     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 472 fi
 473
 474 AM_CONDITIONAL([HAVE_PERL],
 475     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 476
 477 dnl Check for Python (optional, for Python bindings).
 478 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 479
 480 PYTHON_PREFIX=
 481 PYTHON_VERSION=
 482 PYTHON_INCLUDEDIR=
 483 PYTHON_SITE_PACKAGES=
 484
 485 if test "x$PYTHON" != "xno"; then
 486     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 487     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 488     for d in \
 489         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 490         /usr/include/python$PYTHON_VERSION \
 491         /usr/local/include/python$PYTHON_VERSION
 492     do
 493         AC_MSG_CHECKING([Python.h in $d])
 494         if test -r "$d/Python.h"; then
 495             AC_MSG_RESULT([found])
 496             PYTHON_INCLUDEDIR=$d
 497             break
 498         fi
 499         AC_MSG_RESULT([not found])
 500     done
 501     for d in \
 502         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 503         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 504         /usr/lib64/python$PYTHON_VERSION/site-packages \
 505         /usr/lib/python$PYTHON_VERSION/site-packages \
 506         /usr/local/lib/python$PYTHON_VERSION/site-packages
 507     do
 508         AC_MSG_CHECKING([for $d])
 509         if test -d "$d"; then
 510             AC_MSG_RESULT([found])
 511             PYTHON_SITE_PACKAGES=$d
 512             break
 513         fi
 514         AC_MSG_RESULT([not found])
 515     done
 516 fi
 517
 518 AC_SUBST(PYTHON_PREFIX)
 519 AC_SUBST(PYTHON_VERSION)
 520 AC_SUBST(PYTHON_INCLUDEDIR)
 521 AC_SUBST(PYTHON_SITE_PACKAGES)
 522
 523 AM_CONDITIONAL([HAVE_PYTHON],
 524     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 525
 526 dnl Check for Ruby and rake (optional, for Ruby bindings).
 527 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 528 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 529
 530 AM_CONDITIONAL([HAVE_RUBY],
 531     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 532
 533 dnl Check for Java.
 534 AC_ARG_WITH(java_home,
 535     [AS_HELP_STRING([--with-java-home],
 536         [specify path to JDK directory @<:@default=check@:>@])],
 537     [],
 538     [with_java_home=check])
 539
 540 if test "x$with_java_home" != "xno"; then
 541     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 542     then
 543         # Reject unsafe characters in $JAVA_HOME
 544         jh_lf='
 545 '
 546         case $JAVA_HOME in
 547           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 548             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 549         esac
 550         if test -d "$with_java_home"; then
 551             JAVA_HOME="$with_java_home"
 552         else
 553             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 554         fi
 555     fi
 556
 557     if test "x$JAVA_HOME" = "x"; then
 558         # Look for Java in some likely locations.
 559         for d in \
 560             /usr/lib/jvm/java \
 561             /usr/lib/jvm/java-6-openjdk
 562         do
 563             if test -d $d -a -f $d/bin/java; then
 564                 JAVA_HOME=$d
 565                 break
 566             fi
 567         done
 568     fi
 569
 570     if test "x$JAVA_HOME" != "x"; then
 571         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 572         if test ! -x "$JAVA_HOME/bin/java"; then
 573             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 574         else
 575             JAVA="$JAVA_HOME/bin/java"
 576         fi
 577         if test ! -x "$JAVA_HOME/bin/javac"; then
 578             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 579         else
 580             JAVAC="$JAVA_HOME/bin/javac"
 581         fi
 582         if test ! -x "$JAVA_HOME/bin/javah"; then
 583             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 584         else
 585             JAVAH="$JAVA_HOME/bin/javah"
 586         fi
 587         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 588             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 589         else
 590             JAVADOC="$JAVA_HOME/bin/javadoc"
 591         fi
 592         if test ! -x "$JAVA_HOME/bin/jar"; then
 593             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 594         else
 595             JAR="$JAVA_HOME/bin/jar"
 596         fi
 597         java_version=`$JAVA -version 2>&1 | grep "java version"`
 598         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 599
 600         dnl Find jni.h.
 601         AC_MSG_CHECKING([for jni.h])
 602         if test -f "$JAVA_HOME/include/jni.h"; then
 603             JNI_CFLAGS="-I$JAVA_HOME/include"
 604         else
 605             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 606                 head=`find $JAVA_HOME -name jni.h | tail -1`
 607                 dir=`dirname "$head"`
 608                 JNI_CFLAGS="-I$dir"
 609             else
 610                 AC_MSG_FAILURE([missing jni.h header file])
 611             fi
 612         fi
 613         AC_MSG_RESULT([$JNI_CFLAGS])
 614
 615         dnl Find jni_md.h.
 616         AC_MSG_CHECKING([for jni_md.h])
 617         case "$build_os" in
 618         *linux*) system="linux" ;;
 619         *SunOS*) system="solaris" ;;
 620         *cygwin*) system="win32" ;;
 621         *) system="$build_os" ;;
 622         esac
 623         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 624             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 625         else
 626             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 627                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 628                 dir=`dirname "$head"`
 629                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 630             else
 631                 AC_MSG_FAILURE([missing jni_md.h header file])
 632             fi
 633         fi
 634         AC_MSG_RESULT([$JNI_CFLAGS])
 635
 636         dnl Need extra version flag?
 637         AC_MSG_CHECKING([extra javac flags])
 638         JAVAC_FLAGS=
 639         javac_version=`$JAVAC -version 2>&1`
 640         case "$javac_version" in
 641         *Eclipse*)
 642             JAVAC_FLAGS="-source 1.5" ;;
 643         esac
 644         AC_MSG_RESULT([$JAVAC_FLAGS])
 645
 646         dnl Where to install jarfiles.
 647         dnl XXX How to make it configurable?
 648         JAR_INSTALL_DIR=\${prefix}/share/java
 649         JNI_INSTALL_DIR=\${libdir}
 650
 651         dnl JNI version.
 652         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 653         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 654         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 655         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 656     fi
 657 fi
 658
 659 AC_SUBST(JAVA_HOME)
 660 AC_SUBST(JAVA)
 661 AC_SUBST(JAVAC)
 662 AC_SUBST(JAVAH)
 663 AC_SUBST(JAVADOC)
 664 AC_SUBST(JAR)
 665 AC_SUBST(JNI_CFLAGS)
 666 AC_SUBST(JAVAC_FLAGS)
 667 AC_SUBST(JAR_INSTALL_DIR)
 668 AC_SUBST(JNI_INSTALL_DIR)
 669 AC_SUBST(JNI_VERSION_INFO)
 670
 671 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 672
 673 dnl Check for Haskell (GHC).
 674 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 675
 676 AM_CONDITIONAL([HAVE_HASKELL],
 677     [test "x$GHC" != "xno"])
 678
 679 dnl Check for Perl modules needed by virt-df, inspector, etc.
 680 missing_perl_modules=no
 681 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain; do
 682     AC_MSG_CHECKING([for $pm])
 683     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 684         AC_MSG_RESULT([no])
 685         missing_perl_modules=yes
 686     else
 687         AC_MSG_RESULT([yes])
 688     fi
 689 done
 690 if test "x$missing_perl_modules" = "xyes"; then
 691     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 692 fi
 693
 694 AM_CONDITIONAL([HAVE_INSPECTOR],
 695     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 696 AM_CONDITIONAL([HAVE_TOOLS],
 697     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 698
 699 dnl Library versioning.
 700 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 701 AC_SUBST(MAX_PROC_NR)
 702
 703 dnl Run in subdirs.
 704 AC_CONFIG_SUBDIRS([daemon])
 705
 706 dnl Produce output files.
 707 AC_CONFIG_HEADERS([config.h])
 708 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 709 AC_CONFIG_FILES([appliance/update.sh],
 710                 [chmod +x appliance/update.sh])
 711 AC_CONFIG_FILES([appliance/supermin-split.sh],
 712                 [chmod +x appliance/supermin-split.sh])
 713 AC_CONFIG_FILES([appliance/supermin-make.sh],
 714                 [chmod +x appliance/supermin-make.sh])
 715 AC_CONFIG_FILES([appliance/libguestfs-supermin-helper],
 716                 [chmod +x appliance/libguestfs-supermin-helper])
 717 AC_CONFIG_FILES([Makefile
 718                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 719                  appliance/Makefile
 720                  appliance/debian/debirf.conf
 721                  images/Makefile
 722                  capitests/Makefile
 723                  regressions/Makefile
 724                  test-tool/Makefile
 725                  ocaml/Makefile ocaml/examples/Makefile
 726                  perl/Makefile
 727                  python/Makefile
 728                  ruby/Makefile ruby/Rakefile
 729                  java/Makefile
 730                  haskell/Makefile
 731                  inspector/Makefile
 732                  tools/Makefile
 733                  libguestfs.pc
 734                  gnulib/lib/Makefile
 735                  gnulib/tests/Makefile
 736                  hivex/Makefile
 737                  fuse/Makefile
 738                  ocaml/META perl/Makefile.PL])
 739 AC_OUTPUT
 740
 741 dnl Produce summary.
 742 echo
 743 echo
 744 echo "------------------------------------------------------------"
 745 echo "Thank you for downloading $PACKAGE_STRING"
 746 echo
 747 echo "This is how we have configured the optional components for you today:"
 748 echo
 749 echo    "QEMU ................................ $QEMU"
 750 echo -n "OCaml bindings ...................... "
 751 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 752 echo -n "Perl bindings ....................... "
 753 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 754 echo -n "Python bindings ..................... "
 755 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 756 echo -n "Ruby bindings ....................... "
 757 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 758 echo -n "Java bindings ....................... "
 759 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 760 echo -n "Haskell bindings .................... "
 761 if test "x$HAVE_HASKELL" = "x"; then echo "yes"; else echo "no"; fi
 762 echo -n "virt-inspector ...................... "
 763 if test "x$HAVE_INSPECTOR" = "x"; then echo "yes"; else echo "no"; fi
 764 echo -n "virt-* tools ........................ "
 765 if test "x$HAVE_TOOLS" = "x"; then echo "yes"; else echo "no"; fi
 766 echo "supermin appliance .................. $enable_supermin"
 767 echo "FUSE filesystem ..................... $HAVE_FUSE"
 768 echo
 769 echo "If any optional component is configured 'no' when you expected 'yes'"
 770 echo "then you should check the preceeding messages."
 771 echo
 772 echo "Please report bugs back to the mailing list:"
 773 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 774 echo
 775 echo "Next you should type 'make' to build the package,"
 776 echo "then 'make check' to run the tests."
 777 echo "------------------------------------------------------------"