configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [7])
  21 m4_define([libguestfs_release], [0])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Die if the user tries to configure as root, see:
  57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  58 AC_MSG_CHECKING([if you are trying to configure as root])
  59 AS_IF([test "`id -u`" = 0 ],[
  60             AC_MSG_RESULT([yes])
  61             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  62       ],[
  63             AC_MSG_RESULT([no])
  64       ])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 114                                     # was not possible, safe to ignore
 115   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 116   nw="$nw -Wlong-long"              # Allow long long since it's required
 117                                     # by Python, Ruby and xstrtoll.
 118
 119   gl_MANYWARN_ALL_GCC([ws])
 120   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 121   for w in $ws; do
 122     gl_WARN_ADD([$w])
 123   done
 124   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 125   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 126   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 127
 128   # In spite of excluding -Wlogical-op above, it is enabled, as of
 129   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 130   gl_WARN_ADD([-Wno-logical-op])
 131
 132   # Work around warning in src/inspect.c.  This seems to be a bug in gcc 4.5.1.
 133   gl_WARN_ADD([-Wno-strict-overflow])
 134
 135   gl_WARN_ADD([-fdiagnostics-show-option])
 136
 137   AC_SUBST([WARN_CFLAGS])
 138
 139   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 140   AC_DEFINE([_FORTIFY_SOURCE], [2],
 141     [enable compile-time and run-time bounds-checking, and some warnings])
 142   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 143 fi
 144
 145 AC_C_PROTOTYPES
 146 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 147
 148 AM_PROG_CC_C_O
 149
 150 dnl Work out how to specify the linker script to the linker.
 151 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 152 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 153     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 154 AC_SUBST(VERSION_SCRIPT_FLAGS)
 155
 156 dnl Check support for 64 bit file offsets.
 157 AC_SYS_LARGEFILE
 158
 159 dnl Check sizeof long.
 160 AC_CHECK_SIZEOF([long])
 161
 162 dnl Define a C symbol for the host CPU architecture.
 163 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 164
 165 dnl Headers.
 166 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 167
 168 dnl Functions.
 169 AC_CHECK_FUNCS([posix_fallocate])
 170
 171 dnl Build the daemon?
 172 AC_MSG_CHECKING([if we should build the daemon])
 173 AC_ARG_ENABLE([daemon],
 174         [AS_HELP_STRING([--enable-daemon],
 175           [enable building the daemon @<:@default=yes@:>@])],
 176         [],
 177         [enable_daemon=yes])
 178 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 179 AC_MSG_RESULT([$enable_daemon])
 180
 181 dnl Build the appliance?
 182 AC_MSG_CHECKING([if we should build the appliance])
 183 AC_ARG_ENABLE([appliance],
 184         [AS_HELP_STRING([--enable-appliance],
 185           [enable building the appliance @<:@default=yes@:>@])],
 186         [],
 187         [enable_appliance=yes])
 188 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 189 AC_MSG_RESULT([$enable_appliance])
 190
 191 dnl Check for PCRE.
 192 AC_CHECK_LIB([pcre],[pcre_compile],
 193         [AC_SUBST([LIBPCRE], ["-lpcre"])],
 194         [AC_MSG_FAILURE(
 195              [Perl Compatible Regular Expressions library (PCRE) is required])])
 196 AC_CHECK_HEADER([pcre.h],[],
 197         [AC_MSG_FAILURE(
 198              [Perl Compatible Regular Expressions library (PCRE) header file pcre.h is required])])
 199
 200 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 201 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 202 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 203 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 204         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 205         ])
 206
 207 dnl Check for cpio which isn't in the default Pardus install amazingly.
 208 AC_CHECK_PROG([CPIO],[cpio],[cpio],[no])
 209 test "x$CPIO" = "xno" &&
 210      AC_MSG_ERROR([cpio must be installed])
 211
 212 dnl Check for pod2man and pod2text.
 213 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 214 test "x$POD2MAN" = "xno" &&
 215      AC_MSG_ERROR([pod2man must be installed])
 216 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 217 test "x$POD2TEXT" = "xno" &&
 218      AC_MSG_ERROR([pod2text must be installed])
 219
 220 dnl Check for mkisofs.
 221 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 222         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 223 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 224
 225 dnl Check for optional xmllint.
 226 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 227 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 228
 229 dnl Check for QEMU for running binaries on this $host_cpu, fall
 230 dnl back to basic 'qemu'.  Allow the user to override it.
 231 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 232 AC_ARG_WITH([qemu],
 233         [AS_HELP_STRING([--with-qemu],
 234           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 235         [],
 236         [with_qemu="$default_qemu"])
 237 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 238         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 239 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 240 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 241
 242 dnl Check that the chosen qemu has virtio-serial support.
 243 if test "x$vmchannel_test" != "xno"; then
 244     AC_MSG_CHECKING([for virtio-serial support in $QEMU])
 245     if $QEMU -nographic -device \? 2>&1 | grep -sq virtio-serial; then
 246         AC_MSG_RESULT([yes])
 247         vmchannel_guestfwd=guestfwd
 248     else
 249         AC_MSG_RESULT([no])
 250         AC_MSG_FAILURE(
 251 [I did not find virtio-serial support in
 252 $QEMU.
 253
 254 virtio-serial support in qemu or KVM is essential for libguestfs
 255 to operate.
 256
 257 Usually this means that you have to install a newer version of qemu
 258 and/or KVM.  Please read the relevant section in the README file for
 259 more information about this.
 260
 261 You can override this test by setting the environment variable
 262 vmchannel_test=no  However if you don't have the right support
 263 in your qemu, then this just delays the pain.
 264
 265 If I am using the wrong qemu or you want to compile qemu from source
 266 and install it in another location, then you should configure with
 267 the --with-qemu option.
 268 ])
 269     fi
 270 fi
 271
 272 dnl Set default drive interface used by the guestfs_add_drive_opts call
 273 dnl ('-drive ...,if=...' option to qemu).
 274 dnl
 275 dnl If you encounter performance problems with virtio (RHBZ#509383)
 276 dnl then try '--with-drive-if=ide'.
 277 AC_ARG_WITH([drive-if],
 278         [AS_HELP_STRING([--with-drive-if],
 279           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 280         [],
 281         [with_drive_if=virtio])
 282 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 283
 284 dnl Set interface used by the network.  Normally you should
 285 dnl leave this at the default (virtio-net-pci) but you can use the
 286 dnl alternative (ne2k_pci) because of bugs in virtio networking
 287 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 288 AC_ARG_WITH([net-if],
 289         [AS_HELP_STRING([--with-net-if],
 290           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 291         [],
 292         [with_net_if=virtio-net-pci])
 293 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 294
 295 dnl Check for febootstrap etc.
 296 if test "x$enable_appliance" = "xyes"; then
 297     AC_CHECK_PROG([FEBOOTSTRAP],
 298                   [febootstrap],[febootstrap],[no])
 299     if test "x$FEBOOTSTRAP" != "xno"; then
 300       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 301                     [febootstrap-run],[febootstrap-run],[no])
 302       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 303           AC_MSG_ERROR([febootstrap-run must be installed])
 304       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 305                     [febootstrap-install],[febootstrap-install],[no])
 306       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 307           AC_MSG_ERROR([febootstrap-install must be installed])
 308       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 309                     [febootstrap-minimize],[febootstrap-minimize],[no])
 310       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 311           AC_MSG_ERROR([febootstrap-minimize must be installed])
 312       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 313                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 314       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 315           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 316       AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
 317                     [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
 318       test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
 319           AC_MSG_ERROR([febootstrap-to-supermin must be installed])
 320
 321       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 322       dnl of febootstrap, but old versions will fail with yum).
 323       AC_CHECK_PROG([FAKECHROOT],
 324                     [fakechroot],[fakechroot],[no])
 325       test "x$FAKECHROOT" = "xno" && \
 326          AC_MSG_ERROR([fakechroot must be installed])
 327
 328       AC_MSG_CHECKING([fakechroot version])
 329       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 330       if test -z "$fakechroot_version"; then
 331         AC_MSG_RESULT([failed])
 332         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 333       else
 334         AC_MSG_RESULT([$fakechroot_version])
 335         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 336         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 337         if test "$fakechroot_major" -lt 2 || \
 338           ( test "$fakechroot_major" -eq 2 && test "$fakechroot_minor" -lt 9 ); then
 339           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 340         fi
 341       fi
 342       DIST="REDHAT"
 343     else
 344       # check for debootstrap and debirf
 345       AC_CHECK_PROG([DEBOOTSTRAP],
 346                     [debootstrap],[debootstrap],[no])
 347       test "x$DEBOOTSTRAP" = "xno" && \
 348           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 349       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 350       test "x$DEBIRF" = "xno" &&
 351           AC_MSG_ERROR([debirf must be installed])
 352       DIST="DEBIAN"
 353       case "$host_cpu" in
 354       *86)
 355           DEBIAN_KERNEL_ARCH=486
 356           ;;
 357       x86_64)
 358           DEBIAN_KERNEL_ARCH=amd64
 359           ;;
 360       *)
 361          DEBIAN_KERNEL_ARCH=$host_cpu
 362          ;;
 363       esac
 364       AC_SUBST(DEBIAN_KERNEL_ARCH)
 365     fi
 366     AC_SUBST(DIST)
 367
 368     dnl --with-updates to specify a Fedora updates repository.
 369     AC_ARG_WITH([updates],
 370         [AS_HELP_STRING([--with-updates],
 371           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 372         [],
 373         [with_updates=updates-released-f12])
 374     UPDATES="$with_updates"
 375     AC_SUBST(UPDATES)
 376
 377     dnl --with-mirror to specify a local Fedora mirror.
 378     AC_ARG_WITH([mirror],
 379         [AS_HELP_STRING([--with-mirror],
 380           [set URI of a local Fedora mirror])],
 381         [],
 382         [with_mirror=])
 383     MIRROR="$with_mirror"
 384     AC_SUBST(MIRROR)
 385 fi
 386
 387 dnl --with-repo to specify a repository.
 388 AC_ARG_WITH([repo],
 389         [AS_HELP_STRING([--with-repo],
 390           [set name of Fedora repository @<:@default=fedora-13@:>@])],
 391         [],
 392         [with_repo=fedora-13])
 393 REPO="$with_repo"
 394 AC_SUBST(REPO)
 395 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of software repository.])
 396
 397 dnl Build the supermin appliance?  Please see README file before
 398 dnl enabling this option.
 399 AC_ARG_ENABLE([supermin],
 400         [AS_HELP_STRING([--enable-supermin],
 401           [enable supermin appliance (see README) @<:@default=no@:>@])],
 402         [],
 403         [enable_supermin=no])
 404 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 405
 406 dnl Enable packet dumps when in verbose mode.  This generates lots
 407 dnl of debug info, only useful for people debugging the RPC mechanism.
 408 AC_ARG_ENABLE([packet-dump],
 409         [AS_HELP_STRING([--enable-packet-dump],
 410           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 411         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 412         [])
 413
 414 dnl Readline.
 415 AC_ARG_WITH([readline],
 416     [AS_HELP_STRING([--with-readline],
 417         [support fancy command line editing @<:@default=check@:>@])],
 418     [],
 419     [with_readline=check])
 420
 421 LIBREADLINE=
 422 AS_IF([test "x$with_readline" != xno],
 423     [AC_CHECK_LIB([readline], [main],
 424         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 425          AC_DEFINE([HAVE_LIBREADLINE], [1],
 426                    [Define if you have libreadline])
 427         ],
 428         [if test "x$with_readline" != xcheck; then
 429          AC_MSG_FAILURE(
 430              [--with-readline was given, but test for readline failed])
 431          fi
 432         ], -lncurses)
 433      old_LIBS="$LIBS"
 434      LIBS="$LIBS $LIBREADLINE"
 435      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 436      LIBS="$old_LIBS"
 437     ])
 438
 439 dnl For i18n.
 440 AM_GNU_GETTEXT([external])
 441 AM_GNU_GETTEXT_VERSION([0.17])
 442
 443 dnl libmagic (required)
 444 AC_CHECK_LIB([magic],[magic_file],[
 445         AC_SUBST([LIBMAGIC], ["-lmagic"])
 446     ],[
 447         AC_MSG_FAILURE([libmagic is required])
 448     ])
 449 AC_CHECK_HEADER([magic.h],[],[
 450         AC_MSG_FAILURE([magic.h header file is required])
 451     ])
 452
 453 dnl libvirt (required)
 454 PKG_CHECK_MODULES([LIBVIRT], [libvirt])
 455 AC_SUBST([LIBVIRT_CFLAGS])
 456 AC_SUBST([LIBVIRT_LIBS])
 457
 458 dnl libxml2 (required)
 459 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0])
 460 AC_SUBST([LIBXML2_CFLAGS])
 461 AC_SUBST([LIBXML2_LIBS])
 462
 463 dnl Augeas (required)
 464 PKG_CHECK_MODULES([AUGEAS], [augeas])
 465 AC_SUBST([AUGEAS_CFLAGS])
 466 AC_SUBST([AUGEAS_LIBS])
 467
 468 dnl hivex library (required)
 469 dnl This used to be a part of libguestfs, but was spun off into its
 470 dnl own separate upstream project in libguestfs 1.0.85.
 471 PKG_CHECK_MODULES([HIVEX], [hivex])
 472 AC_SUBST([HIVEX_CFLAGS])
 473 AC_SUBST([HIVEX_LIBS])
 474
 475 dnl FUSE is optional to build the FUSE module.
 476 HAVE_FUSE=yes
 477 PKG_CHECK_MODULES([FUSE],[fuse],,[
 478         HAVE_FUSE=no
 479         AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
 480 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
 481
 482 dnl Check for OCaml (optional, for OCaml bindings).
 483 AC_PROG_OCAML
 484 AC_PROG_FINDLIB
 485 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 486
 487 dnl Optional xml-light for running the generator.
 488 OCAML_PKG_xml_light=no
 489 if test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"; then
 490     AC_CHECK_OCAML_PKG([xml-light])
 491 fi
 492 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 493
 494 dnl Build the OCaml viewer example.  This has a lengthy list of
 495 dnl dependencies and we don't attempt to detect them all.  Read
 496 dnl the top of ocaml/examples/viewer.ml before enabling this.
 497 AC_ARG_ENABLE([ocaml-viewer],
 498         [AS_HELP_STRING([--enable-ocaml-viewer],
 499           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 500         [],
 501         [enable_ocaml_viewer=no])
 502 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 503
 504 dnl Check for Perl (optional, for Perl bindings).
 505 dnl XXX This isn't quite right, we should check for Perl devel library.
 506 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 507
 508 dnl Check for Perl modules that must be present to compile and
 509 dnl test the Perl bindings.
 510 missing_perl_modules=no
 511 for pm in Test::More ExtUtils::MakeMaker; do
 512     AC_MSG_CHECKING([for $pm])
 513     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 514         AC_MSG_RESULT([no])
 515         missing_perl_modules=yes
 516     else
 517         AC_MSG_RESULT([yes])
 518     fi
 519 done
 520 if test "x$missing_perl_modules" = "xyes"; then
 521     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 522 fi
 523
 524 AM_CONDITIONAL([HAVE_PERL],
 525     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 526
 527 dnl Check for Python (optional, for Python bindings).
 528 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 529
 530 PYTHON_PREFIX=
 531 PYTHON_VERSION=
 532 PYTHON_INCLUDEDIR=
 533 PYTHON_SITE_PACKAGES=
 534
 535 if test "x$PYTHON" != "xno"; then
 536     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 537     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 538     for d in \
 539         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 540         /usr/include/python$PYTHON_VERSION \
 541         /usr/local/include/python$PYTHON_VERSION
 542     do
 543         AC_MSG_CHECKING([Python.h in $d])
 544         if test -r "$d/Python.h"; then
 545             AC_MSG_RESULT([found])
 546             PYTHON_INCLUDEDIR=$d
 547             break
 548         fi
 549         AC_MSG_RESULT([not found])
 550     done
 551     for d in \
 552         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 553         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 554         /usr/lib64/python$PYTHON_VERSION/site-packages \
 555         /usr/lib/python$PYTHON_VERSION/site-packages \
 556         /usr/local/lib/python$PYTHON_VERSION/site-packages
 557     do
 558         AC_MSG_CHECKING([for $d])
 559         if test -d "$d"; then
 560             AC_MSG_RESULT([found])
 561             PYTHON_SITE_PACKAGES=$d
 562             break
 563         fi
 564         AC_MSG_RESULT([not found])
 565     done
 566
 567     old_LIBS="$LIBS"
 568     LIBS="$LIBS -lpython$PYTHON_VERSION"
 569     AC_CHECK_FUNCS([PyCapsule_New])
 570     LIBS="$old_LIBS"
 571 fi
 572
 573 AC_SUBST(PYTHON_PREFIX)
 574 AC_SUBST(PYTHON_VERSION)
 575 AC_SUBST(PYTHON_INCLUDEDIR)
 576 AC_SUBST(PYTHON_SITE_PACKAGES)
 577
 578 AM_CONDITIONAL([HAVE_PYTHON],
 579     [test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_SITE_PACKAGES" != "x"])
 580
 581 dnl Check for Ruby and rake (optional, for Ruby bindings).
 582 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 583 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 584
 585 AM_CONDITIONAL([HAVE_RUBY],
 586     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 587
 588 dnl Check for Java.
 589 AC_ARG_WITH(java_home,
 590     [AS_HELP_STRING([--with-java-home],
 591         [specify path to JDK directory @<:@default=check@:>@])],
 592     [],
 593     [with_java_home=check])
 594
 595 if test "x$with_java_home" != "xno"; then
 596     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 597     then
 598         # Reject unsafe characters in $JAVA_HOME
 599         jh_lf='
 600 '
 601         case $JAVA_HOME in
 602           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 603             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 604         esac
 605         if test -d "$with_java_home"; then
 606             JAVA_HOME="$with_java_home"
 607         else
 608             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 609         fi
 610     fi
 611
 612     if test "x$JAVA_HOME" = "x"; then
 613         # Look for Java in some likely locations.
 614         for d in \
 615             /usr/lib/jvm/java \
 616             /usr/lib/jvm/java-6-openjdk
 617         do
 618             if test -d $d && test -f $d/bin/java; then
 619                 JAVA_HOME=$d
 620                 break
 621             fi
 622         done
 623     fi
 624
 625     if test "x$JAVA_HOME" != "x"; then
 626         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 627         if test ! -x "$JAVA_HOME/bin/java"; then
 628             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 629         else
 630             JAVA="$JAVA_HOME/bin/java"
 631         fi
 632         if test ! -x "$JAVA_HOME/bin/javac"; then
 633             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 634         else
 635             JAVAC="$JAVA_HOME/bin/javac"
 636         fi
 637         if test ! -x "$JAVA_HOME/bin/javah"; then
 638             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 639         else
 640             JAVAH="$JAVA_HOME/bin/javah"
 641         fi
 642         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 643             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 644         else
 645             JAVADOC="$JAVA_HOME/bin/javadoc"
 646         fi
 647         if test ! -x "$JAVA_HOME/bin/jar"; then
 648             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 649         else
 650             JAR="$JAVA_HOME/bin/jar"
 651         fi
 652         java_version=`$JAVA -version 2>&1 | grep "java version"`
 653         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 654
 655         dnl Find jni.h.
 656         AC_MSG_CHECKING([for jni.h])
 657         if test -f "$JAVA_HOME/include/jni.h"; then
 658             JNI_CFLAGS="-I$JAVA_HOME/include"
 659         else
 660             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 661                 head=`find $JAVA_HOME -name jni.h | tail -1`
 662                 dir=`dirname "$head"`
 663                 JNI_CFLAGS="-I$dir"
 664             else
 665                 AC_MSG_FAILURE([missing jni.h header file])
 666             fi
 667         fi
 668         AC_MSG_RESULT([$JNI_CFLAGS])
 669
 670         dnl Find jni_md.h.
 671         AC_MSG_CHECKING([for jni_md.h])
 672         case "$build_os" in
 673         *linux*) system="linux" ;;
 674         *SunOS*) system="solaris" ;;
 675         *cygwin*) system="win32" ;;
 676         *) system="$build_os" ;;
 677         esac
 678         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 679             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 680         else
 681             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 682                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 683                 dir=`dirname "$head"`
 684                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 685             else
 686                 AC_MSG_FAILURE([missing jni_md.h header file])
 687             fi
 688         fi
 689         AC_MSG_RESULT([$JNI_CFLAGS])
 690
 691         dnl Need extra version flag?
 692         AC_MSG_CHECKING([extra javac flags])
 693         JAVAC_FLAGS=
 694         javac_version=`$JAVAC -version 2>&1`
 695         case "$javac_version" in
 696         *Eclipse*)
 697             JAVAC_FLAGS="-source 1.5" ;;
 698         esac
 699         AC_MSG_RESULT([$JAVAC_FLAGS])
 700
 701         dnl Where to install jarfiles.
 702         dnl XXX How to make it configurable?
 703         JAR_INSTALL_DIR=\${prefix}/share/java
 704         JNI_INSTALL_DIR=\${libdir}
 705
 706         dnl JNI version.
 707         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 708         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 709         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 710         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 711     fi
 712 fi
 713
 714 AC_SUBST(JAVA_HOME)
 715 AC_SUBST(JAVA)
 716 AC_SUBST(JAVAC)
 717 AC_SUBST(JAVAH)
 718 AC_SUBST(JAVADOC)
 719 AC_SUBST(JAR)
 720 AC_SUBST(JNI_CFLAGS)
 721 AC_SUBST(JAVAC_FLAGS)
 722 AC_SUBST(JAR_INSTALL_DIR)
 723 AC_SUBST(JNI_INSTALL_DIR)
 724 AC_SUBST(JNI_VERSION_INFO)
 725
 726 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 727
 728 dnl Check for Haskell (GHC).
 729 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 730
 731 AM_CONDITIONAL([HAVE_HASKELL],
 732     [test "x$GHC" != "xno"])
 733
 734 dnl Check for Perl modules needed by virt-df, inspector, etc.
 735 missing_perl_modules=no
 736 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
 737     AC_MSG_CHECKING([for $pm])
 738     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 739         AC_MSG_RESULT([no])
 740         missing_perl_modules=yes
 741     else
 742         AC_MSG_RESULT([yes])
 743     fi
 744 done
 745 if test "x$missing_perl_modules" = "xyes"; then
 746     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 747 fi
 748
 749 AM_CONDITIONAL([HAVE_INSPECTOR],
 750     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 751 AM_CONDITIONAL([HAVE_TOOLS],
 752     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 753
 754 dnl po4a for translating man pages and POD files (optional).
 755 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 756 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 757
 758 dnl PHP
 759 AC_CHECK_PROG([PHP],[php],[php],[no])
 760 AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 761 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 762
 763 dnl Library versioning.
 764 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 765 AC_SUBST(MAX_PROC_NR)
 766
 767 dnl Run in subdirs.
 768 if test "x$enable_daemon" = "xyes"; then
 769     AC_CONFIG_SUBDIRS([daemon])
 770 fi
 771
 772 dnl Produce output files.
 773 AC_CONFIG_HEADERS([config.h])
 774 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 775 AC_CONFIG_FILES([appliance/update.sh],
 776                 [chmod +x appliance/update.sh])
 777 AC_CONFIG_FILES([Makefile
 778                  generator/Makefile
 779                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 780                  appliance/Makefile
 781                  appliance/debian/debirf.conf
 782                  images/Makefile
 783                  capitests/Makefile
 784                  regressions/Makefile
 785                  test-tool/Makefile
 786                  ocaml/Makefile ocaml/examples/Makefile
 787                  perl/Makefile
 788                  python/Makefile
 789                  ruby/Makefile ruby/Rakefile
 790                  java/Makefile
 791                  haskell/Makefile
 792                  inspector/Makefile
 793                  tools/Makefile
 794                  libguestfs.pc
 795                  gnulib/lib/Makefile
 796                  gnulib/tests/Makefile
 797                  fuse/Makefile
 798                  po-docs/Makefile
 799                  po-docs/ja/Makefile
 800                  php/Makefile
 801                  ocaml/META perl/Makefile.PL])
 802 AC_OUTPUT
 803
 804 dnl Produce summary.
 805 echo
 806 echo
 807 echo "------------------------------------------------------------"
 808 echo "Thank you for downloading $PACKAGE_STRING"
 809 echo
 810 echo "This is how we have configured the optional components for you today:"
 811 echo
 812 echo    "Daemon .............................. $enable_daemon"
 813 echo    "Appliance ........................... $enable_appliance"
 814 echo    "QEMU ................................ $QEMU"
 815 echo -n "OCaml bindings ...................... "
 816 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 817 echo -n "Perl bindings ....................... "
 818 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 819 echo -n "Python bindings ..................... "
 820 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 821 echo -n "Ruby bindings ....................... "
 822 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 823 echo -n "Java bindings ....................... "
 824 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 825 echo -n "Haskell bindings .................... "
 826 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 827 echo -n "PHP bindings ........................ "
 828 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 829 echo -n "virt-inspector ...................... "
 830 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 831 echo -n "virt-* tools ........................ "
 832 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 833 echo "supermin appliance .................. $enable_supermin"
 834 echo "FUSE filesystem ..................... $HAVE_FUSE"
 835 echo
 836 echo "If any optional component is configured 'no' when you expected 'yes'"
 837 echo "then you should check the preceeding messages."
 838 echo
 839 echo "Please report bugs back to the mailing list:"
 840 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 841 echo
 842 echo "Next you should type 'make' to build the package,"
 843 echo "then 'make check' to run the tests."
 844 echo "------------------------------------------------------------"