configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [0])
  21 m4_define([libguestfs_release], [68])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 gl_EARLY
  41 gl_INIT
  42
  43 AC_PROG_LIBTOOL
  44
  45 dnl Check for basic C environment.
  46 AC_PROG_CC_STDC
  47 AC_PROG_INSTALL
  48 AC_PROG_CPP
  49
  50 AC_ARG_ENABLE([gcc-warnings],
  51   [AS_HELP_STRING([--enable-gcc-warnings],
  52                   [turn on lots of GCC warnings (for developers)])],
  53   [case $enableval in
  54      yes|no) ;;
  55      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  56    esac
  57    gl_gcc_warnings=$enableval],
  58   [gl_gcc_warnings=no]
  59 )
  60
  61 if test "$gl_gcc_warnings" = yes; then
  62   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  63   AC_SUBST([WERROR_CFLAGS])
  64
  65   nw=
  66   # This, $nw, is the list of warnings we disable.
  67   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  68   nw="$nw -Waggregate-return"       # anachronistic
  69   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  70   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  71   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  72   nw="$nw -Wcast-qual"              # Too many warnings for now
  73   nw="$nw -Wconversion"             # Too many warnings for now
  74   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  75   nw="$nw -Wsign-conversion"        # Too many warnings for now
  76   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  77   nw="$nw -Wunreachable-code"       # Too many warnings for now
  78   nw="$nw -Wpadded"                 # Our structs are not padded
  79   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  80   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  81   nw="$nw -Wvla"                    # two warnings in mount.c
  82   # things I might fix soon:
  83   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
  84   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
  85   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
  86   # ?? -Wstrict-overflow
  87
  88   gl_MANYWARN_ALL_GCC([ws])
  89   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  90   for w in $ws; do
  91     gl_WARN_ADD([$w])
  92   done
  93   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
  94   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
  95   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
  96
  97   # In spite of excluding -Wlogical-op above, it is enabled, as of
  98   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
  99   gl_WARN_ADD([-Wno-logical-op])
 100
 101   gl_WARN_ADD([-fdiagnostics-show-option])
 102
 103   AC_SUBST([WARN_CFLAGS])
 104
 105   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 106   AC_DEFINE([_FORTIFY_SOURCE], [2],
 107     [enable compile-time and run-time bounds-checking, and some warnings])
 108   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 109 fi
 110
 111 AC_C_PROTOTYPES
 112 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 113
 114 AM_PROG_CC_C_O
 115
 116 dnl Check support for 64 bit file offsets.
 117 AC_SYS_LARGEFILE
 118
 119 dnl Check sizeof long.
 120 AC_CHECK_SIZEOF([long])
 121
 122 dnl Headers.
 123 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h])
 124
 125 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 126 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 127 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 128 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 129         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 130         ])
 131
 132 dnl Check for pod2man and pod2text.
 133 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 134 test "x$POD2MAN" = "xno" &&
 135      AC_MSG_ERROR([pod2man must be installed])
 136 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 137 test "x$POD2TEXT" = "xno" &&
 138      AC_MSG_ERROR([pod2text must be installed])
 139
 140 dnl Check for mkisofs.
 141 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 142         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 143 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 144
 145 dnl Check for QEMU for running binaries on this $host_cpu, fall
 146 dnl back to basic 'qemu'.  Allow the user to override it.
 147 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 148 AC_ARG_WITH([qemu],
 149         [AS_HELP_STRING([--with-qemu],
 150           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 151         [],
 152         [with_qemu="$default_qemu"])
 153 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 154         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 155 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 156 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 157
 158 dnl Check that the chosen qemu has vmchannel support.
 159 dnl http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
 160 if test "x$vmchannel_test" != "xno"; then
 161     AC_MSG_CHECKING([for "guestfwd" support in $QEMU])
 162     if $QEMU --help | grep -sq guestfwd; then
 163         AC_MSG_RESULT([yes])
 164     else
 165         AC_MSG_RESULT([no])
 166         AC_MSG_CHECKING([for "-net channel" support in $QEMU])
 167         vmchannelout=`$QEMU -net channel /dev/zero 2>&1 ||:`
 168         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 169         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 170             AC_MSG_RESULT([yes])
 171         else
 172             AC_MSG_RESULT([no])
 173             AC_MSG_FAILURE(
 174 [I did not find vmchannel support in $QEMU.
 175
 176 vmchannel support is vital for libguestfs to operate.  You need a version
 177 of qemu >= 0.10, or the following patch backported to earlier versions:
 178
 179 http://lists.gnu.org/archive/html/qemu-devel/2009-02/msg01042.html
 180
 181 You can override this test by setting the environment variable
 182 vmchannel_test=no  However if you don't have vmchannel support
 183 in your qemu, then this just delays the pain.
 184
 185 If I am using the wrong qemu or you want to compile qemu from source
 186 and install it in another location, then you should configure with
 187 the --with-qemu option.
 188 ])
 189         fi
 190     fi
 191 fi
 192
 193 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 194 dnl ('-drive ...,if=...' option to qemu).
 195 dnl
 196 dnl NB. We will change the default in future to virtio, but at the
 197 dnl moment this causes a performance problem, RHBZ#509383.
 198 AC_ARG_WITH([drive-if],
 199         [AS_HELP_STRING([--with-drive-if],
 200           [set default driver (ide|scsi|virtio) @<:@default=ide@:>@])],
 201         [],
 202         [with_drive_if=ide])
 203 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 204
 205 dnl Set interface used by the network.  Normally you should
 206 dnl leave this at the default (virtio) but you can use the
 207 dnl alternative (ne2k_pci) because of bugs in virtio networking
 208 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 209 AC_ARG_WITH([net-if],
 210         [AS_HELP_STRING([--with-net-if],
 211           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 212         [],
 213         [with_net_if=virtio])
 214 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 215
 216 dnl Check for febootstrap etc.
 217 AC_CHECK_PROG([FEBOOTSTRAP],
 218         [febootstrap],[febootstrap],[no])
 219 if test "x$FEBOOTSTRAP" != "xno"; then
 220   AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 221         [febootstrap-run],[febootstrap-run],[no])
 222   test "x$FEBOOTSTRAP_RUN" = "xno" && \
 223      AC_MSG_ERROR([febootstrap-run must be installed])
 224   AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 225         [febootstrap-install],[febootstrap-install],[no])
 226   test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 227      AC_MSG_ERROR([febootstrap-install must be installed])
 228   AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 229         [febootstrap-minimize],[febootstrap-minimize],[no])
 230   test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 231      AC_MSG_ERROR([febootstrap-minimize must be installed])
 232   AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 233         [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 234   test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 235      AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 236
 237   dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 238   dnl of febootstrap, but old versions will fail with yum).
 239   AC_CHECK_PROG([FAKECHROOT],
 240         [fakechroot],[fakechroot],[no])
 241   test "x$FAKECHROOT" = "xno" && \
 242     AC_MSG_ERROR([fakechroot must be installed])
 243
 244   AC_MSG_CHECKING([fakechroot version])
 245   fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 246   if test -z "$fakechroot_version"; then
 247     AC_MSG_RESULT([failed])
 248     AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 249   else
 250     AC_MSG_RESULT([$fakechroot_version])
 251     fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 252     fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 253     if test "$fakechroot_major" -lt 2 -o \
 254             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 255         AC_MSG_ERROR([fakechroot version must be >= 2.9])
 256     fi
 257   fi
 258   DIST="REDHAT"
 259 else
 260   # check for debootstrap and debirf
 261   AC_CHECK_PROG([DEBOOTSTRAP],
 262         [debootstrap],[debootstrap],[no])
 263   test "x$DEBOOTSTRAP" = "xno" && \
 264         AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 265   AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 266   test "x$DEBIRF" = "xno" &&
 267         AC_MSG_ERROR([debirf must be installed])
 268   DIST="DEBIAN"
 269   case "$host_cpu" in
 270       *86)
 271           DEBIAN_KERNEL_ARCH=486
 272           ;;
 273       x86_64)
 274           DEBIAN_KERNEL_ARCH=amd64
 275           ;;
 276       *)
 277          DEBIAN_KERNEL_ARCH=$host_cpu
 278          ;;
 279    esac
 280    AC_SUBST(DEBIAN_KERNEL_ARCH)
 281 fi
 282 AC_SUBST(DIST)
 283
 284
 285 dnl --with-repo to specify a Fedora repository.
 286 AC_ARG_WITH([repo],
 287         [AS_HELP_STRING([--with-repo],
 288           [set name of Fedora repository @<:@default=fedora-11@:>@])],
 289         [],
 290         [with_repo=fedora-11])
 291 REPO="$with_repo"
 292 AC_SUBST(REPO)
 293 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 294
 295 dnl --with-updates to specify a Fedora updates repository.
 296 AC_ARG_WITH([updates],
 297         [AS_HELP_STRING([--with-updates],
 298           [set name of Fedora updates repository @<:@default=updates-released-f11@:>@])],
 299         [],
 300         [with_updates=updates-released-f11])
 301 UPDATES="$with_updates"
 302 AC_SUBST(UPDATES)
 303
 304 dnl Define a symbol for the host CPU architecture.
 305 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 306
 307 dnl --with-mirror to specify a local Fedora mirror.
 308 AC_ARG_WITH([mirror],
 309         [AS_HELP_STRING([--with-mirror],
 310           [set URI of a local Fedora mirror])],
 311         [],
 312         [with_mirror=])
 313 MIRROR="$with_mirror"
 314 AC_SUBST(MIRROR)
 315
 316 dnl Build the supermin appliance?  Please see README file before
 317 dnl enabling this option.
 318 AC_ARG_ENABLE([supermin],
 319         [AS_HELP_STRING([--enable-supermin],
 320           [enable supermin appliance (see README) @<:@default=no@:>@])],
 321         [],
 322         [enable_supermin=no])
 323 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 324
 325 if test "x$enable_supermin" = "xyes"; then
 326     dnl Check febootstrap-to-initramfs accepts the --files option
 327     dnl (febootstrap >= 2.2).
 328     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 329     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 330     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 331     if ! echo "$out" | grep -sq -e --files ; then
 332         AC_MSG_RESULT([no])
 333         AC_MSG_FAILURE(
 334 [febootstrap-to-initramfs does not support the --files option.
 335
 336 To build the supermin appliance, you need to upgrade to the latest
 337 version of febootstrap.
 338 ])
 339     fi
 340     AC_MSG_RESULT([yes])
 341
 342     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 343     dnl (febootstrap >= 2.3).
 344     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 345     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 346     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 347     if ! echo "$out" | grep -sq -e --nocompress ; then
 348         AC_MSG_RESULT([no])
 349         AC_MSG_FAILURE(
 350 [febootstrap-to-initramfs does not support the --nocompress option.
 351
 352 To build the supermin appliance, you need to upgrade to the latest
 353 version of febootstrap.
 354 ])
 355     fi
 356     AC_MSG_RESULT([yes])
 357 fi
 358
 359 dnl Readline.
 360 AC_ARG_WITH([readline],
 361     [AS_HELP_STRING([--with-readline],
 362         [support fancy command line editing @<:@default=check@:>@])],
 363     [],
 364     [with_readline=check])
 365
 366 LIBREADLINE=
 367 AS_IF([test "x$with_readline" != xno],
 368     [AC_CHECK_LIB([readline], [main],
 369         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 370          AC_DEFINE([HAVE_LIBREADLINE], [1],
 371                    [Define if you have libreadline])
 372         ],
 373         [if test "x$with_readline" != xcheck; then
 374          AC_MSG_FAILURE(
 375              [--with-readline was given, but test for readline failed])
 376          fi
 377         ], -lncurses)])
 378
 379 dnl For i18n.
 380 AM_GNU_GETTEXT([external])
 381 AM_GNU_GETTEXT_VERSION([0.14])
 382
 383 dnl Check for OCaml (optional, for OCaml bindings).
 384 AC_PROG_OCAML
 385 AC_PROG_FINDLIB
 386 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 387
 388 dnl Check for Perl (optional, for Perl bindings).
 389 dnl XXX This isn't quite right, we should check for Perl devel library.
 390 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 391
 392 dnl Check for Perl modules that must be present to compile and
 393 dnl test the Perl bindings.
 394 missing_perl_modules=no
 395 for pm in Test::More Test::Pod Test::Pod::Coverage ExtUtils::MakeMaker; do
 396     AC_MSG_CHECKING([for $pm])
 397     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 398         AC_MSG_RESULT([no])
 399         missing_perl_modules=yes
 400     else
 401         AC_MSG_RESULT([yes])
 402     fi
 403 done
 404 if test "x$missing_perl_modules" = "xyes"; then
 405     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 406 fi
 407
 408 AM_CONDITIONAL([HAVE_PERL],
 409     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 410
 411 dnl Check for Python (optional, for Python bindings).
 412 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 413
 414 PYTHON_PREFIX=
 415 PYTHON_VERSION=
 416 PYTHON_INCLUDEDIR=
 417 PYTHON_SITE_PACKAGES=
 418
 419 if test "x$PYTHON" != "xno"; then
 420     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 421     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 422     for d in \
 423         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 424         /usr/include/python$PYTHON_VERSION \
 425         /usr/local/include/python$PYTHON_VERSION
 426     do
 427         AC_MSG_CHECKING([Python.h in $d])
 428         if test -r "$d/Python.h"; then
 429             AC_MSG_RESULT([found])
 430             PYTHON_INCLUDEDIR=$d
 431             break
 432         fi
 433         AC_MSG_RESULT([not found])
 434     done
 435     for d in \
 436         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 437         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 438         /usr/lib64/python$PYTHON_VERSION/site-packages \
 439         /usr/lib/python$PYTHON_VERSION/site-packages \
 440         /usr/local/lib/python$PYTHON_VERSION/site-packages
 441     do
 442         AC_MSG_CHECKING([for $d])
 443         if test -d "$d"; then
 444             AC_MSG_RESULT([found])
 445             PYTHON_SITE_PACKAGES=$d
 446             break
 447         fi
 448         AC_MSG_RESULT([not found])
 449     done
 450 fi
 451
 452 AC_SUBST(PYTHON_PREFIX)
 453 AC_SUBST(PYTHON_VERSION)
 454 AC_SUBST(PYTHON_INCLUDEDIR)
 455 AC_SUBST(PYTHON_SITE_PACKAGES)
 456
 457 AM_CONDITIONAL([HAVE_PYTHON],
 458     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 459
 460 dnl Check for Ruby and rake (optional, for Ruby bindings).
 461 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 462 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 463
 464 AM_CONDITIONAL([HAVE_RUBY],
 465     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 466
 467 dnl Check for Java.
 468 AC_ARG_WITH(java_home,
 469     [AS_HELP_STRING([--with-java-home],
 470         [specify path to JDK directory @<:@default=check@:>@])],
 471     [],
 472     [with_java_home=check])
 473
 474 if test "x$with_java_home" != "xno"; then
 475     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 476     then
 477         # Reject unsafe characters in $JAVA_HOME
 478         jh_lf='
 479 '
 480         case $JAVA_HOME in
 481           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 482             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 483         esac
 484         if test -d "$with_java_home"; then
 485             JAVA_HOME="$with_java_home"
 486         else
 487             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 488         fi
 489     fi
 490
 491     if test "x$JAVA_HOME" = "x"; then
 492         # Look for Java in some likely locations.
 493         for d in \
 494             /usr/lib/jvm/java \
 495             /usr/lib/jvm/java-6-openjdk
 496         do
 497             if test -d $d -a -f $d/bin/java; then
 498                 JAVA_HOME=$d
 499                 break
 500             fi
 501         done
 502     fi
 503
 504     if test "x$JAVA_HOME" != "x"; then
 505         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 506         if test ! -x "$JAVA_HOME/bin/java"; then
 507             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 508         else
 509             JAVA="$JAVA_HOME/bin/java"
 510         fi
 511         if test ! -x "$JAVA_HOME/bin/javac"; then
 512             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 513         else
 514             JAVAC="$JAVA_HOME/bin/javac"
 515         fi
 516         if test ! -x "$JAVA_HOME/bin/javah"; then
 517             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 518         else
 519             JAVAH="$JAVA_HOME/bin/javah"
 520         fi
 521         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 522             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 523         else
 524             JAVADOC="$JAVA_HOME/bin/javadoc"
 525         fi
 526         if test ! -x "$JAVA_HOME/bin/jar"; then
 527             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 528         else
 529             JAR="$JAVA_HOME/bin/jar"
 530         fi
 531         java_version=`$JAVA -version 2>&1 | grep "java version"`
 532         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 533
 534         dnl Find jni.h.
 535         AC_MSG_CHECKING([for jni.h])
 536         if test -f "$JAVA_HOME/include/jni.h"; then
 537             JNI_CFLAGS="-I$JAVA_HOME/include"
 538         else
 539             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 540                 head=`find $JAVA_HOME -name jni.h | tail -1`
 541                 dir=`dirname "$head"`
 542                 JNI_CFLAGS="-I$dir"
 543             else
 544                 AC_MSG_FAILURE([missing jni.h header file])
 545             fi
 546         fi
 547         AC_MSG_RESULT([$JNI_CFLAGS])
 548
 549         dnl Find jni_md.h.
 550         AC_MSG_CHECKING([for jni_md.h])
 551         case "$build_os" in
 552         *linux*) system="linux" ;;
 553         *SunOS*) system="solaris" ;;
 554         *cygwin*) system="win32" ;;
 555         *) system="$build_os" ;;
 556         esac
 557         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 558             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 559         else
 560             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 561                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 562                 dir=`dirname "$head"`
 563                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 564             else
 565                 AC_MSG_FAILURE([missing jni_md.h header file])
 566             fi
 567         fi
 568         AC_MSG_RESULT([$JNI_CFLAGS])
 569
 570         dnl Need extra version flag?
 571         AC_MSG_CHECKING([extra javac flags])
 572         JAVAC_FLAGS=
 573         javac_version=`$JAVAC -version 2>&1`
 574         case "$javac_version" in
 575         *Eclipse*)
 576             JAVAC_FLAGS="-source 1.5" ;;
 577         esac
 578         AC_MSG_RESULT([$JAVAC_FLAGS])
 579
 580         dnl Where to install jarfiles.
 581         dnl XXX How to make it configurable?
 582         JAR_INSTALL_DIR=\${prefix}/share/java
 583         JNI_INSTALL_DIR=\${libdir}
 584
 585         dnl JNI version.
 586         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 587         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 588         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 589         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 590     fi
 591 fi
 592
 593 AC_SUBST(JAVA_HOME)
 594 AC_SUBST(JAVA)
 595 AC_SUBST(JAVAC)
 596 AC_SUBST(JAVAH)
 597 AC_SUBST(JAVADOC)
 598 AC_SUBST(JAR)
 599 AC_SUBST(JNI_CFLAGS)
 600 AC_SUBST(JAVAC_FLAGS)
 601 AC_SUBST(JAR_INSTALL_DIR)
 602 AC_SUBST(JNI_INSTALL_DIR)
 603 AC_SUBST(JNI_VERSION_INFO)
 604
 605 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 606
 607 dnl Check for Haskell (GHC).
 608 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 609
 610 AM_CONDITIONAL([HAVE_HASKELL],
 611     [test "x$GHC" != "xno"])
 612
 613 dnl Check for Perl modules needed by virt-df, inspector, etc.
 614 missing_perl_modules=no
 615 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain; do
 616     AC_MSG_CHECKING([for $pm])
 617     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 618         AC_MSG_RESULT([no])
 619         missing_perl_modules=yes
 620     else
 621         AC_MSG_RESULT([yes])
 622     fi
 623 done
 624 if test "x$missing_perl_modules" = "xyes"; then
 625     AC_MSG_WARN([some Perl modules required to compile virt-cat, virt-df and virt-inspector are missing])
 626 fi
 627
 628 AM_CONDITIONAL([HAVE_CAT],
 629     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 630 AM_CONDITIONAL([HAVE_DF],
 631     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 632 AM_CONDITIONAL([HAVE_INSPECTOR],
 633     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 634
 635 dnl Library versioning.
 636 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 637 AC_SUBST(MAX_PROC_NR)
 638
 639 dnl Run in subdirs.
 640 AC_CONFIG_SUBDIRS([daemon])
 641
 642 dnl Produce output files.
 643 AC_CONFIG_HEADERS([config.h])
 644 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 645 AC_CONFIG_FILES([appliance/make.sh],
 646                 [chmod +x appliance/make.sh])
 647 AC_CONFIG_FILES([appliance/update.sh],
 648                 [chmod +x appliance/update.sh])
 649 AC_CONFIG_FILES([appliance/supermin-split.sh],
 650                 [chmod +x appliance/supermin-split.sh])
 651 AC_CONFIG_FILES([appliance/supermin-make.sh],
 652                 [chmod +x appliance/supermin-make.sh])
 653 AC_CONFIG_FILES([appliance/libguestfs-supermin-helper],
 654                 [chmod +x appliance/libguestfs-supermin-helper])
 655 AC_CONFIG_FILES([Makefile
 656                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 657                  appliance/Makefile
 658                  appliance/debian/debirf.conf
 659                  images/Makefile
 660                  capitests/Makefile
 661                  regressions/Makefile
 662                  test-tool/Makefile
 663                  ocaml/Makefile ocaml/examples/Makefile
 664                  perl/Makefile
 665                  python/Makefile
 666                  ruby/Makefile ruby/Rakefile
 667                  java/Makefile
 668                  haskell/Makefile
 669                  cat/Makefile
 670                  df/Makefile
 671                  inspector/Makefile
 672                  libguestfs.pc
 673                  gnulib/lib/Makefile
 674                  gnulib/tests/Makefile
 675                  ocaml/META perl/Makefile.PL])
 676 AC_OUTPUT
 677
 678 dnl Produce summary.
 679 echo
 680 echo
 681 echo "------------------------------------------------------------"
 682 echo "Thank you for downloading $PACKAGE_STRING"
 683 echo
 684 echo "This is how we have configured the optional components for you today:"
 685 echo
 686 echo    "QEMU ................................ $QEMU"
 687 echo -n "OCaml bindings ...................... "
 688 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 689 echo -n "Perl bindings ....................... "
 690 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 691 echo -n "Python bindings ..................... "
 692 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 693 echo -n "Ruby bindings ....................... "
 694 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 695 echo -n "Java bindings ....................... "
 696 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 697 echo -n "Haskell bindings .................... "
 698 if test "x$HAVE_HASKELL" = "x"; then echo "yes"; else echo "no"; fi
 699 echo -n "virt-cat ............................ "
 700 if test "x$HAVE_CAT" = "x"; then echo "yes"; else echo "no"; fi
 701 echo -n "virt-df ............................. "
 702 if test "x$HAVE_DF" = "x"; then echo "yes"; else echo "no"; fi
 703 echo -n "virt-inspector ...................... "
 704 if test "x$HAVE_INSPECTOR" = "x"; then echo "yes"; else echo "no"; fi
 705 echo "supermin appliance .................. $enable_supermin"
 706 echo
 707 echo "If any optional component is configured 'no' when you expected 'yes'"
 708 echo "then you should check the preceeding messages."
 709 echo
 710 echo "Please report bugs back to the mailing list:"
 711 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 712 echo
 713 echo "Next you should type 'make' to build the package,"
 714 echo "then 'make check' to run the tests."
 715 echo "------------------------------------------------------------"