configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 AC_INIT([libguestfs],[1.0.39])
  19 AM_INIT_AUTOMAKE
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_PROG_LIBTOOL
  24
  25 dnl Check for basic C environment.
  26 AC_PROG_CC_STDC
  27 AC_PROG_INSTALL
  28 AC_PROG_CPP
  29
  30 AC_C_PROTOTYPES
  31 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
  32
  33 AM_PROG_CC_C_O
  34
  35 dnl Check support for 64 bit file offsets.
  36 AC_SYS_LARGEFILE
  37
  38 dnl Check sizeof long.
  39 AC_CHECK_SIZEOF([long])
  40
  41 dnl Headers.
  42 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h])
  43
  44 dnl Check for rpcgen and XDR library.  rpcgen is optional.
  45 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
  46 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
  47 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
  48         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
  49         ])
  50
  51 dnl Check for pod2man and pod2text.
  52 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
  53 test "x$POD2MAN" = "xno" &&
  54      AC_MSG_ERROR([pod2man must be installed])
  55 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
  56 test "x$POD2TEXT" = "xno" &&
  57      AC_MSG_ERROR([pod2text must be installed])
  58
  59 dnl Check for mksquashfs.
  60 AC_PATH_PROGS([MKSQUASHFS],[mksquashfs],[no],
  61         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
  62 test "x$MKSQUASHFS" = "xno" && AC_MSG_ERROR([mksquashfs must be installed])
  63
  64 dnl Check for QEMU for running binaries on this $host_cpu, fall
  65 dnl back to basic 'qemu'.  Allow the user to override it.
  66 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
  67 AC_ARG_WITH([qemu],
  68         [AS_HELP_STRING([--with-qemu],
  69           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
  70         [],
  71         [with_qemu="$default_qemu"])
  72 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
  73         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
  74 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
  75 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
  76
  77 dnl Check that the chosen qemu has vmchannel support.
  78 dnl http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
  79 if test "x$vmchannel_test" != "xno"; then
  80     AC_MSG_CHECKING([for vmchannel support in $QEMU])
  81     vmchannelout=`$QEMU -net channel /dev/zero 2>&1 ||:`
  82     echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
  83     if ! echo $vmchannelout | grep -sq "vmchannel wrong port number" ; then
  84         AC_MSG_RESULT([no])
  85         AC_MSG_FAILURE(
  86 [I did not find vmchannel support in $QEMU.
  87
  88 vmchannel support is vital for libguestfs to operate.  You need a version
  89 of qemu >= 0.10, or the following patch backported to earlier versions:
  90
  91 http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
  92
  93 You can override this test by setting the environment variable
  94 vmchannel_test=no  However if you don't have vmchannel support
  95 in your qemu, then this just delays the pain.
  96
  97 If I am using the wrong qemu or you want to compile qemu from source
  98 and install it in another location, then you should configure with
  99 the --with-qemu option.
 100 ])
 101     fi
 102     AC_MSG_RESULT([yes])
 103 fi
 104
 105 dnl Check for febootstrap etc.
 106 AC_CHECK_PROG([FEBOOTSTRAP],
 107         [febootstrap],[febootstrap],[no])
 108 test "x$FEBOOTSTRAP" = "xno" && \
 109      AC_MSG_ERROR([febootstrap must be installed])
 110 AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 111         [febootstrap-run],[febootstrap-run],[no])
 112 test "x$FEBOOTSTRAP_RUN" = "xno" && \
 113      AC_MSG_ERROR([febootstrap-run must be installed])
 114 AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 115         [febootstrap-install],[febootstrap-install],[no])
 116 test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 117      AC_MSG_ERROR([febootstrap-install must be installed])
 118 AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 119         [febootstrap-minimize],[febootstrap-minimize],[no])
 120 test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 121      AC_MSG_ERROR([febootstrap-minimize must be installed])
 122 AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 123         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 124 test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 125      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 126
 127 dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 128 dnl of febootstrap, but old versions will fail with yum).
 129 AC_CHECK_PROG([FAKECHROOT],
 130         [fakechroot],[fakechroot],[no])
 131 test "x$FAKECHROOT" = "xno" && \
 132     AC_MSG_ERROR([fakechroot must be installed])
 133
 134 AC_MSG_CHECKING([fakechroot version])
 135 fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 136 if test -z "$fakechroot_version"; then
 137     AC_MSG_RESULT([failed])
 138     AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 139 else
 140     AC_MSG_RESULT([$fakechroot_version])
 141     fakechroot_major=`echo $fakechroot_version | awk -F. '{print $1}'`
 142     fakechroot_minor=`echo $fakechroot_version | awk -F. '{print $2}'`
 143     if test "$fakechroot_major" -lt 2 -o \
 144             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 145         AC_MSG_ERROR([fakechroot version must be >= 2.9])
 146     fi
 147 fi
 148
 149 dnl --with-repo to specify a Fedora repository.
 150 AC_ARG_WITH([repo],
 151         [AS_HELP_STRING([--with-repo],
 152           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 153         [],
 154         [with_repo=fedora-11])
 155 REPO="$with_repo"
 156 AC_SUBST(REPO)
 157 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 158
 159 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 160
 161 dnl --with-updates to specify a Fedora updates repository.
 162 AC_ARG_WITH([updates],
 163         [AS_HELP_STRING([--with-updates],
 164           [set name of Fedora updates repository @<:@default=updates-released-f11@:>@])],
 165         [],
 166         [with_updates=updates-released-f11])
 167 UPDATES="$with_updates"
 168 AC_SUBST(UPDATES)
 169 AC_DEFINE_UNQUOTED([UPDATES],["$UPDATES"],[Name of Fedora updates repository.])
 170
 171 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 172
 173 dnl --with-mirror to specify a local Fedora mirror.
 174 AC_ARG_WITH([mirror],
 175         [AS_HELP_STRING([--with-mirror],
 176           [set URI of a local Fedora mirror])],
 177         [],
 178         [with_mirror=])
 179 MIRROR="$with_mirror"
 180 AC_SUBST(MIRROR)
 181
 182 dnl Readline.
 183 AC_ARG_WITH([readline],
 184     [AS_HELP_STRING([--with-readline],
 185         [support fancy command line editing @<:@default=check@:>@])],
 186     [],
 187     [with_readline=check])
 188
 189 LIBREADLINE=
 190 AS_IF([test "x$with_readline" != xno],
 191     [AC_CHECK_LIB([readline], [main],
 192         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 193          AC_DEFINE([HAVE_LIBREADLINE], [1],
 194                    [Define if you have libreadline])
 195         ],
 196         [if test "x$with_readline" != xcheck; then
 197          AC_MSG_FAILURE(
 198              [--with-readline was given, but test for readline failed])
 199          fi
 200         ], -lncurses)])
 201
 202 dnl For i18n.
 203 AM_GNU_GETTEXT([external])
 204 AM_GNU_GETTEXT_VERSION([0.14])
 205
 206 dnl Check for OCaml (optional, for OCaml bindings).
 207 AC_PROG_OCAML
 208 AC_PROG_FINDLIB
 209 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 210
 211 dnl Check for Perl (optional, for Perl bindings).
 212 dnl XXX This isn't quite right, we should check for Perl devel library.
 213 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 214
 215 dnl Check for Perl modules that must be present to compile and
 216 dnl test the Perl bindings.
 217 missing_perl_modules=no
 218 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 219     AC_MSG_CHECKING([for $pm])
 220     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 221         AC_MSG_RESULT([no])
 222         missing_perl_modules=yes
 223     else
 224         AC_MSG_RESULT([yes])
 225     fi
 226 done
 227 if test "x$missing_perl_modules" = "xyes"; then
 228     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 229 fi
 230
 231 AM_CONDITIONAL([HAVE_PERL],
 232     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 233
 234 dnl Check for Python (optional, for Python bindings).
 235 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 236
 237 PYTHON_PREFIX=
 238 PYTHON_VERSION=
 239 PYTHON_INCLUDEDIR=
 240 PYTHON_SITE_PACKAGES=
 241
 242 if test "x$PYTHON" != "xno"; then
 243     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 244     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 245     for d in \
 246         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 247         /usr/include/python$PYTHON_VERSION \
 248         /usr/local/include/python$PYTHON_VERSION
 249     do
 250         AC_MSG_CHECKING([Python.h in $d])
 251         if test -r "$d/Python.h"; then
 252             AC_MSG_RESULT([found])
 253             PYTHON_INCLUDEDIR=$d
 254             break
 255         fi
 256         AC_MSG_RESULT([not found])
 257     done
 258     for d in \
 259         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 260         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 261         /usr/lib64/python$PYTHON_VERSION/site-packages \
 262         /usr/lib/python$PYTHON_VERSION/site-packages \
 263         /usr/local/lib/python$PYTHON_VERSION/site-packages
 264     do
 265         AC_MSG_CHECKING([for $d])
 266         if test -d "$d"; then
 267             AC_MSG_RESULT([found])
 268             PYTHON_SITE_PACKAGES=$d
 269             break
 270         fi
 271         AC_MSG_RESULT([not found])
 272     done
 273 fi
 274
 275 AC_SUBST(PYTHON_PREFIX)
 276 AC_SUBST(PYTHON_VERSION)
 277 AC_SUBST(PYTHON_INCLUDEDIR)
 278 AC_SUBST(PYTHON_SITE_PACKAGES)
 279
 280 AM_CONDITIONAL([HAVE_PYTHON],
 281     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 282
 283 dnl Check for Ruby and rake (optional, for Ruby bindings).
 284 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 285 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 286
 287 AM_CONDITIONAL([HAVE_RUBY],
 288     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 289
 290 dnl Check for Java.
 291 AC_ARG_WITH(java_home,
 292     [AS_HELP_STRING([--with-java-home],
 293         [specify path to JDK directory @<:@default=check@:>@])],
 294     [],
 295     [with_java_home=check])
 296
 297 if test "x$with_java_home" != "xno"; then
 298     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 299     then
 300         if test -d "$with_java_home"; then
 301             JAVA_HOME="$with_java_home"
 302         else
 303             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 304         fi
 305     fi
 306
 307     if test "x$JAVA_HOME" = "x"; then
 308         # Look for Java in some likely locations.
 309         for d in \
 310             /usr/lib/jvm/java \
 311             /usr/lib/jvm/java-6-openjdk
 312         do
 313             if test -d $d -a -f $d/bin/java; then
 314                 JAVA_HOME=$d
 315                 break
 316             fi
 317         done
 318     fi
 319
 320     if test "x$JAVA_HOME" != "x"; then
 321         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 322         if test ! -x "$JAVA_HOME/bin/java"; then
 323             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 324         else
 325             JAVA="$JAVA_HOME/bin/java"
 326         fi
 327         if test ! -x "$JAVA_HOME/bin/javac"; then
 328             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 329         else
 330             JAVAC="$JAVA_HOME/bin/javac"
 331         fi
 332         if test ! -x "$JAVA_HOME/bin/javah"; then
 333             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 334         else
 335             JAVAH="$JAVA_HOME/bin/javah"
 336         fi
 337         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 338             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 339         else
 340             JAVADOC="$JAVA_HOME/bin/javadoc"
 341         fi
 342         if test ! -x "$JAVA_HOME/bin/jar"; then
 343             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 344         else
 345             JAR="$JAVA_HOME/bin/jar"
 346         fi
 347         java_version=`$JAVA -version 2>&1 | grep "java version"`
 348         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 349
 350         dnl Find jni.h.
 351         AC_MSG_CHECKING([for jni.h])
 352         if test -f "$JAVA_HOME/include/jni.h"; then
 353             JNI_CFLAGS="-I$JAVA_HOME/include"
 354         else
 355             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 356                 head=`find $JAVA_HOME -name jni.h | tail -1`
 357                 dir=`dirname $head`
 358                 JNI_CFLAGS="-I$dir"
 359             else
 360                 AC_MSG_FAILURE([missing jni.h header file])
 361             fi
 362         fi
 363         AC_MSG_RESULT([$JNI_CFLAGS])
 364
 365         dnl Find jni_md.h.
 366         AC_MSG_CHECKING([for jni_md.h])
 367         case "$build_os" in
 368         *linux*) system="linux" ;;
 369         *SunOS*) system="solaris" ;;
 370         *cygwin*) system="win32" ;;
 371         *) system="$build_os" ;;
 372         esac
 373         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 374             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 375         else
 376             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 377                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 378                 dir=`dirname $head`
 379                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 380             else
 381                 AC_MSG_FAILURE([missing jni_md.h header file])
 382             fi
 383         fi
 384         AC_MSG_RESULT([$JNI_CFLAGS])
 385
 386         dnl Need extra version flag?
 387         AC_MSG_CHECKING([extra javac flags])
 388         JAVAC_FLAGS=
 389         javac_version=`$JAVAC -version 2>&1`
 390         case "$javac_version" in
 391         *Eclipse*)
 392             JAVAC_FLAGS="-source 1.5" ;;
 393         esac
 394         AC_MSG_RESULT([$JAVAC_FLAGS])
 395
 396         dnl Where to install jarfiles.
 397         dnl XXX How to make it configurable?
 398         JAR_INSTALL_DIR=\${prefix}/share/java
 399         JNI_INSTALL_DIR=\${libdir}
 400
 401         dnl JNI version.
 402         jni_major_version=`echo $VERSION | awk -F. '{print $1}'`
 403         jni_minor_version=`echo $VERSION | awk -F. '{print $2}'`
 404         jni_micro_version=`echo $VERSION | awk -F. '{print $3}'`
 405         JNI_VERSION_INFO=`expr $jni_major_version + $jni_minor_version`:$jni_micro_version:$jni_minor_version
 406     fi
 407 fi
 408
 409 AC_SUBST(JAVA_HOME)
 410 AC_SUBST(JAVA)
 411 AC_SUBST(JAVAC)
 412 AC_SUBST(JAVAH)
 413 AC_SUBST(JAVADOC)
 414 AC_SUBST(JAR)
 415 AC_SUBST(JNI_CFLAGS)
 416 AC_SUBST(JAVAC_FLAGS)
 417 AC_SUBST(JAR_INSTALL_DIR)
 418 AC_SUBST(JNI_INSTALL_DIR)
 419 AC_SUBST(JNI_VERSION_INFO)
 420
 421 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 422
 423 dnl Check for Haskell (GHC).
 424 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 425
 426 AM_CONDITIONAL([HAVE_HASKELL],
 427     [test "x$GHC" != "xno"])
 428
 429 dnl Check for Perl modules needed by the inspector.
 430 missing_perl_modules=no
 431 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper; do
 432     AC_MSG_CHECKING([for $pm])
 433     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 434         AC_MSG_RESULT([no])
 435         missing_perl_modules=yes
 436     else
 437         AC_MSG_RESULT([yes])
 438     fi
 439 done
 440 if test "x$missing_perl_modules" = "xyes"; then
 441     AC_MSG_WARN([some Perl modules required to compile virt-inspector are missing])
 442 fi
 443
 444 AM_CONDITIONAL([HAVE_INSPECTOR],
 445     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 446
 447 dnl Run in subdirs.
 448 AC_CONFIG_SUBDIRS([daemon])
 449
 450 dnl Produce output files.
 451 AC_CONFIG_HEADERS([config.h])
 452 AC_CONFIG_FILES([Makefile
 453                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 454                  appliance/Makefile
 455                  appliance/make-initramfs.sh appliance/update-initramfs.sh
 456                  images/Makefile
 457                  capitests/Makefile
 458                  ocaml/Makefile ocaml/examples/Makefile
 459                  perl/Makefile
 460                  python/Makefile
 461                  ruby/Makefile ruby/Rakefile
 462                  java/Makefile
 463                  haskell/Makefile
 464                  inspector/Makefile
 465                  libguestfs.pc
 466                  ocaml/META perl/Makefile.PL])
 467 AC_OUTPUT
 468
 469 dnl WTF?
 470 chmod +x appliance/make-initramfs.sh appliance/update-initramfs.sh
 471
 472 dnl Produce summary.
 473 echo
 474 echo
 475 echo "------------------------------------------------------------"
 476 echo "Thank you for downloading $PACKAGE_STRING"
 477 echo
 478 echo "This is how we have configured the optional components for you today:"
 479 echo
 480 echo    "QEMU ................................ $QEMU"
 481 echo -n "OCaml bindings ...................... "
 482 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 483 echo -n "Perl bindings ....................... "
 484 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 485 echo -n "Python bindings ..................... "
 486 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 487 echo -n "Ruby bindings ....................... "
 488 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 489 echo -n "Java bindings ....................... "
 490 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 491 echo -n "Haskell bindings .................... "
 492 if test "x$HAVE_HASKELL" = "x"; then echo "yes"; else echo "no"; fi
 493 echo -n "virt-inspector ...................... "
 494 if test "x$HAVE_INSPECTOR" = "x"; then echo "yes"; else echo "no"; fi
 495 echo
 496 echo "If any optional component is configured 'no' when you expected 'yes'"
 497 echo "then you should check the preceeding messages."
 498 echo
 499 echo "Please report bugs back to the fedora-virt mailing list:"
 500 echo "http://www.redhat.com/mailman/listinfo/fedora-virt"
 501 echo
 502 echo "Next you should type 'make' to build the package,"
 503 echo "then 'make check' to run the tests."
 504 echo "------------------------------------------------------------"