configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [7])
  21 m4_define([libguestfs_release], [12])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Die if the user tries to configure as root, see:
  57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  58 AC_MSG_CHECKING([if you are trying to configure as root])
  59 AS_IF([test "`id -u`" = 0 ],[
  60             AC_MSG_RESULT([yes])
  61             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  62       ],[
  63             AC_MSG_RESULT([no])
  64       ])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 114                                     # was not possible, safe to ignore
 115   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 116   nw="$nw -Wlong-long"              # Allow long long since it's required
 117                                     # by Python, Ruby and xstrtoll.
 118
 119   gl_MANYWARN_ALL_GCC([ws])
 120   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 121   for w in $ws; do
 122     gl_WARN_ADD([$w])
 123   done
 124   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 125   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 126   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 127
 128   # In spite of excluding -Wlogical-op above, it is enabled, as of
 129   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 130   gl_WARN_ADD([-Wno-logical-op])
 131
 132   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 133   gl_WARN_ADD([-Wno-strict-overflow])
 134
 135   gl_WARN_ADD([-fdiagnostics-show-option])
 136
 137   AC_SUBST([WARN_CFLAGS])
 138
 139   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 140   AC_DEFINE([_FORTIFY_SOURCE], [2],
 141     [enable compile-time and run-time bounds-checking, and some warnings])
 142   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 143 fi
 144
 145 AC_C_PROTOTYPES
 146 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 147
 148 AM_PROG_CC_C_O
 149
 150 dnl Work out how to specify the linker script to the linker.
 151 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 152 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 153     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 154 AC_SUBST(VERSION_SCRIPT_FLAGS)
 155
 156 dnl Check support for 64 bit file offsets.
 157 AC_SYS_LARGEFILE
 158
 159 dnl Check sizeof long.
 160 AC_CHECK_SIZEOF([long])
 161
 162 dnl Define a C symbol for the host CPU architecture.
 163 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 164
 165 dnl Headers.
 166 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 167
 168 dnl Functions.
 169 AC_CHECK_FUNCS([posix_fallocate])
 170
 171 dnl Build the daemon?
 172 AC_MSG_CHECKING([if we should build the daemon])
 173 AC_ARG_ENABLE([daemon],
 174         [AS_HELP_STRING([--enable-daemon],
 175           [enable building the daemon @<:@default=yes@:>@])],
 176         [],
 177         [enable_daemon=yes])
 178 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 179 AC_MSG_RESULT([$enable_daemon])
 180
 181 dnl Build the appliance?
 182 AC_MSG_CHECKING([if we should build the appliance])
 183 AC_ARG_ENABLE([appliance],
 184         [AS_HELP_STRING([--enable-appliance],
 185           [enable building the appliance @<:@default=yes@:>@])],
 186         [],
 187         [enable_appliance=yes])
 188 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 189 AC_MSG_RESULT([$enable_appliance])
 190
 191 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 192 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 193 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 194 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 195         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 196         ])
 197
 198 dnl Check for cpio which isn't in the default Pardus install amazingly.
 199 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 200 test "x$CPIO" = "xno" &&
 201      AC_MSG_ERROR([cpio must be installed])
 202
 203 dnl Check for gperf.
 204 AC_CHECK_PROG([GPERF],[gperf],[gperf],[no])
 205 test "x$GPERF" = "xno" &&
 206      AC_MSG_ERROR([gperf must be installed])
 207
 208 dnl Check for pod2man, pod2text, pod2html.
 209 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 210 test "x$POD2MAN" = "xno" &&
 211      AC_MSG_ERROR([pod2man must be installed])
 212 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 213 test "x$POD2TEXT" = "xno" &&
 214      AC_MSG_ERROR([pod2text must be installed])
 215 AC_CHECK_PROG([POD2HTML],[pod2html],[pod2html],[no])
 216 test "x$POD2HTML" = "xno" &&
 217      AC_MSG_ERROR([pod2html must be installed])
 218
 219 dnl Check for mkisofs.
 220 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 221         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 222 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 223
 224 dnl Check for optional xmllint.
 225 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 226 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 227
 228 dnl po4a for translating man pages and POD files (optional).
 229 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 230 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 231
 232 dnl Check for db_dump, db_load (optional).
 233 AC_CHECK_PROGS([DB_DUMP],[db_dump db4_dump db4.8_dump],[no])
 234 AC_CHECK_PROGS([DB_LOAD],[db_load db4_load db4.8_load],[no])
 235 if test "x$DB_DUMP" != "xno"; then
 236     AC_DEFINE_UNQUOTED([DB_DUMP],["$DB_DUMP"],[Name of db_dump program.])
 237 fi
 238 if test "x$DB_LOAD" != "xno"; then
 239     AC_DEFINE_UNQUOTED([DB_LOAD],["$DB_LOAD"],[Name of db_load program.])
 240 fi
 241
 242 dnl Check for QEMU for running binaries on this $host_cpu, fall
 243 dnl back to basic 'qemu'.  Allow the user to override it.
 244 default_qemu="qemu-kvm kvm qemu-system-$host_cpu qemu"
 245 AC_ARG_WITH([qemu],
 246         [AS_HELP_STRING([--with-qemu],
 247           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 248         [],
 249         [with_qemu="$default_qemu"])
 250 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 251         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 252 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 253 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 254
 255 dnl Check that the chosen qemu has virtio-serial support.
 256 if test "x$vmchannel_test" != "xno"; then
 257     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 258     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 259         AC_MSG_RESULT([yes])
 260         vmchannel_guestfwd=guestfwd
 261     else
 262         AC_MSG_RESULT([no])
 263         AC_MSG_FAILURE(
 264 [I did not find virtio-serial support in
 265 $QEMU.
 266
 267 virtio-serial support in qemu or KVM is essential for libguestfs
 268 to operate.
 269
 270 Usually this means that you have to install a newer version of qemu
 271 and/or KVM.  Please read the relevant section in the README file for
 272 more information about this.
 273
 274 You can override this test by setting the environment variable
 275 vmchannel_test=no  However if you don't have the right support
 276 in your qemu, then this just delays the pain.
 277
 278 If I am using the wrong qemu or you want to compile qemu from source
 279 and install it in another location, then you should configure with
 280 the --with-qemu option.
 281 ])
 282     fi
 283 fi
 284
 285 dnl Set default drive interface used by the guestfs_add_drive_opts call
 286 dnl ('-drive ...,if=...' option to qemu).
 287 dnl
 288 dnl If you encounter performance problems with virtio (RHBZ#509383)
 289 dnl then try '--with-drive-if=ide'.
 290 AC_ARG_WITH([drive-if],
 291         [AS_HELP_STRING([--with-drive-if],
 292           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 293         [],
 294         [with_drive_if=virtio])
 295 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 296
 297 dnl Set interface used by the network.  Normally you should
 298 dnl leave this at the default (virtio-net-pci) but you can use the
 299 dnl alternative (ne2k_pci) because of bugs in virtio networking
 300 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 301 AC_ARG_WITH([net-if],
 302         [AS_HELP_STRING([--with-net-if],
 303           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 304         [],
 305         [with_net_if=virtio-net-pci])
 306 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 307
 308 dnl Check for febootstrap etc.
 309 if test "x$enable_appliance" = "xyes"; then
 310     AC_CHECK_PROG([FEBOOTSTRAP],
 311                   [febootstrap],[febootstrap],[no])
 312     if test "x$FEBOOTSTRAP" != "xno"; then
 313       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 314                     [febootstrap-run],[febootstrap-run],[no])
 315       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 316           AC_MSG_ERROR([febootstrap-run must be installed])
 317       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 318                     [febootstrap-install],[febootstrap-install],[no])
 319       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 320           AC_MSG_ERROR([febootstrap-install must be installed])
 321       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 322                     [febootstrap-minimize],[febootstrap-minimize],[no])
 323       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 324           AC_MSG_ERROR([febootstrap-minimize must be installed])
 325       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 326                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 327       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 328           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 329       AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
 330                     [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
 331       test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
 332           AC_MSG_ERROR([febootstrap-to-supermin must be installed])
 333
 334       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 335       dnl of febootstrap, but old versions will fail with yum).
 336       AC_CHECK_PROG([FAKECHROOT],
 337                     [fakechroot],[fakechroot],[no])
 338       test "x$FAKECHROOT" = "xno" && \
 339          AC_MSG_ERROR([fakechroot must be installed])
 340
 341       AC_MSG_CHECKING([fakechroot version])
 342       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 343       if test -z "$fakechroot_version"; then
 344         AC_MSG_RESULT([failed])
 345         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 346       else
 347         AC_MSG_RESULT([$fakechroot_version])
 348         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 349         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 350         if test "$fakechroot_major" -lt 2 || \
 351           ( test "$fakechroot_major" -eq 2 && test "$fakechroot_minor" -lt 9 ); then
 352           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 353         fi
 354       fi
 355       DIST="REDHAT"
 356     else
 357       # check for debootstrap and debirf
 358       AC_CHECK_PROG([DEBOOTSTRAP],
 359                     [debootstrap],[debootstrap],[no])
 360       test "x$DEBOOTSTRAP" = "xno" && \
 361           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 362       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 363       test "x$DEBIRF" = "xno" &&
 364           AC_MSG_ERROR([debirf must be installed])
 365       DIST="DEBIAN"
 366       case "$host_cpu" in
 367       *86)
 368           DEBIAN_KERNEL_ARCH=486
 369           ;;
 370       x86_64)
 371           DEBIAN_KERNEL_ARCH=amd64
 372           ;;
 373       *)
 374          DEBIAN_KERNEL_ARCH=$host_cpu
 375          ;;
 376       esac
 377       AC_SUBST(DEBIAN_KERNEL_ARCH)
 378     fi
 379     AC_SUBST(DIST)
 380
 381     dnl --with-updates to specify a Fedora updates repository.
 382     AC_ARG_WITH([updates],
 383         [AS_HELP_STRING([--with-updates],
 384           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 385         [],
 386         [with_updates=updates-released-f12])
 387     UPDATES="$with_updates"
 388     AC_SUBST(UPDATES)
 389
 390     dnl --with-mirror to specify a local Fedora mirror.
 391     AC_ARG_WITH([mirror],
 392         [AS_HELP_STRING([--with-mirror],
 393           [set URI of a local Fedora mirror])],
 394         [],
 395         [with_mirror=])
 396     MIRROR="$with_mirror"
 397     AC_SUBST(MIRROR)
 398 fi
 399
 400 dnl --with-repo to specify a repository.
 401 AC_ARG_WITH([repo],
 402         [AS_HELP_STRING([--with-repo],
 403           [set name of Fedora repository @<:@default=fedora-13@:>@])],
 404         [],
 405         [with_repo=fedora-13])
 406 REPO="$with_repo"
 407 AC_SUBST(REPO)
 408 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of software repository.])
 409
 410 dnl Build the supermin appliance?  Please see README file before
 411 dnl enabling this option.
 412 AC_ARG_ENABLE([supermin],
 413         [AS_HELP_STRING([--enable-supermin],
 414           [enable supermin appliance (see README) @<:@default=no@:>@])],
 415         [AC_DEFINE([ENABLE_SUPERMIN],[1],[Supermin appliance enabled.])],
 416         [enable_supermin=no])
 417 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 418
 419 dnl Enable packet dumps when in verbose mode.  This generates lots
 420 dnl of debug info, only useful for people debugging the RPC mechanism.
 421 AC_ARG_ENABLE([packet-dump],
 422         [AS_HELP_STRING([--enable-packet-dump],
 423           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 424         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 425         [])
 426
 427 dnl Readline.
 428 AC_ARG_WITH([readline],
 429     [AS_HELP_STRING([--with-readline],
 430         [support fancy command line editing @<:@default=check@:>@])],
 431     [],
 432     [with_readline=check])
 433
 434 LIBREADLINE=
 435 AS_IF([test "x$with_readline" != xno],
 436     [AC_CHECK_LIB([readline], [main],
 437         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 438          AC_DEFINE([HAVE_LIBREADLINE], [1],
 439                    [Define if you have libreadline])
 440         ],
 441         [if test "x$with_readline" != xcheck; then
 442          AC_MSG_FAILURE(
 443              [--with-readline was given, but test for readline failed])
 444          fi
 445         ], -lncurses)
 446      old_LIBS="$LIBS"
 447      LIBS="$LIBS $LIBREADLINE"
 448      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 449      LIBS="$old_LIBS"
 450     ])
 451
 452 dnl For i18n.
 453 AM_GNU_GETTEXT([external])
 454 AM_GNU_GETTEXT_VERSION([0.17])
 455
 456 dnl libmagic (highly recommended)
 457 AC_CHECK_LIB([magic],[magic_file],
 458         [AC_CHECK_HEADER([magic.h],
 459                 [AC_SUBST([MAGIC_LIBS], ["-lmagic"])
 460                  AC_DEFINE([HAVE_LIBMAGIC],[1],[libmagic found at compile time.])
 461                 ], [])
 462         ],
 463         [AC_MSG_WARN([libmagic not found, some core features will be disabled])])
 464
 465 dnl Check for PCRE (highly recommended)
 466 PKG_CHECK_MODULES([PCRE], [libpcre],
 467         [AC_SUBST([PCRE_CFLAGS])
 468          AC_SUBST([PCRE_LIBS])
 469          AC_DEFINE([HAVE_PCRE],[1],[PCRE found at compile time.])
 470         ],
 471         [AC_MSG_WARN([PCRE not found, some core features will be disabled])])
 472
 473 dnl libvirt (highly recommended)
 474 PKG_CHECK_MODULES([LIBVIRT], [libvirt],
 475         [AC_SUBST([LIBVIRT_CFLAGS])
 476          AC_SUBST([LIBVIRT_LIBS])
 477          AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 478         ],
 479         [AC_MSG_WARN([libvirt not found, some core features will be disabled])])
 480 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 481
 482 dnl libxml2 (highly recommended)
 483 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0],
 484         [AC_SUBST([LIBXML2_CFLAGS])
 485          AC_SUBST([LIBXML2_LIBS])
 486          AC_DEFINE([HAVE_LIBXML2],[1],[libxml2 found at compile time.])
 487         ],
 488         [AC_MSG_WARN([libxml2 not found, some core features will be disabled])])
 489 AM_CONDITIONAL([HAVE_LIBXML2],[test "x$LIBXML2_LIBS" != "x"])
 490
 491 dnl hivex library (highly recommended)
 492 dnl This used to be a part of libguestfs, but was spun off into its
 493 dnl own separate upstream project in libguestfs 1.0.85.
 494 PKG_CHECK_MODULES([HIVEX], [hivex],
 495         [AC_SUBST([HIVEX_CFLAGS])
 496          AC_SUBST([HIVEX_LIBS])
 497          AC_DEFINE([HAVE_HIVEX],[1],[hivex library found at compile time.])
 498         ],
 499         [AC_MSG_WARN([hivex not found, some core features will be disabled])])
 500
 501 dnl FUSE is optional to build the FUSE module.
 502 AC_ARG_ENABLE([fuse],
 503         AS_HELP_STRING([--disable-fuse], [Disable FUSE (guestmount) support]),
 504         [],
 505         [enable_fuse=yes])
 506 AS_IF([test "x$enable_fuse" != "xno"],
 507         [PKG_CHECK_MODULES([FUSE],[fuse],,[
 508                 enable_fuse=no
 509                 AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])])
 510 AM_CONDITIONAL([HAVE_FUSE],[test "x$enable_fuse" != "xno"])
 511
 512 dnl Check for OCaml (optional, for OCaml bindings).
 513 OCAMLC=no
 514 OCAMLFIND=no
 515 AC_ARG_ENABLE([ocaml],
 516         AS_HELP_STRING([--disable-ocaml], [Disable OCaml language bindings]),
 517         [],
 518         [enable_ocaml=yes])
 519 AS_IF([test "x$enable_ocaml" != "xno"],
 520         [dnl OCAMLC and OCAMLFIND have to be unset first, otherwise
 521          dnl AC_CHECK_TOOL (inside AC_PROG_OCAML) will not look.
 522          OCAMLC=
 523          OCAMLFIND=
 524          AC_PROG_OCAML
 525          AC_PROG_FINDLIB
 526         ])
 527 AM_CONDITIONAL([HAVE_OCAML],
 528                [test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 529
 530 dnl Check for Perl (optional, for Perl bindings).
 531 PERL=no
 532 AC_ARG_ENABLE([perl],
 533         AS_HELP_STRING([--disable-perl], [Disable Perl language bindings]),
 534         [],
 535         [enable_perl=yes])
 536 AS_IF([test "x$enable_perl" != "xno"],
 537         [
 538         PERL=
 539         AC_CHECK_PROG([PERL],[perl],[perl],[no])
 540
 541         dnl Check for Perl modules that must be present to compile and
 542         dnl test the Perl bindings.
 543         missing_perl_modules=no
 544         for pm in Test::More ExtUtils::MakeMaker; do
 545             AC_MSG_CHECKING([for $pm])
 546             if ! perl -M$pm -e1 >/dev/null 2>&1; then
 547                 AC_MSG_RESULT([no])
 548                 missing_perl_modules=yes
 549             else
 550                 AC_MSG_RESULT([yes])
 551             fi
 552         done
 553         if test "x$missing_perl_modules" = "xyes"; then
 554             AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 555         fi
 556         ])
 557 AM_CONDITIONAL([HAVE_PERL],
 558     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 559
 560 dnl Check for Python (optional, for Python bindings).
 561 PYTHON_PREFIX=
 562 PYTHON_VERSION=
 563 PYTHON_INCLUDEDIR=
 564 PYTHON_SITE_PACKAGES=
 565
 566 AC_ARG_ENABLE([python],
 567         AS_HELP_STRING([--disable-python], [Disable Python language bindings]),
 568         [],
 569         [enable_python=yes])
 570 AS_IF([test "x$enable_python" != "xno"],
 571         [
 572         AC_CHECK_PROG([PYTHON],[python],[python],[no])
 573
 574         if test "x$PYTHON" != "xno"; then
 575             PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 576             PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 577             for d in \
 578                 $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 579                 /usr/include/python$PYTHON_VERSION \
 580                 /usr/local/include/python$PYTHON_VERSION
 581             do
 582                 AC_MSG_CHECKING([Python.h in $d])
 583                 if test -r "$d/Python.h"; then
 584                     AC_MSG_RESULT([found])
 585                     PYTHON_INCLUDEDIR=$d
 586                     break
 587                 fi
 588                 AC_MSG_RESULT([not found])
 589             done
 590             if test "x$PYTHON_INCLUDEDIR" = "x"; then
 591                 AC_MSG_WARN([Python include directory not found])
 592             fi
 593
 594             for d in \
 595                 $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 596                 $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 597                 /usr/lib64/python$PYTHON_VERSION/site-packages \
 598                 /usr/lib/python$PYTHON_VERSION/site-packages \
 599                 /usr/local/lib/python$PYTHON_VERSION/site-packages
 600             do
 601                 AC_MSG_CHECKING([for $d])
 602                 if test -d "$d"; then
 603                     AC_MSG_RESULT([found])
 604                     PYTHON_SITE_PACKAGES=$d
 605                     break
 606                 fi
 607                 AC_MSG_RESULT([not found])
 608             done
 609             if test "x$PYTHON_SITE_PACKAGES" = "x"; then
 610                 AC_MSG_WARN([Python site-packages directory not found])
 611             fi
 612
 613             old_LIBS="$LIBS"
 614             LIBS="$LIBS -lpython$PYTHON_VERSION"
 615             AC_CHECK_FUNCS([PyCapsule_New])
 616             LIBS="$old_LIBS"
 617         fi
 618
 619         AC_SUBST(PYTHON_PREFIX)
 620         AC_SUBST(PYTHON_VERSION)
 621         AC_SUBST(PYTHON_INCLUDEDIR)
 622         AC_SUBST(PYTHON_SITE_PACKAGES)
 623         ])
 624 AM_CONDITIONAL([HAVE_PYTHON],
 625     [test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_SITE_PACKAGES" != "x"])
 626
 627 dnl Check for Ruby and rake (optional, for Ruby bindings).
 628 AC_ARG_ENABLE([ruby],
 629         AS_HELP_STRING([--disable-ruby], [Disable Ruby language bindings]),
 630         [],
 631         [enable_ruby=yes])
 632 AS_IF([test "x$enable_ruby" != "xno"],
 633         [
 634         AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 635         AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 636         ])
 637 AM_CONDITIONAL([HAVE_RUBY],
 638     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 639
 640 dnl Check for Java.
 641 AC_ARG_WITH(java_home,
 642     [AS_HELP_STRING([--with-java-home],
 643         [specify path to JDK directory @<:@default=check@:>@])],
 644     [],
 645     [with_java_home=check])
 646
 647 if test "x$with_java_home" != "xno"; then
 648     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 649     then
 650         # Reject unsafe characters in $JAVA_HOME
 651         jh_lf='
 652 '
 653         case $JAVA_HOME in
 654           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 655             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 656         esac
 657         if test -d "$with_java_home"; then
 658             JAVA_HOME="$with_java_home"
 659         else
 660             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 661         fi
 662     fi
 663
 664     if test "x$JAVA_HOME" = "x"; then
 665         # Look for Java in some likely locations.
 666         for d in \
 667             /usr/lib/jvm/java \
 668             /usr/lib/jvm/java-6-openjdk
 669         do
 670             if test -d $d && test -f $d/bin/java; then
 671                 JAVA_HOME=$d
 672                 break
 673             fi
 674         done
 675     fi
 676
 677     if test "x$JAVA_HOME" != "x"; then
 678         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 679         if test ! -x "$JAVA_HOME/bin/java"; then
 680             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 681         else
 682             JAVA="$JAVA_HOME/bin/java"
 683         fi
 684         if test ! -x "$JAVA_HOME/bin/javac"; then
 685             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 686         else
 687             JAVAC="$JAVA_HOME/bin/javac"
 688         fi
 689         if test ! -x "$JAVA_HOME/bin/javah"; then
 690             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 691         else
 692             JAVAH="$JAVA_HOME/bin/javah"
 693         fi
 694         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 695             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 696         else
 697             JAVADOC="$JAVA_HOME/bin/javadoc"
 698         fi
 699         if test ! -x "$JAVA_HOME/bin/jar"; then
 700             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 701         else
 702             JAR="$JAVA_HOME/bin/jar"
 703         fi
 704         java_version=`$JAVA -version 2>&1 | grep "java version"`
 705         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 706
 707         dnl Find jni.h.
 708         AC_MSG_CHECKING([for jni.h])
 709         if test -f "$JAVA_HOME/include/jni.h"; then
 710             JNI_CFLAGS="-I$JAVA_HOME/include"
 711         else
 712             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 713                 head=`find $JAVA_HOME -name jni.h | tail -1`
 714                 dir=`dirname "$head"`
 715                 JNI_CFLAGS="-I$dir"
 716             else
 717                 AC_MSG_FAILURE([missing jni.h header file])
 718             fi
 719         fi
 720         AC_MSG_RESULT([$JNI_CFLAGS])
 721
 722         dnl Find jni_md.h.
 723         AC_MSG_CHECKING([for jni_md.h])
 724         case "$build_os" in
 725         *linux*) system="linux" ;;
 726         *SunOS*) system="solaris" ;;
 727         *cygwin*) system="win32" ;;
 728         *) system="$build_os" ;;
 729         esac
 730         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 731             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 732         else
 733             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 734                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 735                 dir=`dirname "$head"`
 736                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 737             else
 738                 AC_MSG_FAILURE([missing jni_md.h header file])
 739             fi
 740         fi
 741         AC_MSG_RESULT([$JNI_CFLAGS])
 742
 743         dnl Need extra version flag?
 744         AC_MSG_CHECKING([extra javac flags])
 745         JAVAC_FLAGS=
 746         javac_version=`$JAVAC -version 2>&1`
 747         case "$javac_version" in
 748         *Eclipse*)
 749             JAVAC_FLAGS="-source 1.5" ;;
 750         esac
 751         AC_MSG_RESULT([$JAVAC_FLAGS])
 752
 753         dnl Where to install jarfiles.
 754         dnl XXX How to make it configurable?
 755         JAR_INSTALL_DIR=\${prefix}/share/java
 756         JNI_INSTALL_DIR=\${libdir}
 757
 758         dnl JNI version.
 759         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 760         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 761         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 762         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 763     fi
 764 fi
 765
 766 AC_SUBST(JAVA_HOME)
 767 AC_SUBST(JAVA)
 768 AC_SUBST(JAVAC)
 769 AC_SUBST(JAVAH)
 770 AC_SUBST(JAVADOC)
 771 AC_SUBST(JAR)
 772 AC_SUBST(JNI_CFLAGS)
 773 AC_SUBST(JAVAC_FLAGS)
 774 AC_SUBST(JAR_INSTALL_DIR)
 775 AC_SUBST(JNI_INSTALL_DIR)
 776 AC_SUBST(JNI_VERSION_INFO)
 777
 778 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 779
 780 dnl Check for Haskell (GHC).
 781 GHC=no
 782 AC_ARG_ENABLE([haskell],
 783         AS_HELP_STRING([--disable-haskell], [Disable Haskell language bindings]),
 784         [],
 785         [enable_haskell=yes])
 786 AS_IF([test "x$enable_haskell" != "xno"],
 787         [
 788         GHC=
 789         AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 790         ])
 791 AM_CONDITIONAL([HAVE_HASKELL],
 792     [test "x$GHC" != "xno"])
 793
 794 dnl PHP
 795 PHP=no
 796 AC_ARG_ENABLE([php],
 797         AS_HELP_STRING([--disable-php], [Disable PHP language bindings]),
 798         [],
 799         [enable_php=yes])
 800 AS_IF([test "x$enable_php" != "xno"],
 801         [
 802         PHP=
 803         AC_CHECK_PROG([PHP],[php],[php],[no])
 804         AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 805         ])
 806 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 807
 808 dnl Check for Perl modules needed by Perl virt tools (virt-df, etc.)
 809 AS_IF([test "x$PERL" != "xno"],
 810         [
 811         missing_perl_modules=no
 812         for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper Locale::TextDomain Win::Hivex Win::Hivex::Regedit String::ShellQuote; do
 813             AC_MSG_CHECKING([for $pm])
 814             if ! $PERL -M$pm -e1 >/dev/null 2>&1; then
 815                 AC_MSG_RESULT([no])
 816                 missing_perl_modules=yes
 817             else
 818                 AC_MSG_RESULT([yes])
 819             fi
 820         done
 821         if test "x$missing_perl_modules" = "xyes"; then
 822             AC_MSG_WARN([some Perl modules required to compile the Perl virt-* tools are missing])
 823         fi
 824         ])
 825
 826 AM_CONDITIONAL([HAVE_TOOLS],
 827     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 828
 829 dnl Library versioning.
 830 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 831 AC_SUBST(MAX_PROC_NR)
 832
 833 dnl Run in subdirs.
 834 if test "x$enable_daemon" = "xyes"; then
 835     AC_CONFIG_SUBDIRS([daemon])
 836 fi
 837
 838 dnl Produce output files.
 839 AC_CONFIG_HEADERS([config.h])
 840 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 841 AC_CONFIG_FILES([appliance/update.sh],
 842                 [chmod +x appliance/update.sh])
 843 AC_CONFIG_FILES([podwrapper.sh],
 844                 [chmod +x podwrapper.sh])
 845 AC_CONFIG_FILES([Makefile
 846                  generator/Makefile
 847                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 848                  appliance/Makefile
 849                  appliance/debian/debirf.conf
 850                  images/Makefile
 851                  capitests/Makefile
 852                  regressions/Makefile
 853                  test-tool/Makefile
 854                  ocaml/Makefile ocaml/examples/Makefile
 855                  perl/Makefile
 856                  python/Makefile
 857                  ruby/Makefile ruby/Rakefile
 858                  java/Makefile
 859                  haskell/Makefile
 860                  inspector/Makefile
 861                  tools/Makefile
 862                  libguestfs.pc
 863                  gnulib/lib/Makefile
 864                  gnulib/tests/Makefile
 865                  fuse/Makefile
 866                  po-docs/Makefile
 867                  po-docs/ja/Makefile
 868                  php/Makefile
 869                  csharp/Makefile
 870                  cat/Makefile
 871                  ocaml/META perl/Makefile.PL])
 872 AC_OUTPUT
 873
 874 dnl Produce summary.
 875 echo
 876 echo
 877 echo "------------------------------------------------------------"
 878 echo "Thank you for downloading $PACKAGE_STRING"
 879 echo
 880 echo "This is how we have configured the optional components for you today:"
 881 echo
 882 echo    "Daemon .............................. $enable_daemon"
 883 echo    "Appliance ........................... $enable_appliance"
 884 echo    "QEMU ................................ $QEMU"
 885 echo -n "OCaml bindings ...................... "
 886 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 887 echo -n "Perl bindings ....................... "
 888 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 889 echo -n "Python bindings ..................... "
 890 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 891 echo -n "Ruby bindings ....................... "
 892 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 893 echo -n "Java bindings ....................... "
 894 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 895 echo -n "Haskell bindings .................... "
 896 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 897 echo -n "PHP bindings ........................ "
 898 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 899 echo -n "virt-* tools ........................ "
 900 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 901 echo "supermin appliance .................. $enable_supermin"
 902 echo "FUSE filesystem ..................... $enable_fuse"
 903 echo
 904 echo "If any optional component is configured 'no' when you expected 'yes'"
 905 echo "then you should check the preceeding messages."
 906 echo
 907 echo "Please report bugs back to the mailing list:"
 908 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 909 echo
 910 echo "Next you should type 'make' to build the package,"
 911 echo "then 'make check' to run the tests."
 912 echo "------------------------------------------------------------"