configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [7])
  21 m4_define([libguestfs_release], [2])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Die if the user tries to configure as root, see:
  57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  58 AC_MSG_CHECKING([if you are trying to configure as root])
  59 AS_IF([test "`id -u`" = 0 ],[
  60             AC_MSG_RESULT([yes])
  61             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  62       ],[
  63             AC_MSG_RESULT([no])
  64       ])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 114                                     # was not possible, safe to ignore
 115   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 116   nw="$nw -Wlong-long"              # Allow long long since it's required
 117                                     # by Python, Ruby and xstrtoll.
 118
 119   gl_MANYWARN_ALL_GCC([ws])
 120   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 121   for w in $ws; do
 122     gl_WARN_ADD([$w])
 123   done
 124   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 125   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 126   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 127
 128   # In spite of excluding -Wlogical-op above, it is enabled, as of
 129   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 130   gl_WARN_ADD([-Wno-logical-op])
 131
 132   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 133   gl_WARN_ADD([-Wno-strict-overflow])
 134
 135   gl_WARN_ADD([-fdiagnostics-show-option])
 136
 137   AC_SUBST([WARN_CFLAGS])
 138
 139   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 140   AC_DEFINE([_FORTIFY_SOURCE], [2],
 141     [enable compile-time and run-time bounds-checking, and some warnings])
 142   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 143 fi
 144
 145 AC_C_PROTOTYPES
 146 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 147
 148 AM_PROG_CC_C_O
 149
 150 dnl Work out how to specify the linker script to the linker.
 151 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 152 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 153     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 154 AC_SUBST(VERSION_SCRIPT_FLAGS)
 155
 156 dnl Check support for 64 bit file offsets.
 157 AC_SYS_LARGEFILE
 158
 159 dnl Check sizeof long.
 160 AC_CHECK_SIZEOF([long])
 161
 162 dnl Define a C symbol for the host CPU architecture.
 163 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 164
 165 dnl Headers.
 166 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 167
 168 dnl Functions.
 169 AC_CHECK_FUNCS([posix_fallocate])
 170
 171 dnl Build the daemon?
 172 AC_MSG_CHECKING([if we should build the daemon])
 173 AC_ARG_ENABLE([daemon],
 174         [AS_HELP_STRING([--enable-daemon],
 175           [enable building the daemon @<:@default=yes@:>@])],
 176         [],
 177         [enable_daemon=yes])
 178 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 179 AC_MSG_RESULT([$enable_daemon])
 180
 181 dnl Build the appliance?
 182 AC_MSG_CHECKING([if we should build the appliance])
 183 AC_ARG_ENABLE([appliance],
 184         [AS_HELP_STRING([--enable-appliance],
 185           [enable building the appliance @<:@default=yes@:>@])],
 186         [],
 187         [enable_appliance=yes])
 188 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 189 AC_MSG_RESULT([$enable_appliance])
 190
 191 dnl Check for PCRE.
 192 AC_CHECK_LIB([pcre],[pcre_compile],
 193         [AC_SUBST([LIBPCRE], ["-lpcre"])],
 194         [AC_MSG_FAILURE(
 195              [Perl Compatible Regular Expressions library (PCRE) is required])])
 196 AC_CHECK_HEADER([pcre.h],[],
 197         [AC_MSG_FAILURE(
 198              [Perl Compatible Regular Expressions library (PCRE) header file pcre.h is required])])
 199
 200 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 201 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 202 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 203 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 204         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 205         ])
 206
 207 dnl Check for cpio which isn't in the default Pardus install amazingly.
 208 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 209 test "x$CPIO" = "xno" &&
 210      AC_MSG_ERROR([cpio must be installed])
 211
 212 dnl Check for gperf.
 213 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 214 test "x$GPERF" = "xno" &&
 215      AC_MSG_ERROR([gperf must be installed])
 216
 217 dnl Check for pod2man and pod2text.
 218 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 219 test "x$POD2MAN" = "xno" &&
 220      AC_MSG_ERROR([pod2man must be installed])
 221 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 222 test "x$POD2TEXT" = "xno" &&
 223      AC_MSG_ERROR([pod2text must be installed])
 224
 225 dnl Check for mkisofs.
 226 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 227         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 228 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 229
 230 dnl Check for optional xmllint.
 231 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 232 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 233
 234 dnl Check for QEMU for running binaries on this $host_cpu, fall
 235 dnl back to basic 'qemu'.  Allow the user to override it.
 236 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 237 AC_ARG_WITH([qemu],
 238         [AS_HELP_STRING([--with-qemu],
 239           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 240         [],
 241         [with_qemu="$default_qemu"])
 242 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 243         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 244 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 245 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 246
 247 dnl Check that the chosen qemu has virtio-serial support.
 248 if test "x$vmchannel_test" != "xno"; then
 249     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 250     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 251         AC_MSG_RESULT([yes])
 252         vmchannel_guestfwd=guestfwd
 253     else
 254         AC_MSG_RESULT([no])
 255         AC_MSG_FAILURE(
 256 [I did not find virtio-serial support in
 257 $QEMU.
 258
 259 virtio-serial support in qemu or KVM is essential for libguestfs
 260 to operate.
 261
 262 Usually this means that you have to install a newer version of qemu
 263 and/or KVM.  Please read the relevant section in the README file for
 264 more information about this.
 265
 266 You can override this test by setting the environment variable
 267 vmchannel_test=no  However if you don't have the right support
 268 in your qemu, then this just delays the pain.
 269
 270 If I am using the wrong qemu or you want to compile qemu from source
 271 and install it in another location, then you should configure with
 272 the --with-qemu option.
 273 ])
 274     fi
 275 fi
 276
 277 dnl Set default drive interface used by the guestfs_add_drive_opts call
 278 dnl ('-drive ...,if=...' option to qemu).
 279 dnl
 280 dnl If you encounter performance problems with virtio (RHBZ#509383)
 281 dnl then try '--with-drive-if=ide'.
 282 AC_ARG_WITH([drive-if],
 283         [AS_HELP_STRING([--with-drive-if],
 284           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 285         [],
 286         [with_drive_if=virtio])
 287 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 288
 289 dnl Set interface used by the network.  Normally you should
 290 dnl leave this at the default (virtio-net-pci) but you can use the
 291 dnl alternative (ne2k_pci) because of bugs in virtio networking
 292 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 293 AC_ARG_WITH([net-if],
 294         [AS_HELP_STRING([--with-net-if],
 295           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 296         [],
 297         [with_net_if=virtio-net-pci])
 298 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 299
 300 dnl Check for febootstrap etc.
 301 if test "x$enable_appliance" = "xyes"; then
 302     AC_CHECK_PROG([FEBOOTSTRAP],
 303                   [febootstrap],[febootstrap],[no])
 304     if test "x$FEBOOTSTRAP" != "xno"; then
 305       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 306                     [febootstrap-run],[febootstrap-run],[no])
 307       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 308           AC_MSG_ERROR([febootstrap-run must be installed])
 309       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 310                     [febootstrap-install],[febootstrap-install],[no])
 311       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 312           AC_MSG_ERROR([febootstrap-install must be installed])
 313       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 314                     [febootstrap-minimize],[febootstrap-minimize],[no])
 315       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 316           AC_MSG_ERROR([febootstrap-minimize must be installed])
 317       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 318                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 319       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 320           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 321       AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
 322                     [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
 323       test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
 324           AC_MSG_ERROR([febootstrap-to-supermin must be installed])
 325
 326       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 327       dnl of febootstrap, but old versions will fail with yum).
 328       AC_CHECK_PROG([FAKECHROOT],
 329                     [fakechroot],[fakechroot],[no])
 330       test "x$FAKECHROOT" = "xno" && \
 331          AC_MSG_ERROR([fakechroot must be installed])
 332
 333       AC_MSG_CHECKING([fakechroot version])
 334       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 335       if test -z "$fakechroot_version"; then
 336         AC_MSG_RESULT([failed])
 337         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 338       else
 339         AC_MSG_RESULT([$fakechroot_version])
 340         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 341         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 342         if test "$fakechroot_major" -lt 2 || \
 343           ( test "$fakechroot_major" -eq 2 && test "$fakechroot_minor" -lt 9 ); then
 344           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 345         fi
 346       fi
 347       DIST="REDHAT"
 348     else
 349       # check for debootstrap and debirf
 350       AC_CHECK_PROG([DEBOOTSTRAP],
 351                     [debootstrap],[debootstrap],[no])
 352       test "x$DEBOOTSTRAP" = "xno" && \
 353           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 354       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 355       test "x$DEBIRF" = "xno" &&
 356           AC_MSG_ERROR([debirf must be installed])
 357       DIST="DEBIAN"
 358       case "$host_cpu" in
 359       *86)
 360           DEBIAN_KERNEL_ARCH=486
 361           ;;
 362       x86_64)
 363           DEBIAN_KERNEL_ARCH=amd64
 364           ;;
 365       *)
 366          DEBIAN_KERNEL_ARCH=$host_cpu
 367          ;;
 368       esac
 369       AC_SUBST(DEBIAN_KERNEL_ARCH)
 370     fi
 371     AC_SUBST(DIST)
 372
 373     dnl --with-updates to specify a Fedora updates repository.
 374     AC_ARG_WITH([updates],
 375         [AS_HELP_STRING([--with-updates],
 376           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 377         [],
 378         [with_updates=updates-released-f12])
 379     UPDATES="$with_updates"
 380     AC_SUBST(UPDATES)
 381
 382     dnl --with-mirror to specify a local Fedora mirror.
 383     AC_ARG_WITH([mirror],
 384         [AS_HELP_STRING([--with-mirror],
 385           [set URI of a local Fedora mirror])],
 386         [],
 387         [with_mirror=])
 388     MIRROR="$with_mirror"
 389     AC_SUBST(MIRROR)
 390 fi
 391
 392 dnl --with-repo to specify a repository.
 393 AC_ARG_WITH([repo],
 394         [AS_HELP_STRING([--with-repo],
 395           [set name of Fedora repository @<:@default=fedora-13@:>@])],
 396         [],
 397         [with_repo=fedora-13])
 398 REPO="$with_repo"
 399 AC_SUBST(REPO)
 400 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of software repository.])
 401
 402 dnl Build the supermin appliance?  Please see README file before
 403 dnl enabling this option.
 404 AC_ARG_ENABLE([supermin],
 405         [AS_HELP_STRING([--enable-supermin],
 406           [enable supermin appliance (see README) @<:@default=no@:>@])],
 407         [AC_DEFINE([ENABLE_SUPERMIN],[1],[Supermin appliance enabled.])],
 408         [enable_supermin=no])
 409 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 410
 411 dnl Enable packet dumps when in verbose mode.  This generates lots
 412 dnl of debug info, only useful for people debugging the RPC mechanism.
 413 AC_ARG_ENABLE([packet-dump],
 414         [AS_HELP_STRING([--enable-packet-dump],
 415           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 416         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 417         [])
 418
 419 dnl Readline.
 420 AC_ARG_WITH([readline],
 421     [AS_HELP_STRING([--with-readline],
 422         [support fancy command line editing @<:@default=check@:>@])],
 423     [],
 424     [with_readline=check])
 425
 426 LIBREADLINE=
 427 AS_IF([test "x$with_readline" != xno],
 428     [AC_CHECK_LIB([readline], [main],
 429         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 430          AC_DEFINE([HAVE_LIBREADLINE], [1],
 431                    [Define if you have libreadline])
 432         ],
 433         [if test "x$with_readline" != xcheck; then
 434          AC_MSG_FAILURE(
 435              [--with-readline was given, but test for readline failed])
 436          fi
 437         ], -lncurses)
 438      old_LIBS="$LIBS"
 439      LIBS="$LIBS $LIBREADLINE"
 440      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 441      LIBS="$old_LIBS"
 442     ])
 443
 444 dnl For i18n.
 445 AM_GNU_GETTEXT([external])
 446 AM_GNU_GETTEXT_VERSION([0.17])
 447
 448 dnl libmagic (required)
 449 AC_CHECK_LIB([magic],[magic_file],[
 450         AC_SUBST([LIBMAGIC], ["-lmagic"])
 451     ],[
 452         AC_MSG_FAILURE([libmagic is required])
 453     ])
 454 AC_CHECK_HEADER([magic.h],[],[
 455         AC_MSG_FAILURE([magic.h header file is required])
 456     ])
 457
 458 dnl libvirt (required)
 459 PKG_CHECK_MODULES([LIBVIRT], [libvirt])
 460 AC_SUBST([LIBVIRT_CFLAGS])
 461 AC_SUBST([LIBVIRT_LIBS])
 462
 463 dnl libxml2 (required)
 464 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0])
 465 AC_SUBST([LIBXML2_CFLAGS])
 466 AC_SUBST([LIBXML2_LIBS])
 467
 468 dnl Augeas (required)
 469 PKG_CHECK_MODULES([AUGEAS], [augeas])
 470 AC_SUBST([AUGEAS_CFLAGS])
 471 AC_SUBST([AUGEAS_LIBS])
 472
 473 dnl hivex library (required)
 474 dnl This used to be a part of libguestfs, but was spun off into its
 475 dnl own separate upstream project in libguestfs 1.0.85.
 476 PKG_CHECK_MODULES([HIVEX], [hivex])
 477 AC_SUBST([HIVEX_CFLAGS])
 478 AC_SUBST([HIVEX_LIBS])
 479
 480 dnl FUSE is optional to build the FUSE module.
 481 AC_ARG_ENABLE([fuse],
 482         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 483         [],
 484         [enable_fuse=yes])
 485 AS_IF([test "x$enable_fuse" != "xno"],
 486         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 487                 enable_fuse=no
 488                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 489 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 490
 491 dnl Check for OCaml (optional, for OCaml bindings).
 492 OCAMLC=no
 493 OCAMLFIND=no
 494 OCAML_PKG_xml_light=no
 495 AC_ARG_ENABLE([ocaml],
 496         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 497         [],
 498         [enable_ocaml=yes])
 499 AS_IF([test "x$enable_ocaml" != "xno"],
 500         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 501          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 502          OCAMLC=
 503          OCAMLFIND=
 504          AC_PROG_OCAML
 505          AC_PROG_FINDLIB
 506
 507          dnl Optional xml-light for running the generator.
 508          if test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"; then
 509              AC_CHECK_OCAML_PKG([xml-light])
 510          fi])
 511 AM_CONDITIONAL([HAVE_OCAML],
 512                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 513 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 514
 515 dnl Check for Perl (optional, for Perl bindings).
 516 PERL=no
 517 AC_ARG_ENABLE([perl],
 518         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 519         [],
 520         [enable_perl=yes])
 521 AS_IF([test "x$enable_perl" != "xno"],
 522         [
 523         PERL=
 524         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 525
 526         dnl Check for Perl modules that must be present to compile and
 527         dnl test the Perl bindings.
 528         missing_perl_modules=no
 529         for pm in Test::More ExtUtils::MakeMaker; do
 530             AC_MSG_CHECKING([for $pm])
 531             if ! perl -M$pm -e1 >/dev/null 2>&1; then
 532                 AC_MSG_RESULT([no])
 533                 missing_perl_modules=yes
 534             else
 535                 AC_MSG_RESULT([yes])
 536             fi
 537         done
 538         if test "x$missing_perl_modules" = "xyes"; then
 539             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 540         fi
 541         ])
 542 AM_CONDITIONAL([HAVE_PERL],
 543     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 544
 545 dnl Check for Python (optional, for Python bindings).
 546 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 547
 548 PYTHON_PREFIX=
 549 PYTHON_VERSION=
 550 PYTHON_INCLUDEDIR=
 551 PYTHON_SITE_PACKAGES=
 552
 553 if test "x$PYTHON" != "xno"; then
 554     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 555     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 556     for d in \
 557         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 558         /usr/include/python$PYTHON_VERSION \
 559         /usr/local/include/python$PYTHON_VERSION
 560     do
 561         AC_MSG_CHECKING([Python.h in $d])
 562         if test -r "$d/Python.h"; then
 563             AC_MSG_RESULT([found])
 564             PYTHON_INCLUDEDIR=$d
 565             break
 566         fi
 567         AC_MSG_RESULT([not found])
 568     done
 569     for d in \
 570         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 571         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 572         /usr/lib64/python$PYTHON_VERSION/site-packages \
 573         /usr/lib/python$PYTHON_VERSION/site-packages \
 574         /usr/local/lib/python$PYTHON_VERSION/site-packages
 575     do
 576         AC_MSG_CHECKING([for $d])
 577         if test -d "$d"; then
 578             AC_MSG_RESULT([found])
 579             PYTHON_SITE_PACKAGES=$d
 580             break
 581         fi
 582         AC_MSG_RESULT([not found])
 583     done
 584
 585     old_LIBS="$LIBS"
 586     LIBS="$LIBS -lpython$PYTHON_VERSION"
 587     AC_CHECK_FUNCS([PyCapsule_New])
 588     LIBS="$old_LIBS"
 589 fi
 590
 591 AC_SUBST(PYTHON_PREFIX)
 592 AC_SUBST(PYTHON_VERSION)
 593 AC_SUBST(PYTHON_INCLUDEDIR)
 594 AC_SUBST(PYTHON_SITE_PACKAGES)
 595
 596 AM_CONDITIONAL([HAVE_PYTHON],
 597     [test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_SITE_PACKAGES" != "x"])
 598
 599 dnl Check for Ruby and rake (optional, for Ruby bindings).
 600 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 601 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 602
 603 AM_CONDITIONAL([HAVE_RUBY],
 604     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 605
 606 dnl Check for Java.
 607 AC_ARG_WITH(java_home,
 608     [AS_HELP_STRING([--with-java-home],
 609         [specify path to JDK directory @<:@default=check@:>@])],
 610     [],
 611     [with_java_home=check])
 612
 613 if test "x$with_java_home" != "xno"; then
 614     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 615     then
 616         # Reject unsafe characters in $JAVA_HOME
 617         jh_lf='
 618 '
 619         case $JAVA_HOME in
 620           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 621             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 622         esac
 623         if test -d "$with_java_home"; then
 624             JAVA_HOME="$with_java_home"
 625         else
 626             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 627         fi
 628     fi
 629
 630     if test "x$JAVA_HOME" = "x"; then
 631         # Look for Java in some likely locations.
 632         for d in \
 633             /usr/lib/jvm/java \
 634             /usr/lib/jvm/java-6-openjdk
 635         do
 636             if test -d $d && test -f $d/bin/java; then
 637                 JAVA_HOME=$d
 638                 break
 639             fi
 640         done
 641     fi
 642
 643     if test "x$JAVA_HOME" != "x"; then
 644         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 645         if test ! -x "$JAVA_HOME/bin/java"; then
 646             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 647         else
 648             JAVA="$JAVA_HOME/bin/java"
 649         fi
 650         if test ! -x "$JAVA_HOME/bin/javac"; then
 651             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 652         else
 653             JAVAC="$JAVA_HOME/bin/javac"
 654         fi
 655         if test ! -x "$JAVA_HOME/bin/javah"; then
 656             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 657         else
 658             JAVAH="$JAVA_HOME/bin/javah"
 659         fi
 660         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 661             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 662         else
 663             JAVADOC="$JAVA_HOME/bin/javadoc"
 664         fi
 665         if test ! -x "$JAVA_HOME/bin/jar"; then
 666             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 667         else
 668             JAR="$JAVA_HOME/bin/jar"
 669         fi
 670         java_version=`$JAVA -version 2>&1 | grep "java version"`
 671         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 672
 673         dnl Find jni.h.
 674         AC_MSG_CHECKING([for jni.h])
 675         if test -f "$JAVA_HOME/include/jni.h"; then
 676             JNI_CFLAGS="-I$JAVA_HOME/include"
 677         else
 678             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 679                 head=`find $JAVA_HOME -name jni.h | tail -1`
 680                 dir=`dirname "$head"`
 681                 JNI_CFLAGS="-I$dir"
 682             else
 683                 AC_MSG_FAILURE([missing jni.h header file])
 684             fi
 685         fi
 686         AC_MSG_RESULT([$JNI_CFLAGS])
 687
 688         dnl Find jni_md.h.
 689         AC_MSG_CHECKING([for jni_md.h])
 690         case "$build_os" in
 691         *linux*) system="linux" ;;
 692         *SunOS*) system="solaris" ;;
 693         *cygwin*) system="win32" ;;
 694         *) system="$build_os" ;;
 695         esac
 696         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 697             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 698         else
 699             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 700                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 701                 dir=`dirname "$head"`
 702                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 703             else
 704                 AC_MSG_FAILURE([missing jni_md.h header file])
 705             fi
 706         fi
 707         AC_MSG_RESULT([$JNI_CFLAGS])
 708
 709         dnl Need extra version flag?
 710         AC_MSG_CHECKING([extra javac flags])
 711         JAVAC_FLAGS=
 712         javac_version=`$JAVAC -version 2>&1`
 713         case "$javac_version" in
 714         *Eclipse*)
 715             JAVAC_FLAGS="-source 1.5" ;;
 716         esac
 717         AC_MSG_RESULT([$JAVAC_FLAGS])
 718
 719         dnl Where to install jarfiles.
 720         dnl XXX How to make it configurable?
 721         JAR_INSTALL_DIR=\${prefix}/share/java
 722         JNI_INSTALL_DIR=\${libdir}
 723
 724         dnl JNI version.
 725         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 726         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 727         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 728         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 729     fi
 730 fi
 731
 732 AC_SUBST(JAVA_HOME)
 733 AC_SUBST(JAVA)
 734 AC_SUBST(JAVAC)
 735 AC_SUBST(JAVAH)
 736 AC_SUBST(JAVADOC)
 737 AC_SUBST(JAR)
 738 AC_SUBST(JNI_CFLAGS)
 739 AC_SUBST(JAVAC_FLAGS)
 740 AC_SUBST(JAR_INSTALL_DIR)
 741 AC_SUBST(JNI_INSTALL_DIR)
 742 AC_SUBST(JNI_VERSION_INFO)
 743
 744 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 745
 746 dnl Check for Haskell (GHC).
 747 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 748
 749 AM_CONDITIONAL([HAVE_HASKELL],
 750     [test "x$GHC" != "xno"])
 751
 752 dnl Check for Perl modules needed by virt-df, inspector, etc.
 753 missing_perl_modules=no
 754 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
 755     AC_MSG_CHECKING([for $pm])
 756     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 757         AC_MSG_RESULT([no])
 758         missing_perl_modules=yes
 759     else
 760         AC_MSG_RESULT([yes])
 761     fi
 762 done
 763 if test "x$missing_perl_modules" = "xyes"; then
 764     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 765 fi
 766
 767 AM_CONDITIONAL([HAVE_INSPECTOR],
 768     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 769 AM_CONDITIONAL([HAVE_TOOLS],
 770     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 771
 772 dnl po4a for translating man pages and POD files (optional).
 773 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 774 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 775
 776 dnl PHP
 777 AC_CHECK_PROG([PHP],[php],[php],[no])
 778 AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 779 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 780
 781 dnl Library versioning.
 782 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 783 AC_SUBST(MAX_PROC_NR)
 784
 785 dnl Run in subdirs.
 786 if test "x$enable_daemon" = "xyes"; then
 787     AC_CONFIG_SUBDIRS([daemon])
 788 fi
 789
 790 dnl Produce output files.
 791 AC_CONFIG_HEADERS([config.h])
 792 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 793 AC_CONFIG_FILES([appliance/update.sh],
 794                 [chmod +x appliance/update.sh])
 795 AC_CONFIG_FILES([Makefile
 796                  generator/Makefile
 797                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 798                  appliance/Makefile
 799                  appliance/debian/debirf.conf
 800                  images/Makefile
 801                  capitests/Makefile
 802                  regressions/Makefile
 803                  test-tool/Makefile
 804                  ocaml/Makefile ocaml/examples/Makefile
 805                  perl/Makefile
 806                  python/Makefile
 807                  ruby/Makefile ruby/Rakefile
 808                  java/Makefile
 809                  haskell/Makefile
 810                  inspector/Makefile
 811                  tools/Makefile
 812                  libguestfs.pc
 813                  gnulib/lib/Makefile
 814                  gnulib/tests/Makefile
 815                  fuse/Makefile
 816                  po-docs/Makefile
 817                  po-docs/ja/Makefile
 818                  php/Makefile
 819                  csharp/Makefile
 820                  ocaml/META perl/Makefile.PL])
 821 AC_OUTPUT
 822
 823 dnl Produce summary.
 824 echo
 825 echo
 826 echo "------------------------------------------------------------"
 827 echo "Thank you for downloading $PACKAGE_STRING"
 828 echo
 829 echo "This is how we have configured the optional components for you today:"
 830 echo
 831 echo    "Daemon .............................. $enable_daemon"
 832 echo    "Appliance ........................... $enable_appliance"
 833 echo    "QEMU ................................ $QEMU"
 834 echo -n "OCaml bindings ...................... "
 835 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 836 echo -n "Perl bindings ....................... "
 837 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 838 echo -n "Python bindings ..................... "
 839 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 840 echo -n "Ruby bindings ....................... "
 841 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 842 echo -n "Java bindings ....................... "
 843 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 844 echo -n "Haskell bindings .................... "
 845 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 846 echo -n "PHP bindings ........................ "
 847 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 848 echo -n "virt-inspector ...................... "
 849 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 850 echo -n "virt-* tools ........................ "
 851 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 852 echo "supermin appliance .................. $enable_supermin"
 853 echo "FUSE filesystem ..................... $enable_fuse"
 854 echo
 855 echo "If any optional component is configured 'no' when you expected 'yes'"
 856 echo "then you should check the preceeding messages."
 857 echo
 858 echo "Please report bugs back to the mailing list:"
 859 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 860 echo
 861 echo "Next you should type 'make' to build the package,"
 862 echo "then 'make check' to run the tests."
 863 echo "------------------------------------------------------------"