configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2011 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  17
  18 # The major, minor, and release fields MUST be numbers.  Packagers can
  19 # add extra information using --with-extra="..." which may be any
  20 # freeform string.
  21 m4_define([libguestfs_major],   [1])
  22 m4_define([libguestfs_minor],   [15])
  23 m4_define([libguestfs_release], [12])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Stable or unstable version?
  35 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  36 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  37             AC_MSG_RESULT([stable])
  38        ],[
  39             AC_MSG_RESULT([unstable])
  40             AC_MSG_NOTICE([
  41 ***
  42 This is a development version of libguestfs. Some APIs may be unstable
  43 until they appear in a stable release of libguestfs (at which point
  44 the C API and ABI is guaranteed to remain stable forever).  For
  45 more information about stable and development branches of libguestfs
  46 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  47 ***])
  48        ])
  49
  50 dnl Extra string, a freeform string defined by packagers.
  51 AC_ARG_WITH([extra],
  52   [AS_HELP_STRING([--with-extra],
  53                   [extra version string (for use by packagers)])],
  54   [libguestfs_extra="$withval"],
  55   [libguestfs_extra=]
  56 )
  57
  58 AC_MSG_NOTICE([libguestfs version libguestfs_major.libguestfs_minor.libguestfs_release$libguestfs_extra])
  59
  60 dnl Split up the version string.
  61 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  62 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  63 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  64 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],["$libguestfs_extra"],[Extra version string])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 AC_PROG_SED
  73
  74 dnl Check for basic C environment.
  75 AC_PROG_CC_STDC
  76 AC_PROG_INSTALL
  77 AC_PROG_CPP
  78
  79 AC_ARG_ENABLE([gcc-warnings],
  80   [AS_HELP_STRING([--enable-gcc-warnings],
  81                   [turn on lots of GCC warnings (for developers)])],
  82   [case $enableval in
  83      yes|no) ;;
  84      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  85    esac
  86    gl_gcc_warnings=$enableval],
  87   [gl_gcc_warnings=no]
  88 )
  89
  90 if test "$gl_gcc_warnings" = yes; then
  91   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  92   AC_SUBST([WERROR_CFLAGS])
  93
  94   nw=
  95   # This, $nw, is the list of warnings we disable.
  96   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  97   nw="$nw -Waggregate-return"       # anachronistic
  98   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  99   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 100   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 101   nw="$nw -Wcast-qual"              # Too many warnings for now
 102   nw="$nw -Wconversion"             # Too many warnings for now
 103   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 104   nw="$nw -Wsign-conversion"        # Too many warnings for now
 105   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 106   nw="$nw -Wunreachable-code"       # Too many warnings for now
 107   nw="$nw -Wpadded"                 # Our structs are not padded
 108   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 109   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 110   nw="$nw -Wvla"                    # two warnings in mount.c
 111   # things I might fix soon:
 112   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 113   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 114   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 115   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 116                                     # was not possible, safe to ignore
 117   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 118   nw="$nw -Wlong-long"              # Allow long long since it's required
 119                                     # by Python, Ruby and xstrtoll.
 120   nw="$nw -Wstack-protector"        # Don't warn about stack-protector
 121                                     # failures (seen on Ubuntu).
 122   nw="$nw -Wmissing-noreturn"       # Don't warn about missed noreturn funcs
 123                                     # (seen on Ubuntu).
 124   nw="$nw -Wsuggest-attribute=pure" # Don't suggest pure functions.
 125   nw="$nw -Wsuggest-attribute=const" # Don't suggest const functions.
 126   nw="$nw -Wunsuffixed-float-constants" # Don't care about these.
 127
 128   gl_MANYWARN_ALL_GCC([ws])
 129   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 130   for w in $ws; do
 131     gl_WARN_ADD([$w])
 132   done
 133   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 134   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 135   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 136
 137   # In spite of excluding -Wlogical-op above, it is enabled, as of
 138   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 139   gl_WARN_ADD([-Wno-logical-op])
 140
 141   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 142   gl_WARN_ADD([-Wno-strict-overflow])
 143
 144   gl_WARN_ADD([-fdiagnostics-show-option])
 145
 146   AC_SUBST([WARN_CFLAGS])
 147
 148   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 149   AC_DEFINE([_FORTIFY_SOURCE], [2],
 150     [enable compile-time and run-time bounds-checking, and some warnings])
 151   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 152 fi
 153
 154 AC_C_PROTOTYPES
 155 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 156
 157 AM_PROG_CC_C_O
 158
 159 dnl Work out how to specify the linker script to the linker.
 160 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 161 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 162     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 163 AC_SUBST(VERSION_SCRIPT_FLAGS)
 164
 165 dnl Check support for 64 bit file offsets.
 166 AC_SYS_LARGEFILE
 167
 168 dnl Check sizeof long.
 169 AC_CHECK_SIZEOF([long])
 170
 171 dnl Check if dirent (readdir) supports d_type member.
 172 AC_STRUCT_DIRENT_D_TYPE
 173
 174 dnl Check if stat has the required fields.
 175 AC_STRUCT_ST_BLOCKS
 176 AC_CHECK_MEMBER([struct stat.st_blksize],[
 177         AC_DEFINE([HAVE_STRUCT_STAT_ST_BLKSIZE],[1],[Define to 1 if 'st_blksize' is a member of 'struct stat'])])
 178
 179 dnl Define a C symbol for the host CPU architecture.
 180 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 181
 182 dnl Headers.
 183 AC_CHECK_HEADERS([\
 184         attr/xattr.h \
 185         byteswap.h \
 186         endian.h \
 187         errno.h \
 188         printf.h \
 189         sys/inotify.h \
 190         sys/socket.h \
 191         sys/statvfs.h \
 192         sys/types.h \
 193         sys/un.h \
 194         sys/wait.h \
 195         windows.h \
 196         sys/xattr.h])
 197
 198 dnl Functions.
 199 AC_CHECK_FUNCS([\
 200         futimens \
 201         getxattr \
 202         htonl \
 203         htons \
 204         inotify_init1 \
 205         lgetxattr \
 206         listxattr \
 207         llistxattr \
 208         lsetxattr \
 209         lremovexattr \
 210         mknod \
 211         ntohl \
 212         ntohs \
 213         posix_fallocate \
 214         realpath \
 215         removexattr \
 216         setitimer \
 217         setxattr \
 218         sigaction \
 219         statvfs \
 220         sync])
 221
 222 dnl For modified printf in the daemon, we need glibc either (old-style)
 223 dnl register_printf_function or (new-style) register_printf_specifier.
 224 AC_CHECK_FUNC([register_printf_specifier],[
 225         AC_DEFINE([HAVE_REGISTER_PRINTF_SPECIFIER],[1],
 226                 [Define to 1 if you have new-style register_printf_specifier])
 227         ],[
 228         AC_CHECK_FUNC([register_printf_function],[
 229                 AC_DEFINE([HAVE_REGISTER_PRINTF_FUNCTION],[1],
 230                         [Define to 1 if you have old-style register_printf_function])
 231                 ],[
 232                 AC_MSG_FAILURE(
 233 [No support for glibc-style extended printf formatters.
 234
 235 This means you either have a very old glibc (pre-2.0) or you
 236 are using some other libc where this is not supported.])])])
 237
 238 dnl Build the daemon?
 239 AC_MSG_CHECKING([if we should build the daemon])
 240 AC_ARG_ENABLE([daemon],
 241         [AS_HELP_STRING([--enable-daemon],
 242           [enable building the daemon @<:@default=yes@:>@])],
 243         [],
 244         [enable_daemon=yes])
 245 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 246 AC_MSG_RESULT([$enable_daemon])
 247
 248 if test "x$enable_daemon" = "xyes"; then
 249         dnl Install the daemon (for libguestfs live service)
 250         AC_MSG_CHECKING([if we should install the daemon])
 251         AC_ARG_ENABLE([install-daemon],
 252                 [AS_HELP_STRING([--enable-install-daemon],
 253                   [enable installing the daemon under $sbindir @<:@default=no@:>@])],
 254                 [],
 255                 [enable_install_daemon=no])
 256         AM_CONDITIONAL([INSTALL_DAEMON],[test "x$enable_install_daemon" = "xyes"])
 257         AC_MSG_RESULT([$enable_install_daemon])
 258 fi
 259
 260 dnl Build the appliance?
 261 AC_MSG_CHECKING([if we should build the appliance])
 262 AC_ARG_ENABLE([appliance],
 263         [AS_HELP_STRING([--enable-appliance],
 264           [enable building the appliance @<:@default=yes@:>@])],
 265         [],
 266         [enable_appliance=yes])
 267 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 268 AC_MSG_RESULT([$enable_appliance])
 269
 270 if test "x$enable_appliance" = "xyes"; then
 271     dnl Check for febootstrap >= 3.0
 272     AC_CHECK_PROG([FEBOOTSTRAP],
 273                   [febootstrap],[febootstrap],[no])
 274     test "x$FEBOOTSTRAP" = "xno" &&
 275         AC_MSG_ERROR([febootstrap must be installed])
 276     dnl febootstrap 2.x did not support the --version parameter
 277     $FEBOOTSTRAP --version >&AS_MESSAGE_LOG_FD 2>&1 ||
 278         AC_MSG_ERROR([febootstrap >= 3.0 must be installed, your version is too old])
 279
 280     dnl Pass a febootstrap --yum-config option.
 281     AC_MSG_CHECKING([if user requested febootstrap --yum-config option])
 282     AC_ARG_WITH([febootstrap-yum-config],
 283         [AS_HELP_STRING([--with-febootstrap-yum-config=FILE],
 284           [pass febootstrap --yum-config option @<:@default=no@:>@])],
 285         [FEBOOTSTRAP_YUM_CONFIG="$withval"],
 286         [FEBOOTSTRAP_YUM_CONFIG=no])
 287     AC_MSG_RESULT([$FEBOOTSTRAP_YUM_CONFIG])
 288     AC_SUBST([FEBOOTSTRAP_YUM_CONFIG])
 289
 290     dnl Which distro?
 291     dnl
 292     dnl This used to be Very Important but is now just used to select
 293     dnl which packages to install in the appliance, since the package
 294     dnl names vary slightly across distros.  (See
 295     dnl appliance/packagelist.in and appliance/excludelist.in)
 296     AC_MSG_CHECKING([which Linux distro for package names])
 297     DISTRO=REDHAT
 298     if test -f /etc/debian_version; then
 299         DISTRO=DEBIAN
 300         if grep -q 'DISTRIB_ID=Ubuntu' /etc/lsb-release 2>&AS_MESSAGE_LOG_FD; then
 301             DISTRO=UBUNTU
 302         fi
 303     fi
 304     if test -f /etc/arch-release; then
 305         DISTRO=ARCHLINUX
 306     fi
 307     AC_MSG_RESULT([$DISTRO])
 308     AC_SUBST([DISTRO])
 309 fi
 310
 311 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 312 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 313 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 314 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 315         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 316         ])
 317
 318 dnl Check for Augeas (optional).
 319 PKG_CHECK_MODULES([AUGEAS], [augeas],
 320         [AC_SUBST([AUGEAS_CFLAGS])
 321          AC_SUBST([AUGEAS_LIBS])
 322          AC_DEFINE([HAVE_AUGEAS],[1],[Define to 1 if you have Augeas])
 323
 324          old_LIBS="$LIBS"
 325          LIBS="$LIBS $AUGEAS_LIBS"
 326          dnl Check for functions not available in earlier versions of Augeas.
 327          AC_CHECK_FUNCS([aug_load aug_defvar aug_defnode])
 328          LIBS="$old_LIBS"
 329         ],
 330         [AC_MSG_WARN([augeas not found, some core features will be disabled])])
 331
 332 dnl Check for libselinux (optional).
 333 AC_CHECK_HEADERS([selinux/selinux.h])
 334 AC_CHECK_LIB([selinux],[setexeccon],[
 335         have_libselinux="$ac_cv_header_selinux_selinux_h"
 336         SELINUX_LIB="-lselinux"
 337
 338         old_LIBS="$LIBS"
 339         LIBS="$LIBS $SELINUX_LIB"
 340         AC_CHECK_FUNCS([setcon getcon])
 341         LIBS="$old_LIBS"
 342
 343         ],[have_libselinux=no])
 344 if test "x$have_libselinux" = "xyes"; then
 345         AC_DEFINE([HAVE_LIBSELINUX],[1],[Define to 1 if you have libselinux])
 346 fi
 347 AC_SUBST([SELINUX_LIB])
 348
 349 dnl Check for systemtap/DTrace userspace probes (optional).
 350 dnl http://sourceware.org/systemtap/wiki/AddingUserSpaceProbingToApps
 351 AC_CHECK_HEADERS([sys/sdt.h])
 352 dnl AC_CHECK_PROG([DTRACE],[dtrace],[dtrace],[no])
 353
 354 dnl Check for cpio which isn't in the default Pardus install amazingly.
 355 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 356 test "x$CPIO" = "xno" &&
 357      AC_MSG_ERROR([cpio must be installed])
 358
 359 dnl Check for gperf.
 360 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 361 test "x$GPERF" = "xno" &&
 362      AC_MSG_ERROR([gperf must be installed])
 363
 364 dnl Check for pod2man, pod2text, pod2html.
 365 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 366 test "x$POD2MAN" = "xno" &&
 367      AC_MSG_ERROR([pod2man must be installed])
 368 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 369 test "x$POD2TEXT" = "xno" &&
 370      AC_MSG_ERROR([pod2text must be installed])
 371 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 372 test "x$POD2HTML" = "xno" &&
 373      AC_MSG_ERROR([pod2html must be installed])
 374
 375 dnl Check if pod2man, pod2text take --stderr and -u options (not in RHEL 5).
 376 AC_MSG_CHECKING([if pod2man takes --stderr option])
 377 if "$POD2MAN" --stderr >&AS_MESSAGE_LOG_FD 2>&1; then
 378     AC_MSG_RESULT([yes])
 379     POD2_STDERR_OPTION="--stderr"
 380 else
 381     AC_MSG_RESULT([no])
 382     POD2_STDERR_OPTION=""
 383 fi
 384 AC_SUBST([POD2_STDERR_OPTION])
 385
 386 AC_MSG_CHECKING([if pod2man takes -u option])
 387 if "$POD2MAN" -u >&AS_MESSAGE_LOG_FD 2>&1; then
 388     AC_MSG_RESULT([yes])
 389     POD2_UTF8_OPTION="-u"
 390 else
 391     AC_MSG_RESULT([no])
 392     POD2_UTF8_OPTION=""
 393 fi
 394 AC_SUBST([POD2_UTF8_OPTION])
 395
 396 dnl Check for genisoimage.
 397 AC_PATH_PROGS([GENISOIMAGE],[genisoimage],[no],
 398         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 399 test "x$GENISOIMAGE" = "xno" && AC_MSG_ERROR([genisoimage must be installed])
 400
 401 dnl Check for optional xmllint.
 402 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 403 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 404
 405 dnl po4a for translating man pages and POD files (optional).
 406 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 407 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 408
 409 dnl Check for db_dump, db_load (optional).
 410 AC_CHECK_PROGS([DB_DUMP],
 411                [db_dump db4_dump db4.8_dump db4.7_dump db4.6_dump],[no])
 412 AC_CHECK_PROGS([DB_LOAD],
 413                [db_load db4_load db4.8_load db4.7_load db4.6_load],[no])
 414 if test "x$DB_DUMP" != "xno"; then
 415     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 416 fi
 417 if test "x$DB_LOAD" != "xno"; then
 418     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 419 fi
 420
 421 dnl Check for QEMU for running binaries on this $host_cpu, fall
 422 dnl back to basic 'qemu'.  Allow the user to override it.
 423 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 424 AC_ARG_WITH([qemu],
 425         [AS_HELP_STRING([--with-qemu],
 426           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 427         [],
 428         [with_qemu="$default_qemu"])
 429 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 430         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 431 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 432 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 433
 434 dnl Check that the chosen qemu has virtio-serial support.
 435 if test "x$vmchannel_test" != "xno"; then
 436     AC_MSG_CHECKING([that $QEMU -help works])
 437     if $QEMU -help >&AS_MESSAGE_LOG_FD 2>&1; then
 438         AC_MSG_RESULT([yes])
 439     else
 440         AC_MSG_RESULT([no])
 441         AC_MSG_FAILURE(
 442 [$QEMU -help: command failed.
 443
 444 This could be a very old version of qemu, or qemu might not be
 445 working.
 446 ])
 447     fi
 448
 449     dnl qemu 0.15 was released with broken support for '-machine',
 450     dnl requiring you to add the machine type: '-machine pc,[...]'.
 451     dnl The problem is that 'pc' is only applicable for PC-like
 452     dnl hardware, so we cannot do this as a general solution.  Since
 453     dnl qemu 0.15, this problem has been fixed so now the default
 454     dnl machine type is chosen (qemu commit 2645c6dcaf6ea2a51a).
 455     dnl
 456     dnl We need to work out if this qemu is the broken version, so we
 457     dnl can add 'pc' just for this broken version.
 458     dnl
 459     dnl Note that old qemu didn't support the '-machine' option at all.
 460     dnl
 461     dnl We use the -kernel option for testing this, because this option
 462     dnl is processed very late, after qemu has set up the machine.
 463     AC_MSG_CHECKING([for broken '-machine accel=tcg' option in $QEMU])
 464     LC_ALL=C $QEMU -nographic -machine accel=tcg -kernel /NO_SUCH_FILE \
 465              > config1.tmp 2>&1
 466     LC_ALL=C $QEMU -nographic -machine pc,accel=tcg -kernel /NO_SUCH_FILE \
 467              > config2.tmp 2>&1
 468     if cmp -s config1.tmp config2.tmp; then
 469         AC_MSG_RESULT([no])
 470     else
 471         AC_MSG_RESULT([yes])
 472         AC_DEFINE([QEMU_MACHINE_TYPE_IS_BROKEN],[1],[qemu -machine accel=tcg option is broken (in qemu 0.15 only)])
 473     fi
 474     rm config1.tmp config2.tmp
 475
 476     dnl See if the '-machine [pc,]accel=tcg' option is required in
 477     dnl order to run the virtio-serial test below.  This happens when
 478     dnl we run qemu-kvm inside a VM without forcing TCG:
 479     dnl
 480     dnl   Could not access KVM kernel module: No such file or directory
 481     dnl   failed to initialize KVM: No such file or directory
 482     dnl   No accelerator found!
 483     AC_MSG_CHECKING([if -machine @<:@pc,@:>@accel=tcg option is required to test virtio-serial feature])
 484     if $QEMU -nographic -device \? >/dev/null 2>&1; then
 485         :
 486     elif $QEMU -machine accel=tcg -nographic -device \? >/dev/null 2>&1; then
 487         QEMU_EXTRA_OPTIONS_FOR_TEST="-machine accel=tcg"
 488     elif $QEMU -machine pc,accel=tcg -nographic -device \? >/dev/null 2>&1; then
 489         QEMU_EXTRA_OPTIONS_FOR_TEST="-machine pc,accel=tcg"
 490     # else nothing ... it'll fail below.
 491     fi
 492     AC_MSG_RESULT([$QEMU_EXTRA_OPTIONS_FOR_TEST])
 493
 494     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 495     if $QEMU $QEMU_EXTRA_OPTIONS_FOR_TEST -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 496         AC_MSG_RESULT([yes])
 497     else
 498         AC_MSG_RESULT([no])
 499         AC_MSG_FAILURE(
 500 [I did not find virtio-serial support in
 501 $QEMU.
 502
 503 virtio-serial support in qemu or KVM is essential for libguestfs
 504 to operate.
 505
 506 Usually this means that you have to install a newer version of qemu
 507 and/or KVM.  Please read the relevant section in the README file for
 508 more information about this.
 509
 510 You can override this test by setting the environment variable
 511 vmchannel_test=no  However if you don't have the right support
 512 in your qemu, then this just delays the pain.
 513
 514 If I am using the wrong qemu or you want to compile qemu from source
 515 and install it in another location, then you should configure with
 516 the --with-qemu option.
 517 ])
 518     fi
 519 fi
 520
 521 dnl Set default drive interface used by the guestfs_add_drive_opts call
 522 dnl ('-drive ...,if=...' option to qemu).
 523 dnl
 524 dnl If you encounter performance problems with virtio (RHBZ#509383)
 525 dnl then try '--with-drive-if=ide'.
 526 AC_ARG_WITH([drive-if],
 527         [AS_HELP_STRING([--with-drive-if],
 528           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 529         [],
 530         [with_drive_if=virtio])
 531 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 532
 533 dnl Set interface used by the network.  Normally you should
 534 dnl leave this at the default (virtio-net-pci) but you can use the
 535 dnl alternative (ne2k_pci) because of bugs in virtio networking
 536 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 537 AC_ARG_WITH([net-if],
 538         [AS_HELP_STRING([--with-net-if],
 539           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 540         [],
 541         [with_net_if=virtio-net-pci])
 542 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 543
 544 dnl Enable packet dumps when in verbose mode.  This generates lots
 545 dnl of debug info, only useful for people debugging the RPC mechanism.
 546 AC_ARG_ENABLE([packet-dump],
 547         [AS_HELP_STRING([--enable-packet-dump],
 548           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 549         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 550         [])
 551
 552 dnl Readline.
 553 AC_ARG_WITH([readline],
 554     [AS_HELP_STRING([--with-readline],
 555         [support fancy command line editing @<:@default=check@:>@])],
 556     [],
 557     [with_readline=check])
 558
 559 LIBREADLINE=
 560 AS_IF([test "x$with_readline" != xno],
 561     [AC_CHECK_LIB([readline], [main],
 562         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 563          AC_DEFINE([HAVE_LIBREADLINE], [1],
 564                    [Define if you have libreadline])
 565         ],
 566         [if test "x$with_readline" != xcheck; then
 567          AC_MSG_FAILURE(
 568              [--with-readline was given, but test for readline failed])
 569          fi
 570         ], -lncurses)
 571      old_LIBS="$LIBS"
 572      LIBS="$LIBS $LIBREADLINE"
 573      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 574      LIBS="$old_LIBS"
 575     ])
 576
 577 dnl For i18n.
 578 AM_GNU_GETTEXT([external])
 579
 580 dnl Check for PCRE (required)
 581 PKG_CHECK_MODULES([PCRE], [libpcre])
 582
 583 dnl libmagic (highly recommended)
 584 AC_CHECK_LIB([magic],[magic_file],
 585         [AC_CHECK_HEADER([magic.h],
 586                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 587                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 588                 ], [])
 589         ],
 590         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 591
 592 dnl libvirt (highly recommended)
 593 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 594         [AC_SUBST([LIBVIRT_CFLAGS])
 595          AC_SUBST([LIBVIRT_LIBS])
 596          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 597         ],
 598         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 599 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 600
 601 dnl libxml2 (highly recommended)
 602 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 603         [AC_SUBST([LIBXML2_CFLAGS])
 604          AC_SUBST([LIBXML2_LIBS])
 605          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 606         ],
 607         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 608 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 609
 610 dnl libconfig (highly recommended)
 611 PKG_CHECK_MODULES([LIBCONFIG], [libconfig],
 612         [AC_SUBST([LIBCONFIG_CFLAGS])
 613          AC_SUBST([LIBCONFIG_LIBS])
 614          AC_DEFINE([HAVE_LIBCONFIG],[1],[libconfig found at compile time.])
 615         ],
 616         [AC_MSG_WARN([libconfig not found, some features will be disabled])])
 617 AM_CONDITIONAL([HAVE_LIBCONFIG],[test "x$LIBCONFIG_LIBS" != "x"])
 618
 619 dnl hivex library (highly recommended)
 620 dnl This used to be a part of libguestfs, but was spun off into its
 621 dnl own separate upstream project in libguestfs 1.0.85.
 622 PKG_CHECK_MODULES([HIVEX], [hivex],
 623         [AC_SUBST([HIVEX_CFLAGS])
 624          AC_SUBST([HIVEX_LIBS])
 625          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 626         ],
 627         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 628 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HIVEX_LIBS" != "x"])
 629
 630 dnl FUSE is optional to build the FUSE module.
 631 AC_ARG_ENABLE([fuse],
 632         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 633         [],
 634         [enable_fuse=yes])
 635 AS_IF([test "x$enable_fuse" != "xno"],
 636         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 637                 enable_fuse=no
 638                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 639 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 640
 641 dnl Check for OCaml (optional, for OCaml bindings).
 642 OCAMLC=no
 643 OCAMLFIND=no
 644 AC_ARG_ENABLE([ocaml],
 645         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 646         [],
 647         [enable_ocaml=yes])
 648 AS_IF([test "x$enable_ocaml" != "xno"],
 649         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 650          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 651          OCAMLC=
 652          OCAMLFIND=
 653          AC_PROG_OCAML
 654          AC_PROG_FINDLIB
 655         ])
 656 AM_CONDITIONAL([HAVE_OCAML],
 657                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 658 AM_CONDITIONAL([HAVE_OCAMLDOC],
 659                [test "x$OCAMLDOC" != "xno"])
 660
 661 dnl Check for Perl (optional, for Perl bindings).
 662 PERL=no
 663 AC_ARG_ENABLE([perl],
 664         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 665         [],
 666         [enable_perl=yes])
 667 AS_IF([test "x$enable_perl" != "xno"],
 668         [
 669         PERL=
 670         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 671
 672         dnl Check for Perl modules that must be present to compile and
 673         dnl test the Perl bindings.
 674         missing_perl_modules=no
 675         for pm in Test::More ExtUtils::MakeMaker; do
 676             AC_MSG_CHECKING([for $pm])
 677             if ! perl -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 678                 AC_MSG_RESULT([no])
 679                 missing_perl_modules=yes
 680             else
 681                 AC_MSG_RESULT([yes])
 682             fi
 683         done
 684         if test "x$missing_perl_modules" = "xyes"; then
 685             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 686         fi
 687         ])
 688 AM_CONDITIONAL([HAVE_PERL],
 689     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 690
 691 dnl Check for Python (optional, for Python bindings).
 692 PYTHON_PREFIX=
 693 PYTHON_VERSION=
 694 PYTHON_INCLUDEDIR=
 695 PYTHON_INSTALLDIR=
 696
 697 AC_ARG_ENABLE([python],
 698         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 699         [],
 700         [enable_python=yes])
 701 AS_IF([test "x$enable_python" != "xno"],
 702         [
 703         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 704
 705         if test "x$PYTHON" != "xno"; then
 706             AC_MSG_CHECKING([Python prefix])
 707             PYTHON_PREFIX=`$PYTHON -c "import sys; print (sys.prefix)"`
 708             AC_MSG_RESULT([$PYTHON_PREFIX])
 709
 710             AC_MSG_CHECKING([Python version])
 711             PYTHON_VERSION_MAJOR=`$PYTHON -c "import sys; print (sys.version_info@<:@0@:>@)"`
 712             PYTHON_VERSION_MINOR=`$PYTHON -c "import sys; print (sys.version_info@<:@1@:>@)"`
 713             PYTHON_VERSION="$PYTHON_VERSION_MAJOR.$PYTHON_VERSION_MINOR"
 714             AC_MSG_RESULT([$PYTHON_VERSION])
 715
 716             AC_MSG_CHECKING([for Python include path])
 717             if test -z "$PYTHON_INCLUDEDIR"; then
 718                 python_path=`$PYTHON -c "import distutils.sysconfig; \
 719                                          print (distutils.sysconfig.get_python_inc ());"`
 720                 PYTHON_INCLUDEDIR=$python_path
 721             fi
 722             AC_MSG_RESULT([$PYTHON_INCLUDEDIR])
 723
 724             AC_ARG_WITH([python-installdir],
 725                         [AS_HELP_STRING([--with-python-installdir],
 726                                         [directory to install python modules @<:@default=check@:>@])],
 727                         [PYTHON_INSTALLDIR="$withval"
 728                         AC_MSG_NOTICE([Python install dir $PYTHON_INSTALLDIR])],
 729                         [PYTHON_INSTALLDIR=check])
 730
 731             if test "x$PYTHON_INSTALLDIR" = "xcheck"; then
 732                 PYTHON_INSTALLDIR=
 733                 AC_MSG_CHECKING([for Python site-packages path])
 734                 if test -z "$PYTHON_INSTALLDIR"; then
 735                     PYTHON_INSTALLDIR=`$PYTHON -c "import distutils.sysconfig; \
 736                                                    print (distutils.sysconfig.get_python_lib(1,0));"`
 737                 fi
 738                 AC_MSG_RESULT([$PYTHON_INSTALLDIR])
 739             fi
 740
 741             dnl Look for some optional symbols in libpython.
 742             old_LIBS="$LIBS"
 743
 744             PYTHON_BLDLIBRARY=`$PYTHON -c "import distutils.sysconfig; \
 745                                            print (distutils.sysconfig.get_config_var('BLDLIBRARY'))"`
 746             AC_CHECK_LIB([c],[PyCapsule_New],
 747                          [AC_DEFINE([HAVE_PYCAPSULE_NEW],1,
 748                                     [Found PyCapsule_New in libpython])],
 749                          [],[$PYTHON_BLDLIBRARY])
 750             AC_CHECK_LIB([c],[PyString_AsString],
 751                          [AC_DEFINE([HAVE_PYSTRING_ASSTRING],1,
 752                                     [Found PyString_AsString in libpython])],
 753                          [],[$PYTHON_BLDLIBRARY])
 754
 755             LIBS="$old_LIBS"
 756         fi
 757
 758         AC_SUBST(PYTHON_PREFIX)
 759         AC_SUBST(PYTHON_VERSION)
 760         AC_SUBST(PYTHON_INCLUDEDIR)
 761         AC_SUBST(PYTHON_INSTALLDIR)
 762         ])
 763 AM_CONDITIONAL([HAVE_PYTHON],
 764     [test "x$PYTHON" != "xno" && test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_INSTALLDIR" != "x"])
 765
 766 dnl Check for Ruby and rake (optional, for Ruby bindings).
 767 AC_ARG_ENABLE([ruby],
 768         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 769         [],
 770         [enable_ruby=yes])
 771 AS_IF([test "x$enable_ruby" != "xno"],
 772         [
 773         AC_CHECK_PROG([RUBY],[ruby],[ruby],[no])
 774         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 775         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 776         AC_SUBST([RAKE])
 777         ])
 778 AM_CONDITIONAL([HAVE_RUBY],
 779     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 780
 781 dnl Check for Java.
 782 AC_ARG_WITH(java_home,
 783     [AS_HELP_STRING([--with-java-home],
 784         [specify path to JDK directory @<:@default=check@:>@])],
 785     [],
 786     [with_java_home=check])
 787
 788 if test "x$with_java_home" != "xno"; then
 789     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 790     then
 791         # Reject unsafe characters in $JAVA_HOME
 792         jh_lf='
 793 '
 794         case $JAVA_HOME in
 795           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 796             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 797         esac
 798         if test -d "$with_java_home"; then
 799             JAVA_HOME="$with_java_home"
 800         else
 801             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 802         fi
 803     fi
 804
 805     if test "x$JAVA_HOME" = "x"; then
 806         # Look for Java in some likely locations.
 807         for d in \
 808             /usr/lib/jvm/java \
 809             /usr/lib/jvm/java-6-openjdk
 810         do
 811             if test -d $d && test -f $d/bin/java; then
 812                 JAVA_HOME=$d
 813                 break
 814             fi
 815         done
 816     fi
 817
 818     if test "x$JAVA_HOME" != "x"; then
 819         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 820         if test ! -x "$JAVA_HOME/bin/java"; then
 821             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 822         else
 823             JAVA="$JAVA_HOME/bin/java"
 824         fi
 825         if test ! -x "$JAVA_HOME/bin/javac"; then
 826             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 827         else
 828             JAVAC="$JAVA_HOME/bin/javac"
 829         fi
 830         if test ! -x "$JAVA_HOME/bin/javah"; then
 831             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 832         else
 833             JAVAH="$JAVA_HOME/bin/javah"
 834         fi
 835         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 836             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 837         else
 838             JAVADOC="$JAVA_HOME/bin/javadoc"
 839         fi
 840         if test ! -x "$JAVA_HOME/bin/jar"; then
 841             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 842         else
 843             JAR="$JAVA_HOME/bin/jar"
 844         fi
 845         java_version=`$JAVA -version 2>&1 | grep "java version"`
 846         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 847
 848         dnl Find jni.h.
 849         AC_MSG_CHECKING([for jni.h])
 850         if test -f "$JAVA_HOME/include/jni.h"; then
 851             JNI_CFLAGS="-I$JAVA_HOME/include"
 852         else
 853             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 854                 head=`find $JAVA_HOME -name jni.h | tail -1`
 855                 dir=`dirname "$head"`
 856                 JNI_CFLAGS="-I$dir"
 857             else
 858                 AC_MSG_FAILURE([missing jni.h header file])
 859             fi
 860         fi
 861         AC_MSG_RESULT([$JNI_CFLAGS])
 862
 863         dnl Find jni_md.h.
 864         AC_MSG_CHECKING([for jni_md.h])
 865         case "$build_os" in
 866         *linux*) system="linux" ;;
 867         *SunOS*) system="solaris" ;;
 868         *cygwin*) system="win32" ;;
 869         *) system="$build_os" ;;
 870         esac
 871         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 872             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 873         else
 874             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 875                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 876                 dir=`dirname "$head"`
 877                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 878             else
 879                 AC_MSG_FAILURE([missing jni_md.h header file])
 880             fi
 881         fi
 882         AC_MSG_RESULT([$JNI_CFLAGS])
 883
 884         dnl Need extra version flag?
 885         AC_MSG_CHECKING([extra javac flags])
 886         JAVAC_FLAGS=
 887         javac_version=`$JAVAC -version 2>&1`
 888         case "$javac_version" in
 889         *Eclipse*)
 890             JAVAC_FLAGS="-source 1.5" ;;
 891         esac
 892         AC_MSG_RESULT([$JAVAC_FLAGS])
 893
 894         dnl Where to install jarfiles.
 895         dnl XXX How to make it configurable?
 896         JAR_INSTALL_DIR=\${prefix}/share/java
 897         JNI_INSTALL_DIR=\${libdir}
 898
 899         dnl JNI version.
 900         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 901         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 902         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 903         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 904     fi
 905 fi
 906
 907 AC_SUBST(JAVA_HOME)
 908 AC_SUBST(JAVA)
 909 AC_SUBST(JAVAC)
 910 AC_SUBST(JAVAH)
 911 AC_SUBST(JAVADOC)
 912 AC_SUBST(JAR)
 913 AC_SUBST(JNI_CFLAGS)
 914 AC_SUBST(JAVAC_FLAGS)
 915 AC_SUBST(JAR_INSTALL_DIR)
 916 AC_SUBST(JNI_INSTALL_DIR)
 917 AC_SUBST(JNI_VERSION_INFO)
 918
 919 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 920
 921 dnl Check for Haskell (GHC).
 922 GHC=no
 923 AC_ARG_ENABLE([haskell],
 924         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 925         [],
 926         [enable_haskell=yes])
 927 AS_IF([test "x$enable_haskell" != "xno"],
 928         [
 929         GHC=
 930         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 931         ])
 932 AM_CONDITIONAL([HAVE_HASKELL],
 933     [test "x$GHC" != "xno"])
 934
 935 dnl PHP
 936 PHP=no
 937 AC_ARG_ENABLE([php],
 938         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 939         [],
 940         [enable_php=yes])
 941 AS_IF([test "x$enable_php" != "xno"],
 942         [
 943         PHP=
 944         AC_CHECK_PROG([PHP],[php],[php],[no])
 945         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 946         ])
 947 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 948
 949 dnl Erlang
 950 ERLANG=no
 951 AC_ARG_ENABLE([erlang],
 952     AS_HELP_STRING([--disable-erlang], [Disable Erlang language bindings]),
 953          [],
 954          [enable_erlang=yes])
 955 # NB: Don't use AS_IF here: it doesn't work.
 956 if test "x$enable_erlang" != "xno"; then
 957         ERLANG=
 958         AC_ERLANG_PATH_ERLC([no])
 959
 960         if test "x$ERLC" != "xno"; then
 961             AC_ERLANG_CHECK_LIB([erl_interface], [],
 962                                 [AC_MSG_FAILURE([Erlang erl_interface library not installed.  Use --disable-erlang to disable.])])
 963             AC_ERLANG_SUBST_LIB_DIR
 964         fi
 965 fi
 966 AM_CONDITIONAL([HAVE_ERLANG], [test "x$ERLANG" != "xno" && test "x$ERLC" != "xno"])
 967
 968 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 969 AS_IF([test "x$PERL" != "xno"],
 970         [
 971         missing_perl_modules=no
 972         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 973             AC_MSG_CHECKING([for $pm])
 974             if ! $PERL -M$pm -e1 >&AS_MESSAGE_LOG_FD 2>&1; then
 975                 AC_MSG_RESULT([no])
 976                 missing_perl_modules=yes
 977             else
 978                 AC_MSG_RESULT([yes])
 979             fi
 980         done
 981         if test "x$missing_perl_modules" = "xyes"; then
 982             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 983         fi
 984         ])
 985
 986 AM_CONDITIONAL([HAVE_TOOLS],
 987     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 988
 989 dnl Library versioning.
 990 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 991 AC_SUBST(MAX_PROC_NR)
 992
 993 dnl Replace libtool with a wrapper that clobbers dependency_libs in *.la files
 994 dnl http://lists.fedoraproject.org/pipermail/devel/2010-November/146343.html
 995 LIBTOOL='bash $(top_srcdir)/libtool-kill-dependency_libs.sh $(top_builddir)/libtool'
 996 AC_SUBST([LIBTOOL])
 997
 998 dnl Produce output files.
 999 AC_CONFIG_HEADERS([config.h])
1000 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
1001 AC_CONFIG_FILES([clone/virt-sysprep],
1002                 [chmod +x clone/virt-sysprep])
1003 AC_CONFIG_FILES([podwrapper.sh],
1004                 [chmod +x podwrapper.sh])
1005 AC_CONFIG_FILES([run],
1006                 [chmod +x run])
1007 AC_CONFIG_FILES([Makefile
1008                  align/Makefile
1009                  appliance/Makefile
1010                  cat/Makefile
1011                  clone/Makefile
1012                  csharp/Makefile
1013                  daemon/Makefile
1014                  debian/changelog
1015                  df/Makefile
1016                  edit/Makefile
1017                  erlang/Makefile
1018                  erlang/examples/Makefile
1019                  examples/Makefile
1020                  fish/Makefile
1021                  fuse/Makefile
1022                  generator/Makefile
1023                  gnulib/lib/Makefile
1024                  gnulib/tests/Makefile
1025                  haskell/Makefile
1026                  inspector/Makefile
1027                  java/Makefile
1028                  java/examples/Makefile
1029                  libguestfs.pc
1030                  ocaml/META
1031                  ocaml/Makefile
1032                  ocaml/examples/Makefile
1033                  perl/Makefile
1034                  perl/Makefile.PL
1035                  perl/examples/Makefile
1036                  php/Makefile
1037                  po-docs/Makefile
1038                  po-docs/ja/Makefile
1039                  po-docs/uk/Makefile
1040                  po/Makefile.in
1041                  python/Makefile
1042                  python/examples/Makefile
1043                  rescue/Makefile
1044                  resize/Makefile
1045                  ruby/Makefile
1046                  ruby/Rakefile
1047                  ruby/examples/Makefile
1048                  sparsify/Makefile
1049                  src/Makefile
1050                  test-tool/Makefile
1051                  tests/c-api/Makefile
1052                  tests/data/Makefile
1053                  tests/extra/Makefile
1054                  tests/guests/Makefile
1055                  tests/luks/Makefile
1056                  tests/lvm/Makefile
1057                  tests/md/Makefile
1058                  tests/protocol/Makefile
1059                  tests/qemu/Makefile
1060                  tests/regressions/Makefile
1061                  tools/Makefile])
1062 AC_OUTPUT
1063
1064 dnl Produce summary.
1065 echo
1066 echo
1067 echo "------------------------------------------------------------"
1068 echo "Thank you for downloading $PACKAGE_STRING"
1069 echo
1070 echo "This is how we have configured the optional components for you today:"
1071 echo
1072 echo    "Daemon .............................. $enable_daemon"
1073 echo    "Appliance ........................... $enable_appliance"
1074 echo    "QEMU ................................ $QEMU"
1075 echo -n "OCaml bindings ...................... "
1076 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1077 echo -n "Perl bindings ....................... "
1078 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1079 echo -n "Python bindings ..................... "
1080 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1081 echo -n "Ruby bindings ....................... "
1082 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1083 echo -n "Java bindings ....................... "
1084 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1085 echo -n "Haskell bindings .................... "
1086 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1087 echo -n "PHP bindings ........................ "
1088 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1089 echo -n "Erlang bindings ..................... "
1090 if test "x$HAVE_ERLANG_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1091 echo    "guestfish and C virt tools .......... yes"
1092 echo -n "Perl virt tools ..................... "
1093 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1094 echo -n "virt-resize ......................... "
1095 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
1096 echo "FUSE filesystem ..................... $enable_fuse"
1097 echo
1098 echo "If any optional component is configured 'no' when you expected 'yes'"
1099 echo "then you should check the preceeding messages."
1100 echo
1101 echo "Please report bugs back to the mailing list:"
1102 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
1103 echo
1104 echo "Next you should type 'make' to build the package,"
1105 echo "then 'make check' to run the tests."
1106 echo "------------------------------------------------------------"