configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [5])
  21 m4_define([libguestfs_release], [12])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Stable or unstable version?
  41 AC_MSG_CHECKING([if this is a stable or unstable branch of libguestfs])
  42 AS_IF([test "$((libguestfs_minor % 2))" -eq 0 ],[
  43             AC_MSG_RESULT([stable])
  44        ],[
  45             AC_MSG_RESULT([unstable])
  46             AC_MSG_NOTICE([
  47 ***
  48 This is a development version of libguestfs. Some APIs may be unstable
  49 until they appear in a stable release of libguestfs (at which point
  50 the C API and ABI is guaranteed to remain stable forever).  For
  51 more information about stable and development branches of libguestfs
  52 please see the section "LIBGUESTFS VERSION NUMBERS" in guestfs(3).
  53 ***])
  54        ])
  55
  56 dnl Die if the user tries to configure as root, see:
  57 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  58 AC_MSG_CHECKING([if you are trying to configure as root])
  59 AS_IF([test "`id -u`" = 0 ],[
  60             AC_MSG_RESULT([yes])
  61             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  62       ],[
  63             AC_MSG_RESULT([no])
  64       ])
  65
  66 dnl Early gnulib initialization.
  67 gl_EARLY
  68 gl_INIT
  69
  70 AC_PROG_LIBTOOL
  71
  72 dnl Check for basic C environment.
  73 AC_PROG_CC_STDC
  74 AC_PROG_INSTALL
  75 AC_PROG_CPP
  76
  77 AC_ARG_ENABLE([gcc-warnings],
  78   [AS_HELP_STRING([--enable-gcc-warnings],
  79                   [turn on lots of GCC warnings (for developers)])],
  80   [case $enableval in
  81      yes|no) ;;
  82      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  83    esac
  84    gl_gcc_warnings=$enableval],
  85   [gl_gcc_warnings=no]
  86 )
  87
  88 if test "$gl_gcc_warnings" = yes; then
  89   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  90   AC_SUBST([WERROR_CFLAGS])
  91
  92   nw=
  93   # This, $nw, is the list of warnings we disable.
  94   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  95   nw="$nw -Waggregate-return"       # anachronistic
  96   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  97   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  98   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  99   nw="$nw -Wcast-qual"              # Too many warnings for now
 100   nw="$nw -Wconversion"             # Too many warnings for now
 101   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 102   nw="$nw -Wsign-conversion"        # Too many warnings for now
 103   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 104   nw="$nw -Wunreachable-code"       # Too many warnings for now
 105   nw="$nw -Wpadded"                 # Our structs are not padded
 106   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 107   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 108   nw="$nw -Wvla"                    # two warnings in mount.c
 109   # things I might fix soon:
 110   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
 111   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
 112   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
 113   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
 114                                     # was not possible, safe to ignore
 115   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 116   nw="$nw -Wlong-long"              # Allow long long since it's required
 117                                     # by Python, Ruby and xstrtoll.
 118
 119   gl_MANYWARN_ALL_GCC([ws])
 120   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 121   for w in $ws; do
 122     gl_WARN_ADD([$w])
 123   done
 124   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 125   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 126   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 127
 128   # In spite of excluding -Wlogical-op above, it is enabled, as of
 129   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 130   gl_WARN_ADD([-Wno-logical-op])
 131
 132   gl_WARN_ADD([-fdiagnostics-show-option])
 133
 134   AC_SUBST([WARN_CFLAGS])
 135
 136   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 137   AC_DEFINE([_FORTIFY_SOURCE], [2],
 138     [enable compile-time and run-time bounds-checking, and some warnings])
 139   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 140 fi
 141
 142 AC_C_PROTOTYPES
 143 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 144
 145 AM_PROG_CC_C_O
 146
 147 dnl Work out how to specify the linker script to the linker.
 148 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 149 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 150     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 151 AC_SUBST(VERSION_SCRIPT_FLAGS)
 152
 153 dnl Check support for 64 bit file offsets.
 154 AC_SYS_LARGEFILE
 155
 156 dnl Check sizeof long.
 157 AC_CHECK_SIZEOF([long])
 158
 159 dnl Define a C symbol for the host CPU architecture.
 160 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 161
 162 dnl Headers.
 163 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 164
 165 dnl Functions.
 166 AC_CHECK_FUNCS([posix_fallocate])
 167
 168 dnl Build the daemon?
 169 AC_MSG_CHECKING([if we should build the daemon])
 170 AC_ARG_ENABLE([daemon],
 171         [AS_HELP_STRING([--enable-daemon],
 172           [enable building the daemon @<:@default=yes@:>@])],
 173         [],
 174         [enable_daemon=yes])
 175 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 176 AC_MSG_RESULT([$enable_daemon])
 177
 178 dnl Build the appliance?
 179 AC_MSG_CHECKING([if we should build the appliance])
 180 AC_ARG_ENABLE([appliance],
 181         [AS_HELP_STRING([--enable-appliance],
 182           [enable building the appliance @<:@default=yes@:>@])],
 183         [],
 184         [enable_appliance=yes])
 185 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 186 AC_MSG_RESULT([$enable_appliance])
 187
 188 dnl Check for PCRE.
 189 AC_CHECK_LIB([pcre],[pcre_compile],
 190         [AC_SUBST([LIBPCRE], ["-lpcre"])],
 191         [AC_MSG_FAILURE(
 192              [Perl Compatible Regular Expressions library (PCRE) is required])])
 193 AC_CHECK_HEADER([pcre.h],[],
 194         [AC_MSG_FAILURE(
 195              [Perl Compatible Regular Expressions library (PCRE) header file pcre.h is required])])
 196
 197 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 198 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 199 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 200 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 201         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 202         ])
 203
 204 dnl Check for pod2man and pod2text.
 205 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 206 test "x$POD2MAN" = "xno" &&
 207      AC_MSG_ERROR([pod2man must be installed])
 208 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 209 test "x$POD2TEXT" = "xno" &&
 210      AC_MSG_ERROR([pod2text must be installed])
 211
 212 dnl Check for mkisofs.
 213 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 214         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 215 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 216
 217 dnl Check for optional xmllint.
 218 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 219 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 220
 221 dnl Check for QEMU for running binaries on this $host_cpu, fall
 222 dnl back to basic 'qemu'.  Allow the user to override it.
 223 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 224 AC_ARG_WITH([qemu],
 225         [AS_HELP_STRING([--with-qemu],
 226           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 227         [],
 228         [with_qemu="$default_qemu"])
 229 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 230         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 231 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 232 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 233
 234 dnl Check that the chosen qemu has vmchannel support or we can
 235 dnl fallback to null vmchannel (still using SLIRP).  See the
 236 dnl discussion in the README file.
 237 if test "x$vmchannel_test" != "xno"; then
 238     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 239     if $QEMU -nographic --help | grep -sq guestfwd; then
 240         AC_MSG_RESULT([yes])
 241         vmchannel_guestfwd=guestfwd
 242     else
 243         AC_MSG_RESULT([no])
 244         # Note that this test must be conditional on the previous
 245         # test failing.  This is because recent qemu will throw
 246         # up an SDL window and hang if we try to run this test.
 247         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 248         vmchannelout=`$QEMU -nographic -net channel /dev/zero 2>&1 ||:`
 249         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 250         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 251             AC_MSG_RESULT([yes])
 252             vmchannel_guestfwd=net_channel
 253         else
 254             AC_MSG_RESULT([no])
 255             vmchannel_guestfwd=no
 256         fi
 257     fi
 258
 259     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 260     if $QEMU -nographic --help | grep -sq -- "-net user"; then
 261         AC_MSG_RESULT([yes])
 262         vmchannel_net_user=yes
 263     else
 264         AC_MSG_RESULT([no])
 265         vmchannel_net_user=no
 266     fi
 267
 268     if test "x$vmchannel_net_user" = "xno" && test "x$vmchannel_guestfwd" = "xno"; then
 269         AC_MSG_FAILURE(
 270 [I did not find user mode network or vmchannel support in
 271 $QEMU.
 272
 273 Either user mode networking or vmchannel support is vital for
 274 libguestfs to operate.
 275
 276 Please read the relevant section in the README file for more
 277 information about this.
 278
 279 You can override this test by setting the environment variable
 280 vmchannel_test=no  However if you don't have the right support
 281 in your qemu, then this just delays the pain.
 282
 283 If I am using the wrong qemu or you want to compile qemu from source
 284 and install it in another location, then you should configure with
 285 the --with-qemu option.
 286 ])
 287     fi
 288 fi
 289
 290 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 291 dnl ('-drive ...,if=...' option to qemu).
 292 dnl
 293 dnl If you encounter performance problems with virtio (RHBZ#509383)
 294 dnl then try '--with-drive-if=ide'.
 295 AC_ARG_WITH([drive-if],
 296         [AS_HELP_STRING([--with-drive-if],
 297           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 298         [],
 299         [with_drive_if=virtio])
 300 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 301
 302 dnl Set interface used by the network.  Normally you should
 303 dnl leave this at the default (virtio-net-pci) but you can use the
 304 dnl alternative (ne2k_pci) because of bugs in virtio networking
 305 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 306 AC_ARG_WITH([net-if],
 307         [AS_HELP_STRING([--with-net-if],
 308           [set default net driver (virtio-net-pci|ne2k_pci) @<:@default=virtio-net-pci@:>@])],
 309         [],
 310         [with_net_if=virtio-net-pci])
 311 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 312
 313 dnl Check for febootstrap etc.
 314 if test "x$enable_appliance" = "xyes"; then
 315     AC_CHECK_PROG([FEBOOTSTRAP],
 316                   [febootstrap],[febootstrap],[no])
 317     if test "x$FEBOOTSTRAP" != "xno"; then
 318       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 319                     [febootstrap-run],[febootstrap-run],[no])
 320       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 321           AC_MSG_ERROR([febootstrap-run must be installed])
 322       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 323                     [febootstrap-install],[febootstrap-install],[no])
 324       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 325           AC_MSG_ERROR([febootstrap-install must be installed])
 326       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 327                     [febootstrap-minimize],[febootstrap-minimize],[no])
 328       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 329           AC_MSG_ERROR([febootstrap-minimize must be installed])
 330       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 331                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 332       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 333           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 334       AC_CHECK_PROG([FEBOOTSTRAP_TO_SUPERMIN],
 335                     [febootstrap-to-supermin],[febootstrap-to-supermin],[no])
 336       test "x$FEBOOTSTRAP_TO_SUPERMIN" = "xno" && \
 337           AC_MSG_ERROR([febootstrap-to-supermin must be installed])
 338
 339       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 340       dnl of febootstrap, but old versions will fail with yum).
 341       AC_CHECK_PROG([FAKECHROOT],
 342                     [fakechroot],[fakechroot],[no])
 343       test "x$FAKECHROOT" = "xno" && \
 344          AC_MSG_ERROR([fakechroot must be installed])
 345
 346       AC_MSG_CHECKING([fakechroot version])
 347       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 348       if test -z "$fakechroot_version"; then
 349         AC_MSG_RESULT([failed])
 350         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 351       else
 352         AC_MSG_RESULT([$fakechroot_version])
 353         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 354         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 355         if test "$fakechroot_major" -lt 2 || \
 356           ( test "$fakechroot_major" -eq 2 && test "$fakechroot_minor" -lt 9 ); then
 357           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 358         fi
 359       fi
 360       DIST="REDHAT"
 361     else
 362       # check for debootstrap and debirf
 363       AC_CHECK_PROG([DEBOOTSTRAP],
 364                     [debootstrap],[debootstrap],[no])
 365       test "x$DEBOOTSTRAP" = "xno" && \
 366           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 367       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 368       test "x$DEBIRF" = "xno" &&
 369           AC_MSG_ERROR([debirf must be installed])
 370       DIST="DEBIAN"
 371       case "$host_cpu" in
 372       *86)
 373           DEBIAN_KERNEL_ARCH=486
 374           ;;
 375       x86_64)
 376           DEBIAN_KERNEL_ARCH=amd64
 377           ;;
 378       *)
 379          DEBIAN_KERNEL_ARCH=$host_cpu
 380          ;;
 381       esac
 382       AC_SUBST(DEBIAN_KERNEL_ARCH)
 383     fi
 384     AC_SUBST(DIST)
 385
 386     dnl --with-updates to specify a Fedora updates repository.
 387     AC_ARG_WITH([updates],
 388         [AS_HELP_STRING([--with-updates],
 389           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 390         [],
 391         [with_updates=updates-released-f12])
 392     UPDATES="$with_updates"
 393     AC_SUBST(UPDATES)
 394
 395     dnl --with-mirror to specify a local Fedora mirror.
 396     AC_ARG_WITH([mirror],
 397         [AS_HELP_STRING([--with-mirror],
 398           [set URI of a local Fedora mirror])],
 399         [],
 400         [with_mirror=])
 401     MIRROR="$with_mirror"
 402     AC_SUBST(MIRROR)
 403 fi
 404
 405 dnl --with-repo to specify a Fedora repository.
 406 AC_ARG_WITH([repo],
 407         [AS_HELP_STRING([--with-repo],
 408           [set name of Fedora repository @<:@default=fedora-12@:>@])],
 409         [],
 410         [with_repo=fedora-12])
 411 REPO="$with_repo"
 412 AC_SUBST(REPO)
 413 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 414
 415 dnl Build the supermin appliance?  Please see README file before
 416 dnl enabling this option.
 417 AC_ARG_ENABLE([supermin],
 418         [AS_HELP_STRING([--enable-supermin],
 419           [enable supermin appliance (see README) @<:@default=no@:>@])],
 420         [],
 421         [enable_supermin=no])
 422 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 423
 424 dnl Enable packet dumps when in verbose mode.  This generates lots
 425 dnl of debug info, only useful for people debugging the RPC mechanism.
 426 AC_ARG_ENABLE([packet-dump],
 427         [AS_HELP_STRING([--enable-packet-dump],
 428           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 429         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 430         [])
 431
 432 dnl Readline.
 433 AC_ARG_WITH([readline],
 434     [AS_HELP_STRING([--with-readline],
 435         [support fancy command line editing @<:@default=check@:>@])],
 436     [],
 437     [with_readline=check])
 438
 439 LIBREADLINE=
 440 AS_IF([test "x$with_readline" != xno],
 441     [AC_CHECK_LIB([readline], [main],
 442         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 443          AC_DEFINE([HAVE_LIBREADLINE], [1],
 444                    [Define if you have libreadline])
 445         ],
 446         [if test "x$with_readline" != xcheck; then
 447          AC_MSG_FAILURE(
 448              [--with-readline was given, but test for readline failed])
 449          fi
 450         ], -lncurses)
 451      old_LIBS="$LIBS"
 452      LIBS="$LIBS $LIBREADLINE"
 453      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 454      LIBS="$old_LIBS"
 455     ])
 456
 457 dnl For i18n.
 458 AM_GNU_GETTEXT([external])
 459 AM_GNU_GETTEXT_VERSION([0.17])
 460
 461 dnl libmagic (required)
 462 AC_CHECK_LIB([magic],[magic_file],[
 463         AC_SUBST([LIBMAGIC], ["-lmagic"])
 464     ],[
 465         AC_MSG_FAILURE([libmagic is required])
 466     ])
 467 AC_CHECK_HEADER([magic.h],[],[
 468         AC_MSG_FAILURE([magic.h header file is required])
 469     ])
 470
 471 dnl libvirt (required)
 472 PKG_CHECK_MODULES([LIBVIRT], [libvirt])
 473 AC_SUBST([LIBVIRT_CFLAGS])
 474 AC_SUBST([LIBVIRT_LIBS])
 475
 476 dnl libxml2 (required)
 477 PKG_CHECK_MODULES([LIBXML2], [libxml-2.0])
 478 AC_SUBST([LIBXML2_CFLAGS])
 479 AC_SUBST([LIBXML2_LIBS])
 480
 481 dnl Augeas (required)
 482 PKG_CHECK_MODULES([AUGEAS], [augeas])
 483 AC_SUBST([AUGEAS_CFLAGS])
 484 AC_SUBST([AUGEAS_LIBS])
 485
 486 dnl hivex library (highly recommended).
 487 dnl This used to be a part of libguestfs, but was spun off into its
 488 dnl own separate upstream project in libguestfs 1.0.85.
 489 HAVE_HIVEX=yes
 490 PKG_CHECK_MODULES([HIVEX], [hivex],,[
 491         HAVE_HIVEX=no
 492         AC_MSG_WARN([Hivex library and headers are missing, so optional Windows Registry tools won't be built])])
 493 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HAVE_HIVEX" = "xyes"])
 494 AC_SUBST([HIVEX_CFLAGS])
 495 AC_SUBST([HIVEX_LIBS])
 496
 497 dnl FUSE is optional to build the FUSE module.
 498 HAVE_FUSE=yes
 499 PKG_CHECK_MODULES([FUSE],[fuse],,[
 500         HAVE_FUSE=no
 501         AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
 502 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
 503
 504 dnl Check for OCaml (optional, for OCaml bindings).
 505 AC_PROG_OCAML
 506 AC_PROG_FINDLIB
 507 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"])
 508
 509 dnl Optional xml-light for running the generator.
 510 OCAML_PKG_xml_light=no
 511 if test "x$OCAMLC" != "xno" && test "x$OCAMLFIND" != "xno"; then
 512     AC_CHECK_OCAML_PKG([xml-light])
 513 fi
 514 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 515
 516 dnl Build the OCaml viewer example.  This has a lengthy list of
 517 dnl dependencies and we don't attempt to detect them all.  Read
 518 dnl the top of ocaml/examples/viewer.ml before enabling this.
 519 AC_ARG_ENABLE([ocaml-viewer],
 520         [AS_HELP_STRING([--enable-ocaml-viewer],
 521           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 522         [],
 523         [enable_ocaml_viewer=no])
 524 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 525
 526 dnl Check for Perl (optional, for Perl bindings).
 527 dnl XXX This isn't quite right, we should check for Perl devel library.
 528 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 529
 530 dnl Check for Perl modules that must be present to compile and
 531 dnl test the Perl bindings.
 532 missing_perl_modules=no
 533 for pm in Test::More ExtUtils::MakeMaker; do
 534     AC_MSG_CHECKING([for $pm])
 535     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 536         AC_MSG_RESULT([no])
 537         missing_perl_modules=yes
 538     else
 539         AC_MSG_RESULT([yes])
 540     fi
 541 done
 542 if test "x$missing_perl_modules" = "xyes"; then
 543     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 544 fi
 545
 546 AM_CONDITIONAL([HAVE_PERL],
 547     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 548
 549 dnl Check for Python (optional, for Python bindings).
 550 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 551
 552 PYTHON_PREFIX=
 553 PYTHON_VERSION=
 554 PYTHON_INCLUDEDIR=
 555 PYTHON_SITE_PACKAGES=
 556
 557 if test "x$PYTHON" != "xno"; then
 558     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 559     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 560     for d in \
 561         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 562         /usr/include/python$PYTHON_VERSION \
 563         /usr/local/include/python$PYTHON_VERSION
 564     do
 565         AC_MSG_CHECKING([Python.h in $d])
 566         if test -r "$d/Python.h"; then
 567             AC_MSG_RESULT([found])
 568             PYTHON_INCLUDEDIR=$d
 569             break
 570         fi
 571         AC_MSG_RESULT([not found])
 572     done
 573     for d in \
 574         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 575         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 576         /usr/lib64/python$PYTHON_VERSION/site-packages \
 577         /usr/lib/python$PYTHON_VERSION/site-packages \
 578         /usr/local/lib/python$PYTHON_VERSION/site-packages
 579     do
 580         AC_MSG_CHECKING([for $d])
 581         if test -d "$d"; then
 582             AC_MSG_RESULT([found])
 583             PYTHON_SITE_PACKAGES=$d
 584             break
 585         fi
 586         AC_MSG_RESULT([not found])
 587     done
 588
 589     old_LIBS="$LIBS"
 590     LIBS="$LIBS -lpython$PYTHON_VERSION"
 591     AC_CHECK_FUNCS([PyCapsule_New])
 592     LIBS="$old_LIBS"
 593 fi
 594
 595 AC_SUBST(PYTHON_PREFIX)
 596 AC_SUBST(PYTHON_VERSION)
 597 AC_SUBST(PYTHON_INCLUDEDIR)
 598 AC_SUBST(PYTHON_SITE_PACKAGES)
 599
 600 AM_CONDITIONAL([HAVE_PYTHON],
 601     [test "x$PYTHON_INCLUDEDIR" != "x" && test "x$PYTHON_SITE_PACKAGES" != "x"])
 602
 603 dnl Check for Ruby and rake (optional, for Ruby bindings).
 604 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 605 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 606
 607 AM_CONDITIONAL([HAVE_RUBY],
 608     [test "x$RAKE" != "xno" && test -n "$HAVE_LIBRUBY"])
 609
 610 dnl Check for Java.
 611 AC_ARG_WITH(java_home,
 612     [AS_HELP_STRING([--with-java-home],
 613         [specify path to JDK directory @<:@default=check@:>@])],
 614     [],
 615     [with_java_home=check])
 616
 617 if test "x$with_java_home" != "xno"; then
 618     if test "x$with_java_home" != "xyes" && test "x$with_java_home" != "xcheck"
 619     then
 620         # Reject unsafe characters in $JAVA_HOME
 621         jh_lf='
 622 '
 623         case $JAVA_HOME in
 624           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 625             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 626         esac
 627         if test -d "$with_java_home"; then
 628             JAVA_HOME="$with_java_home"
 629         else
 630             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 631         fi
 632     fi
 633
 634     if test "x$JAVA_HOME" = "x"; then
 635         # Look for Java in some likely locations.
 636         for d in \
 637             /usr/lib/jvm/java \
 638             /usr/lib/jvm/java-6-openjdk
 639         do
 640             if test -d $d && test -f $d/bin/java; then
 641                 JAVA_HOME=$d
 642                 break
 643             fi
 644         done
 645     fi
 646
 647     if test "x$JAVA_HOME" != "x"; then
 648         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 649         if test ! -x "$JAVA_HOME/bin/java"; then
 650             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 651         else
 652             JAVA="$JAVA_HOME/bin/java"
 653         fi
 654         if test ! -x "$JAVA_HOME/bin/javac"; then
 655             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 656         else
 657             JAVAC="$JAVA_HOME/bin/javac"
 658         fi
 659         if test ! -x "$JAVA_HOME/bin/javah"; then
 660             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 661         else
 662             JAVAH="$JAVA_HOME/bin/javah"
 663         fi
 664         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 665             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 666         else
 667             JAVADOC="$JAVA_HOME/bin/javadoc"
 668         fi
 669         if test ! -x "$JAVA_HOME/bin/jar"; then
 670             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 671         else
 672             JAR="$JAVA_HOME/bin/jar"
 673         fi
 674         java_version=`$JAVA -version 2>&1 | grep "java version"`
 675         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 676
 677         dnl Find jni.h.
 678         AC_MSG_CHECKING([for jni.h])
 679         if test -f "$JAVA_HOME/include/jni.h"; then
 680             JNI_CFLAGS="-I$JAVA_HOME/include"
 681         else
 682             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 683                 head=`find $JAVA_HOME -name jni.h | tail -1`
 684                 dir=`dirname "$head"`
 685                 JNI_CFLAGS="-I$dir"
 686             else
 687                 AC_MSG_FAILURE([missing jni.h header file])
 688             fi
 689         fi
 690         AC_MSG_RESULT([$JNI_CFLAGS])
 691
 692         dnl Find jni_md.h.
 693         AC_MSG_CHECKING([for jni_md.h])
 694         case "$build_os" in
 695         *linux*) system="linux" ;;
 696         *SunOS*) system="solaris" ;;
 697         *cygwin*) system="win32" ;;
 698         *) system="$build_os" ;;
 699         esac
 700         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 701             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 702         else
 703             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 704                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 705                 dir=`dirname "$head"`
 706                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 707             else
 708                 AC_MSG_FAILURE([missing jni_md.h header file])
 709             fi
 710         fi
 711         AC_MSG_RESULT([$JNI_CFLAGS])
 712
 713         dnl Need extra version flag?
 714         AC_MSG_CHECKING([extra javac flags])
 715         JAVAC_FLAGS=
 716         javac_version=`$JAVAC -version 2>&1`
 717         case "$javac_version" in
 718         *Eclipse*)
 719             JAVAC_FLAGS="-source 1.5" ;;
 720         esac
 721         AC_MSG_RESULT([$JAVAC_FLAGS])
 722
 723         dnl Where to install jarfiles.
 724         dnl XXX How to make it configurable?
 725         JAR_INSTALL_DIR=\${prefix}/share/java
 726         JNI_INSTALL_DIR=\${libdir}
 727
 728         dnl JNI version.
 729         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 730         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 731         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 732         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 733     fi
 734 fi
 735
 736 AC_SUBST(JAVA_HOME)
 737 AC_SUBST(JAVA)
 738 AC_SUBST(JAVAC)
 739 AC_SUBST(JAVAH)
 740 AC_SUBST(JAVADOC)
 741 AC_SUBST(JAR)
 742 AC_SUBST(JNI_CFLAGS)
 743 AC_SUBST(JAVAC_FLAGS)
 744 AC_SUBST(JAR_INSTALL_DIR)
 745 AC_SUBST(JNI_INSTALL_DIR)
 746 AC_SUBST(JNI_VERSION_INFO)
 747
 748 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 749
 750 dnl Check for Haskell (GHC).
 751 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 752
 753 AM_CONDITIONAL([HAVE_HASKELL],
 754     [test "x$GHC" != "xno"])
 755
 756 dnl Check for Perl modules needed by virt-df, inspector, etc.
 757 missing_perl_modules=no
 758 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
 759     AC_MSG_CHECKING([for $pm])
 760     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 761         AC_MSG_RESULT([no])
 762         missing_perl_modules=yes
 763     else
 764         AC_MSG_RESULT([yes])
 765     fi
 766 done
 767 if test "x$missing_perl_modules" = "xyes"; then
 768     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 769 fi
 770
 771 AM_CONDITIONAL([HAVE_INSPECTOR],
 772     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 773 AM_CONDITIONAL([HAVE_TOOLS],
 774     [test "x$PERL" != "xno" && test "x$missing_perl_modules" != "xyes"])
 775
 776 dnl po4a for translating man pages and POD files (optional).
 777 AC_CHECK_PROG([PO4A],[po4a],[po4a],[no])
 778 AM_CONDITIONAL([HAVE_PO4A], [test "x$PO4A" != "xno"])
 779
 780 dnl PHP
 781 AC_CHECK_PROG([PHP],[php],[php],[no])
 782 AC_CHECK_PROG([PHPIZE],[phpize],[phpize],[no])
 783 AM_CONDITIONAL([HAVE_PHP], [test "x$PHP" != "xno" && test "x$PHPIZE" != "xno"])
 784
 785 dnl Library versioning.
 786 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 787 AC_SUBST(MAX_PROC_NR)
 788
 789 dnl Run in subdirs.
 790 if test "x$enable_daemon" = "xyes"; then
 791     AC_CONFIG_SUBDIRS([daemon])
 792 fi
 793
 794 dnl Produce output files.
 795 AC_CONFIG_HEADERS([config.h])
 796 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 797 AC_CONFIG_FILES([appliance/update.sh],
 798                 [chmod +x appliance/update.sh])
 799 AC_CONFIG_FILES([Makefile
 800                  generator/Makefile
 801                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 802                  appliance/Makefile
 803                  appliance/debian/debirf.conf
 804                  images/Makefile
 805                  capitests/Makefile
 806                  regressions/Makefile
 807                  test-tool/Makefile
 808                  ocaml/Makefile ocaml/examples/Makefile
 809                  perl/Makefile
 810                  python/Makefile
 811                  ruby/Makefile ruby/Rakefile
 812                  java/Makefile
 813                  haskell/Makefile
 814                  inspector/Makefile
 815                  tools/Makefile
 816                  libguestfs.pc
 817                  gnulib/lib/Makefile
 818                  gnulib/tests/Makefile
 819                  fuse/Makefile
 820                  po-docs/Makefile
 821                  po-docs/ja/Makefile
 822                  php/Makefile
 823                  ocaml/META perl/Makefile.PL])
 824 AC_OUTPUT
 825
 826 dnl Produce summary.
 827 echo
 828 echo
 829 echo "------------------------------------------------------------"
 830 echo "Thank you for downloading $PACKAGE_STRING"
 831 echo
 832 echo "This is how we have configured the optional components for you today:"
 833 echo
 834 echo    "Daemon .............................. $enable_daemon"
 835 echo    "Appliance ........................... $enable_appliance"
 836 echo    "QEMU ................................ $QEMU"
 837 echo -n "OCaml bindings ...................... "
 838 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 839 echo -n "Perl bindings ....................... "
 840 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 841 echo -n "Python bindings ..................... "
 842 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 843 echo -n "Ruby bindings ....................... "
 844 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 845 echo -n "Java bindings ....................... "
 846 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 847 echo -n "Haskell bindings .................... "
 848 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 849 echo -n "PHP bindings ........................ "
 850 if test "x$HAVE_PHP_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 851 echo -n "virt-inspector ...................... "
 852 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 853 echo -n "virt-* tools ........................ "
 854 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 855 echo "supermin appliance .................. $enable_supermin"
 856 echo "FUSE filesystem ..................... $HAVE_FUSE"
 857 echo
 858 echo "If any optional component is configured 'no' when you expected 'yes'"
 859 echo "then you should check the preceeding messages."
 860 echo
 861 echo "Please report bugs back to the mailing list:"
 862 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 863 echo
 864 echo "Next you should type 'make' to build the package,"
 865 echo "then 'make check' to run the tests."
 866 echo "------------------------------------------------------------"