configure.ac

   1 # libguestfs
   2 # Copyright (C) 2009-2010 Red Hat Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 # major/minor/release must be numbers
  19 m4_define([libguestfs_major],   [1])
  20 m4_define([libguestfs_minor],   [3])
  21 m4_define([libguestfs_release], [11])
  22 # extra can be any string
  23 m4_define([libguestfs_extra],   [])
  24
  25 AC_INIT([libguestfs],libguestfs_major.libguestfs_minor.libguestfs_release[]libguestfs_extra)
  26 AC_CONFIG_AUX_DIR([build-aux])
  27 AM_INIT_AUTOMAKE([foreign])
  28
  29 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  30 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  31
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 dnl Split up the version string.
  35 AC_DEFINE([PACKAGE_VERSION_MAJOR],[libguestfs_major],[Major version number])
  36 AC_DEFINE([PACKAGE_VERSION_MINOR],[libguestfs_minor],[Minor version number])
  37 AC_DEFINE([PACKAGE_VERSION_RELEASE],[libguestfs_release],[Release number])
  38 AC_DEFINE([PACKAGE_VERSION_EXTRA],["libguestfs_extra"],[Extra version string])
  39
  40 dnl Die if the user tries to configure as root, see:
  41 dnl https://www.redhat.com/archives/libguestfs/2010-April/msg00098.html
  42 AC_MSG_CHECKING([if you are trying to configure as root])
  43 AS_IF([test "`id -u`" = 0 ],[
  44             AC_MSG_RESULT([yes])
  45             AC_MSG_FAILURE([Don't run './configure' or 'make' as root.])
  46       ],[
  47             AC_MSG_RESULT([no])
  48       ])
  49
  50 dnl Early gnulib initialization.
  51 gl_EARLY
  52 gl_INIT
  53
  54 AC_PROG_LIBTOOL
  55
  56 dnl Check for basic C environment.
  57 AC_PROG_CC_STDC
  58 AC_PROG_INSTALL
  59 AC_PROG_CPP
  60
  61 AC_ARG_ENABLE([gcc-warnings],
  62   [AS_HELP_STRING([--enable-gcc-warnings],
  63                   [turn on lots of GCC warnings (for developers)])],
  64   [case $enableval in
  65      yes|no) ;;
  66      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  67    esac
  68    gl_gcc_warnings=$enableval],
  69   [gl_gcc_warnings=no]
  70 )
  71
  72 if test "$gl_gcc_warnings" = yes; then
  73   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  74   AC_SUBST([WERROR_CFLAGS])
  75
  76   nw=
  77   # This, $nw, is the list of warnings we disable.
  78   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  79   nw="$nw -Waggregate-return"       # anachronistic
  80   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  81   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  82   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  83   nw="$nw -Wcast-qual"              # Too many warnings for now
  84   nw="$nw -Wconversion"             # Too many warnings for now
  85   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  86   nw="$nw -Wsign-conversion"        # Too many warnings for now
  87   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  88   nw="$nw -Wunreachable-code"       # Too many warnings for now
  89   nw="$nw -Wpadded"                 # Our structs are not padded
  90   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  91   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  92   nw="$nw -Wvla"                    # two warnings in mount.c
  93   # things I might fix soon:
  94   nw="$nw -Wmissing-format-attribute" # daemon.h's asprintf_nowarn
  95   nw="$nw -Winline"                 # daemon.h's asprintf_nowarn
  96   nw="$nw -Wshadow"                 # numerous, plus we're not unanimous
  97   # ?? -Wstrict-overflow
  98   nw="$nw -Wunsafe-loop-optimizations" # just a warning that an optimization
  99                                     # was not possible, safe to ignore
 100   nw="$nw -Wpacked"                 # Allow attribute((packed)) on structs
 101
 102   gl_MANYWARN_ALL_GCC([ws])
 103   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 104   for w in $ws; do
 105     gl_WARN_ADD([$w])
 106   done
 107   gl_WARN_ADD([-Wno-unused-parameter]) # stubs.c
 108   gl_WARN_ADD([-Wno-jump-misses-init]) # stubs.c
 109   gl_WARN_ADD([-Wno-unused-variable]) # FIXME: only temporary, for guestfs_protocol.c, etc
 110
 111   # In spite of excluding -Wlogical-op above, it is enabled, as of
 112   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 113   gl_WARN_ADD([-Wno-logical-op])
 114
 115   gl_WARN_ADD([-fdiagnostics-show-option])
 116
 117   AC_SUBST([WARN_CFLAGS])
 118
 119   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 120   AC_DEFINE([_FORTIFY_SOURCE], [2],
 121     [enable compile-time and run-time bounds-checking, and some warnings])
 122   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 123 fi
 124
 125 AC_C_PROTOTYPES
 126 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
 127
 128 AM_PROG_CC_C_O
 129
 130 dnl Work out how to specify the linker script to the linker.
 131 VERSION_SCRIPT_FLAGS=-Wl,--version-script=
 132 `/usr/bin/ld --help 2>&1 | grep -- --version-script >/dev/null` || \
 133     VERSION_SCRIPT_FLAGS="-Wl,-M -Wl,"
 134 AC_SUBST(VERSION_SCRIPT_FLAGS)
 135
 136 dnl Check support for 64 bit file offsets.
 137 AC_SYS_LARGEFILE
 138
 139 dnl Check sizeof long.
 140 AC_CHECK_SIZEOF([long])
 141
 142 dnl Define a C symbol for the host CPU architecture.
 143 AC_DEFINE_UNQUOTED([host_cpu],["$host_cpu"],[Host architecture.])
 144
 145 dnl Headers.
 146 AC_CHECK_HEADERS([errno.h sys/types.h sys/un.h sys/wait.h sys/socket.h endian.h byteswap.h])
 147
 148 dnl Functions.
 149 AC_CHECK_FUNCS([posix_fallocate])
 150
 151 dnl Build the daemon?
 152 AC_MSG_CHECKING([if we should build the daemon])
 153 AC_ARG_ENABLE([daemon],
 154         [AS_HELP_STRING([--enable-daemon],
 155           [enable building the daemon @<:@default=yes@:>@])],
 156         [],
 157         [enable_daemon=yes])
 158 AM_CONDITIONAL([ENABLE_DAEMON],[test "x$enable_daemon" = "xyes"])
 159 AC_MSG_RESULT([$enable_daemon])
 160
 161 dnl Build the appliance?
 162 AC_MSG_CHECKING([if we should build the appliance])
 163 AC_ARG_ENABLE([appliance],
 164         [AS_HELP_STRING([--enable-appliance],
 165           [enable building the appliance @<:@default=yes@:>@])],
 166         [],
 167         [enable_appliance=yes])
 168 AM_CONDITIONAL([ENABLE_APPLIANCE],[test "x$enable_appliance" = "xyes"])
 169 AC_MSG_RESULT([$enable_appliance])
 170
 171 dnl Check for rpcgen and XDR library.  rpcgen is optional.
 172 AC_CHECK_PROG([RPCGEN],[rpcgen],[rpcgen],[no])
 173 AM_CONDITIONAL([HAVE_RPCGEN],[test "x$RPCGEN" != "xno"])
 174 AC_CHECK_LIB([portablexdr],[xdrmem_create],[],[
 175         AC_SEARCH_LIBS([xdrmem_create],[rpc xdr nsl])
 176         ])
 177
 178 dnl Check for pod2man and pod2text.
 179 AC_CHECK_PROG([POD2MAN],[pod2man],[pod2man],[no])
 180 test "x$POD2MAN" = "xno" &&
 181      AC_MSG_ERROR([pod2man must be installed])
 182 AC_CHECK_PROG([POD2TEXT],[pod2text],[pod2text],[no])
 183 test "x$POD2TEXT" = "xno" &&
 184      AC_MSG_ERROR([pod2text must be installed])
 185
 186 dnl Check for mkisofs.
 187 AC_PATH_PROGS([MKISOFS],[mkisofs],[no],
 188         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 189 test "x$MKISOFS" = "xno" && AC_MSG_ERROR([mkisofs must be installed])
 190
 191 dnl Check for optional xmllint.
 192 AC_CHECK_PROG([XMLLINT],[xmllint],[xmllint],[no])
 193 AM_CONDITIONAL([HAVE_XMLLINT],[test "x$XMLLINT" != "xno"])
 194
 195 dnl Check for QEMU for running binaries on this $host_cpu, fall
 196 dnl back to basic 'qemu'.  Allow the user to override it.
 197 default_qemu="qemu-kvm qemu-system-$host_cpu qemu"
 198 AC_ARG_WITH([qemu],
 199         [AS_HELP_STRING([--with-qemu],
 200           [set default QEMU binary @<:@default=[qemu-kvm] qemu-system-<host> qemu@:>@])],
 201         [],
 202         [with_qemu="$default_qemu"])
 203 AC_PATH_PROGS([QEMU],[$with_qemu],[no],
 204         [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/libexec])
 205 test "x$QEMU" = "xno" && AC_MSG_ERROR([qemu must be installed])
 206 AC_DEFINE_UNQUOTED([QEMU],["$QEMU"],[Location of qemu binary.])
 207
 208 dnl Check that the chosen qemu has vmchannel support or we can
 209 dnl fallback to null vmchannel (still using SLIRP).  See the
 210 dnl discussion in the README file.
 211 if test "x$vmchannel_test" != "xno"; then
 212     AC_MSG_CHECKING([for guestfwd support in $QEMU])
 213     if $QEMU -nographic --help | grep -sq guestfwd; then
 214         AC_MSG_RESULT([yes])
 215         vmchannel_guestfwd=guestfwd
 216     else
 217         AC_MSG_RESULT([no])
 218         # Note that this test must be conditional on the previous
 219         # test failing.  This is because recent qemu will throw
 220         # up an SDL window and hang if we try to run this test.
 221         AC_MSG_CHECKING([for "-net channel" (old guestfwd) support in $QEMU])
 222         vmchannelout=`$QEMU -nographic -net channel /dev/zero 2>&1 ||:`
 223         echo "vmchannel test command output: $vmchannelout" >&AS_MESSAGE_LOG_FD
 224         if echo "$vmchannelout" | grep -sq "vmchannel wrong port number" ; then
 225             AC_MSG_RESULT([yes])
 226             vmchannel_guestfwd=net_channel
 227         else
 228             AC_MSG_RESULT([no])
 229             vmchannel_guestfwd=no
 230         fi
 231     fi
 232
 233     AC_MSG_CHECKING([for "-net user" (user mode network) support in $QEMU])
 234     if $QEMU -nographic --help | grep -sq -- "-net user"; then
 235         AC_MSG_RESULT([yes])
 236         vmchannel_net_user=yes
 237     else
 238         AC_MSG_RESULT([no])
 239         vmchannel_net_user=no
 240     fi
 241
 242     if test "x$vmchannel_net_user" = "xno" -a "x$vmchannel_guestfwd" = "xno"; then
 243         AC_MSG_FAILURE(
 244 [I did not find user mode network or vmchannel support in
 245 $QEMU.
 246
 247 Either user mode networking or vmchannel support is vital for
 248 libguestfs to operate.
 249
 250 Please read the relevant section in the README file for more
 251 information about this.
 252
 253 You can override this test by setting the environment variable
 254 vmchannel_test=no  However if you don't have the right support
 255 in your qemu, then this just delays the pain.
 256
 257 If I am using the wrong qemu or you want to compile qemu from source
 258 and install it in another location, then you should configure with
 259 the --with-qemu option.
 260 ])
 261     fi
 262 fi
 263
 264 dnl Set drive interface used by the guestfs_add_drive{,_ro} calls
 265 dnl ('-drive ...,if=...' option to qemu).
 266 dnl
 267 dnl If you encounter performance problems with virtio (RHBZ#509383)
 268 dnl then try '--with-drive-if=ide'.
 269 AC_ARG_WITH([drive-if],
 270         [AS_HELP_STRING([--with-drive-if],
 271           [set default driver (ide|scsi|virtio) @<:@default=virtio@:>@])],
 272         [],
 273         [with_drive_if=virtio])
 274 AC_DEFINE_UNQUOTED([DRIVE_IF],["$with_drive_if"],[Default drive interface.])
 275
 276 dnl Set interface used by the network.  Normally you should
 277 dnl leave this at the default (virtio) but you can use the
 278 dnl alternative (ne2k_pci) because of bugs in virtio networking
 279 dnl eg. https://bugzilla.redhat.com/show_bug.cgi?id=516022
 280 AC_ARG_WITH([net-if],
 281         [AS_HELP_STRING([--with-net-if],
 282           [set default net driver (virtio|ne2k_pci) @<:@default=virtio@:>@])],
 283         [],
 284         [with_net_if=virtio])
 285 AC_DEFINE_UNQUOTED([NET_IF],["$with_net_if"],[Default network interface.])
 286
 287 dnl Check for febootstrap etc.
 288 if test "x$enable_appliance" = "xyes"; then
 289     AC_CHECK_PROG([FEBOOTSTRAP],
 290                   [febootstrap],[febootstrap],[no])
 291     if test "x$FEBOOTSTRAP" != "xno"; then
 292       AC_CHECK_PROG([FEBOOTSTRAP_RUN],
 293                     [febootstrap-run],[febootstrap-run],[no])
 294       test "x$FEBOOTSTRAP_RUN" = "xno" && \
 295           AC_MSG_ERROR([febootstrap-run must be installed])
 296       AC_CHECK_PROG([FEBOOTSTRAP_INSTALL],
 297                     [febootstrap-install],[febootstrap-install],[no])
 298       test "x$FEBOOTSTRAP_INSTALL" = "xno" && \
 299           AC_MSG_ERROR([febootstrap-install must be installed])
 300       AC_CHECK_PROG([FEBOOTSTRAP_MINIMIZE],
 301                     [febootstrap-minimize],[febootstrap-minimize],[no])
 302       test "x$FEBOOTSTRAP_MINIMIZE" = "xno" && \
 303           AC_MSG_ERROR([febootstrap-minimize must be installed])
 304       AC_CHECK_PROG([FEBOOTSTRAP_TO_INITRAMFS],
 305                     [febootstrap-to-initramfs],[febootstrap-to-initramfs],[no])
 306       test "x$FEBOOTSTRAP_TO_INITRAMFS" = "xno" && \
 307           AC_MSG_ERROR([febootstrap-to-initramfs must be installed])
 308
 309       dnl Check we have fakechroot >= 2.9 (it's an indirect requirement
 310       dnl of febootstrap, but old versions will fail with yum).
 311       AC_CHECK_PROG([FAKECHROOT],
 312                     [fakechroot],[fakechroot],[no])
 313       test "x$FAKECHROOT" = "xno" && \
 314          AC_MSG_ERROR([fakechroot must be installed])
 315
 316       AC_MSG_CHECKING([fakechroot version])
 317       fakechroot_version=`$FAKECHROOT --version | awk '{print $3}'`
 318       if test -z "$fakechroot_version"; then
 319         AC_MSG_RESULT([failed])
 320         AC_MSG_WARN([fakechroot --version command failed, proceeding anyway])
 321       else
 322         AC_MSG_RESULT([$fakechroot_version])
 323         fakechroot_major=`echo "$fakechroot_version" | awk -F. '{print $1}'`
 324         fakechroot_minor=`echo "$fakechroot_version" | awk -F. '{print $2}'`
 325         if test "$fakechroot_major" -lt 2 -o \
 326             \( "$fakechroot_major" -eq 2 -a "$fakechroot_minor" -lt 9 \); then
 327           AC_MSG_ERROR([fakechroot version must be >= 2.9])
 328         fi
 329       fi
 330       DIST="REDHAT"
 331     else
 332       # check for debootstrap and debirf
 333       AC_CHECK_PROG([DEBOOTSTRAP],
 334                     [debootstrap],[debootstrap],[no])
 335       test "x$DEBOOTSTRAP" = "xno" && \
 336           AC_MSG_ERROR([Either febootstrap or debootstrap must be installed])
 337       AC_CHECK_PROG([DEBIRF],[debirf],[debirf],[no])
 338       test "x$DEBIRF" = "xno" &&
 339           AC_MSG_ERROR([debirf must be installed])
 340       DIST="DEBIAN"
 341       case "$host_cpu" in
 342       *86)
 343           DEBIAN_KERNEL_ARCH=486
 344           ;;
 345       x86_64)
 346           DEBIAN_KERNEL_ARCH=amd64
 347           ;;
 348       *)
 349          DEBIAN_KERNEL_ARCH=$host_cpu
 350          ;;
 351       esac
 352       AC_SUBST(DEBIAN_KERNEL_ARCH)
 353     fi
 354     AC_SUBST(DIST)
 355
 356     dnl --with-updates to specify a Fedora updates repository.
 357     AC_ARG_WITH([updates],
 358         [AS_HELP_STRING([--with-updates],
 359           [set name of Fedora updates repository @<:@default=updates-released-f12@:>@])],
 360         [],
 361         [with_updates=updates-released-f12])
 362     UPDATES="$with_updates"
 363     AC_SUBST(UPDATES)
 364
 365     dnl --with-mirror to specify a local Fedora mirror.
 366     AC_ARG_WITH([mirror],
 367         [AS_HELP_STRING([--with-mirror],
 368           [set URI of a local Fedora mirror])],
 369         [],
 370         [with_mirror=])
 371     MIRROR="$with_mirror"
 372     AC_SUBST(MIRROR)
 373 fi
 374
 375 dnl --with-repo to specify a Fedora repository.
 376 AC_ARG_WITH([repo],
 377         [AS_HELP_STRING([--with-repo],
 378           [set name of Fedora repository @<:@default=fedora-12@:>@])],
 379         [],
 380         [with_repo=fedora-12])
 381 REPO="$with_repo"
 382 AC_SUBST(REPO)
 383 AC_DEFINE_UNQUOTED([REPO],["$REPO"],[Name of Fedora repository.])
 384
 385 dnl Build the supermin appliance?  Please see README file before
 386 dnl enabling this option.
 387 AC_ARG_ENABLE([supermin],
 388         [AS_HELP_STRING([--enable-supermin],
 389           [enable supermin appliance (see README) @<:@default=no@:>@])],
 390         [],
 391         [enable_supermin=no])
 392 AM_CONDITIONAL([SUPERMIN],[test "x$enable_supermin" = "xyes"])
 393
 394 if test "x$enable_supermin" = "xyes"; then
 395     dnl Check febootstrap-to-initramfs accepts the --files option
 396     dnl (febootstrap >= 2.2).
 397     AC_MSG_CHECKING([for --files support in $FEBOOTSTRAP_TO_INITRAMFS])
 398     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 399     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 400     if ! echo "$out" | grep -sq -e --files ; then
 401         AC_MSG_RESULT([no])
 402         AC_MSG_FAILURE(
 403 [febootstrap-to-initramfs does not support the --files option.
 404
 405 To build the supermin appliance, you need to upgrade to the latest
 406 version of febootstrap.
 407 ])
 408     fi
 409     AC_MSG_RESULT([yes])
 410
 411     dnl Check febootstrap-to-initramfs accepts the --nocompress option
 412     dnl (febootstrap >= 2.3).
 413     AC_MSG_CHECKING([for --nocompress support in $FEBOOTSTRAP_TO_INITRAMFS])
 414     out=`$FEBOOTSTRAP_TO_INITRAMFS 2>&1 ||:`
 415     echo "febootstrap_to_initramfs test command output: $out" >&AS_MESSAGE_LOG_FD
 416     if ! echo "$out" | grep -sq -e --nocompress ; then
 417         AC_MSG_RESULT([no])
 418         AC_MSG_FAILURE(
 419 [febootstrap-to-initramfs does not support the --nocompress option.
 420
 421 To build the supermin appliance, you need to upgrade to the latest
 422 version of febootstrap.
 423 ])
 424     fi
 425     AC_MSG_RESULT([yes])
 426 fi
 427
 428 dnl Enable packet dumps when in verbose mode.  This generates lots
 429 dnl of debug info, only useful for people debugging the RPC mechanism.
 430 AC_ARG_ENABLE([packet-dump],
 431         [AS_HELP_STRING([--enable-packet-dump],
 432           [enable packet dumps in verbose mode @<:@default=no@:>@])],
 433         [AC_DEFINE([ENABLE_PACKET_DUMP],[1],[Enable packet dumps in verbose mode.])],
 434         [])
 435
 436 dnl Readline.
 437 AC_ARG_WITH([readline],
 438     [AS_HELP_STRING([--with-readline],
 439         [support fancy command line editing @<:@default=check@:>@])],
 440     [],
 441     [with_readline=check])
 442
 443 LIBREADLINE=
 444 AS_IF([test "x$with_readline" != xno],
 445     [AC_CHECK_LIB([readline], [main],
 446         [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 447          AC_DEFINE([HAVE_LIBREADLINE], [1],
 448                    [Define if you have libreadline])
 449         ],
 450         [if test "x$with_readline" != xcheck; then
 451          AC_MSG_FAILURE(
 452              [--with-readline was given, but test for readline failed])
 453          fi
 454         ], -lncurses)
 455      old_LIBS="$LIBS"
 456      LIBS="$LIBS $LIBREADLINE"
 457      AC_CHECK_FUNCS([append_history completion_matches rl_completion_matches])
 458      LIBS="$old_LIBS"
 459     ])
 460
 461 dnl For i18n.
 462 AM_GNU_GETTEXT([external])
 463 AM_GNU_GETTEXT_VERSION([0.17])
 464
 465 dnl hivex library (highly recommended).
 466 dnl This used to be a part of libguestfs, but was spun off into its
 467 dnl own separate upstream project in libguestfs 1.0.85.
 468 HAVE_HIVEX=yes
 469 PKG_CHECK_MODULES([HIVEX], [hivex],,[
 470         HAVE_HIVEX=no
 471         AC_MSG_WARN([Hivex library and headers are missing, so optional Windows Registry tools won't be built])])
 472 AM_CONDITIONAL([HAVE_HIVEX],[test "x$HAVE_HIVEX" = "xyes"])
 473 AC_SUBST([HIVEX_CFLAGS])
 474 AC_SUBST([HIVEX_LIBS])
 475
 476 dnl FUSE is optional to build the FUSE module.
 477 HAVE_FUSE=yes
 478 PKG_CHECK_MODULES([FUSE],[fuse],,[
 479         HAVE_FUSE=no
 480         AC_MSG_WARN([FUSE library and headers are missing, so optional FUSE module won't be built])])
 481 AM_CONDITIONAL([HAVE_FUSE],[test "x$HAVE_FUSE" = "xyes"])
 482
 483 dnl Check for OCaml (optional, for OCaml bindings).
 484 AC_PROG_OCAML
 485 AC_PROG_FINDLIB
 486 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"])
 487
 488 dnl Optional xml-light for running the generator.
 489 OCAML_PKG_xml_light=no
 490 if test "x$OCAMLC" != "xno" -a "x$OCAMLFIND" != "xno"; then
 491     AC_CHECK_OCAML_PKG([xml-light])
 492 fi
 493 AM_CONDITIONAL([HAVE_XML_LIGHT],[test "x$OCAML_PKG_xml_light" != "xno"])
 494
 495 dnl Build the OCaml viewer example.  This has a lengthy list of
 496 dnl dependencies and we don't attempt to detect them all.  Read
 497 dnl the top of ocaml/examples/viewer.ml before enabling this.
 498 AC_ARG_ENABLE([ocaml-viewer],
 499         [AS_HELP_STRING([--enable-ocaml-viewer],
 500           [enable OCaml viewer (see ocaml/examples) @<:@default=no@:>@])],
 501         [],
 502         [enable_ocaml_viewer=no])
 503 AM_CONDITIONAL([BUILD_OCAML_VIEWER],[test "x$enable_ocaml_viewer" = "xyes"])
 504
 505 dnl Check for Perl (optional, for Perl bindings).
 506 dnl XXX This isn't quite right, we should check for Perl devel library.
 507 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 508
 509 dnl Check for Perl modules that must be present to compile and
 510 dnl test the Perl bindings.
 511 missing_perl_modules=no
 512 for pm in Test::More ExtUtils::MakeMaker; do
 513     AC_MSG_CHECKING([for $pm])
 514     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 515         AC_MSG_RESULT([no])
 516         missing_perl_modules=yes
 517     else
 518         AC_MSG_RESULT([yes])
 519     fi
 520 done
 521 if test "x$missing_perl_modules" = "xyes"; then
 522     AC_MSG_WARN([some Perl modules required to compile or test the Perl bindings are missing])
 523 fi
 524
 525 AM_CONDITIONAL([HAVE_PERL],
 526     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 527
 528 dnl Check for Python (optional, for Python bindings).
 529 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 530
 531 PYTHON_PREFIX=
 532 PYTHON_VERSION=
 533 PYTHON_INCLUDEDIR=
 534 PYTHON_SITE_PACKAGES=
 535
 536 if test "x$PYTHON" != "xno"; then
 537     PYTHON_PREFIX=`$PYTHON -c "import sys; print sys.prefix"`
 538     PYTHON_VERSION=`$PYTHON -c "import sys; print sys.version[[0:3]]"`
 539     for d in \
 540         $PYTHON_PREFIX/include/python$PYTHON_VERSION \
 541         /usr/include/python$PYTHON_VERSION \
 542         /usr/local/include/python$PYTHON_VERSION
 543     do
 544         AC_MSG_CHECKING([Python.h in $d])
 545         if test -r "$d/Python.h"; then
 546             AC_MSG_RESULT([found])
 547             PYTHON_INCLUDEDIR=$d
 548             break
 549         fi
 550         AC_MSG_RESULT([not found])
 551     done
 552     for d in \
 553         $PYTHON_PREFIX/lib64/python$PYTHON_VERSION/site-packages \
 554         $PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages \
 555         /usr/lib64/python$PYTHON_VERSION/site-packages \
 556         /usr/lib/python$PYTHON_VERSION/site-packages \
 557         /usr/local/lib/python$PYTHON_VERSION/site-packages
 558     do
 559         AC_MSG_CHECKING([for $d])
 560         if test -d "$d"; then
 561             AC_MSG_RESULT([found])
 562             PYTHON_SITE_PACKAGES=$d
 563             break
 564         fi
 565         AC_MSG_RESULT([not found])
 566     done
 567 fi
 568
 569 AC_SUBST(PYTHON_PREFIX)
 570 AC_SUBST(PYTHON_VERSION)
 571 AC_SUBST(PYTHON_INCLUDEDIR)
 572 AC_SUBST(PYTHON_SITE_PACKAGES)
 573
 574 AM_CONDITIONAL([HAVE_PYTHON],
 575     [test "x$PYTHON_INCLUDEDIR" != "x" -a "x$PYTHON_SITE_PACKAGES" != "x"])
 576
 577 dnl Check for Ruby and rake (optional, for Ruby bindings).
 578 AC_CHECK_LIB([ruby],[ruby_init],[HAVE_LIBRUBY=1],[HAVE_LIBRUBY=0])
 579 AC_CHECK_PROG([RAKE],[rake],[rake],[no])
 580
 581 AM_CONDITIONAL([HAVE_RUBY],
 582     [test "x$RAKE" != "xno" -a -n "$HAVE_LIBRUBY"])
 583
 584 dnl Check for Java.
 585 AC_ARG_WITH(java_home,
 586     [AS_HELP_STRING([--with-java-home],
 587         [specify path to JDK directory @<:@default=check@:>@])],
 588     [],
 589     [with_java_home=check])
 590
 591 if test "x$with_java_home" != "xno"; then
 592     if test "x$with_java_home" != "xyes" -a "x$with_java_home" != "xcheck"
 593     then
 594         # Reject unsafe characters in $JAVA_HOME
 595         jh_lf='
 596 '
 597         case $JAVA_HOME in
 598           *[\\\"\#\$\&\'\`$jh_lf\ \     ]*)
 599             AC_MSG_FAILURE([unsafe \$JAVA_HOME directory (use --with-java-home=no to disable Java support)]);;
 600         esac
 601         if test -d "$with_java_home"; then
 602             JAVA_HOME="$with_java_home"
 603         else
 604             AC_MSG_FAILURE([$with_java_home is not a directory (use --with-java-home=no to disable Java support)])
 605         fi
 606     fi
 607
 608     if test "x$JAVA_HOME" = "x"; then
 609         # Look for Java in some likely locations.
 610         for d in \
 611             /usr/lib/jvm/java \
 612             /usr/lib/jvm/java-6-openjdk
 613         do
 614             if test -d $d -a -f $d/bin/java; then
 615                 JAVA_HOME=$d
 616                 break
 617             fi
 618         done
 619     fi
 620
 621     if test "x$JAVA_HOME" != "x"; then
 622         AC_MSG_CHECKING(for JDK in $JAVA_HOME)
 623         if test ! -x "$JAVA_HOME/bin/java"; then
 624             AC_MSG_ERROR([missing $JAVA_HOME/bin/java binary (use --with-java-home=no to disable Java support)])
 625         else
 626             JAVA="$JAVA_HOME/bin/java"
 627         fi
 628         if test ! -x "$JAVA_HOME/bin/javac"; then
 629             AC_MSG_ERROR([missing $JAVA_HOME/bin/javac binary])
 630         else
 631             JAVAC="$JAVA_HOME/bin/javac"
 632         fi
 633         if test ! -x "$JAVA_HOME/bin/javah"; then
 634             AC_MSG_ERROR([missing $JAVA_HOME/bin/javah binary])
 635         else
 636             JAVAH="$JAVA_HOME/bin/javah"
 637         fi
 638         if test ! -x "$JAVA_HOME/bin/javadoc"; then
 639             AC_MSG_ERROR([missing $JAVA_HOME/bin/javadoc binary])
 640         else
 641             JAVADOC="$JAVA_HOME/bin/javadoc"
 642         fi
 643         if test ! -x "$JAVA_HOME/bin/jar"; then
 644             AC_MSG_ERROR([missing $JAVA_HOME/bin/jar binary])
 645         else
 646             JAR="$JAVA_HOME/bin/jar"
 647         fi
 648         java_version=`$JAVA -version 2>&1 | grep "java version"`
 649         AC_MSG_RESULT(found $java_version in $JAVA_HOME)
 650
 651         dnl Find jni.h.
 652         AC_MSG_CHECKING([for jni.h])
 653         if test -f "$JAVA_HOME/include/jni.h"; then
 654             JNI_CFLAGS="-I$JAVA_HOME/include"
 655         else
 656             if test "`find $JAVA_HOME -name jni.h`" != ""; then
 657                 head=`find $JAVA_HOME -name jni.h | tail -1`
 658                 dir=`dirname "$head"`
 659                 JNI_CFLAGS="-I$dir"
 660             else
 661                 AC_MSG_FAILURE([missing jni.h header file])
 662             fi
 663         fi
 664         AC_MSG_RESULT([$JNI_CFLAGS])
 665
 666         dnl Find jni_md.h.
 667         AC_MSG_CHECKING([for jni_md.h])
 668         case "$build_os" in
 669         *linux*) system="linux" ;;
 670         *SunOS*) system="solaris" ;;
 671         *cygwin*) system="win32" ;;
 672         *) system="$build_os" ;;
 673         esac
 674         if test -f "$JAVA_HOME/include/$system/jni_md.h"; then
 675             JNI_CFLAGS="$JNI_CFLAGS -I$JAVA_HOME/include/$system"
 676         else
 677             if test "`find $JAVA_HOME -name jni_md.h`" != ""; then
 678                 head=`find $JAVA_HOME -name jni_md.h | tail -1`
 679                 dir=`dirname "$head"`
 680                 JNI_CFLAGS="$JNI_CFLAGS -I$dir"
 681             else
 682                 AC_MSG_FAILURE([missing jni_md.h header file])
 683             fi
 684         fi
 685         AC_MSG_RESULT([$JNI_CFLAGS])
 686
 687         dnl Need extra version flag?
 688         AC_MSG_CHECKING([extra javac flags])
 689         JAVAC_FLAGS=
 690         javac_version=`$JAVAC -version 2>&1`
 691         case "$javac_version" in
 692         *Eclipse*)
 693             JAVAC_FLAGS="-source 1.5" ;;
 694         esac
 695         AC_MSG_RESULT([$JAVAC_FLAGS])
 696
 697         dnl Where to install jarfiles.
 698         dnl XXX How to make it configurable?
 699         JAR_INSTALL_DIR=\${prefix}/share/java
 700         JNI_INSTALL_DIR=\${libdir}
 701
 702         dnl JNI version.
 703         jni_major_version=`echo "$VERSION" | awk -F. '{print $1}'`
 704         jni_minor_version=`echo "$VERSION" | awk -F. '{print $2}'`
 705         jni_micro_version=`echo "$VERSION" | awk -F. '{print $3}'`
 706         JNI_VERSION_INFO=`expr "$jni_major_version" + "$jni_minor_version"`":$jni_micro_version:$jni_minor_version"
 707     fi
 708 fi
 709
 710 AC_SUBST(JAVA_HOME)
 711 AC_SUBST(JAVA)
 712 AC_SUBST(JAVAC)
 713 AC_SUBST(JAVAH)
 714 AC_SUBST(JAVADOC)
 715 AC_SUBST(JAR)
 716 AC_SUBST(JNI_CFLAGS)
 717 AC_SUBST(JAVAC_FLAGS)
 718 AC_SUBST(JAR_INSTALL_DIR)
 719 AC_SUBST(JNI_INSTALL_DIR)
 720 AC_SUBST(JNI_VERSION_INFO)
 721
 722 AM_CONDITIONAL([HAVE_JAVA],[test -n "$JAVAC"])
 723
 724 dnl Check for Haskell (GHC).
 725 AC_CHECK_PROG([GHC],[ghc],[ghc],[no])
 726
 727 AM_CONDITIONAL([HAVE_HASKELL],
 728     [test "x$GHC" != "xno"])
 729
 730 dnl Check for Perl modules needed by virt-df, inspector, etc.
 731 missing_perl_modules=no
 732 for pm in Pod::Usage Getopt::Long Sys::Virt Data::Dumper XML::Writer Locale::TextDomain Win::Hivex Win::Hivex::Regedit; do
 733     AC_MSG_CHECKING([for $pm])
 734     if ! perl -M$pm -e1 >/dev/null 2>&1; then
 735         AC_MSG_RESULT([no])
 736         missing_perl_modules=yes
 737     else
 738         AC_MSG_RESULT([yes])
 739     fi
 740 done
 741 if test "x$missing_perl_modules" = "xyes"; then
 742     AC_MSG_WARN([some Perl modules required to compile virt-inspector and the other virt-* tools are missing])
 743 fi
 744
 745 AM_CONDITIONAL([HAVE_INSPECTOR],
 746     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 747 AM_CONDITIONAL([HAVE_TOOLS],
 748     [test "x$PERL" != "xno" -a "x$missing_perl_modules" != "xyes"])
 749
 750 dnl Library versioning.
 751 MAX_PROC_NR=`cat $srcdir/src/MAX_PROC_NR`
 752 AC_SUBST(MAX_PROC_NR)
 753
 754 dnl Run in subdirs.
 755 if test "x$enable_daemon" = "xyes"; then
 756     AC_CONFIG_SUBDIRS([daemon])
 757 fi
 758
 759 dnl Produce output files.
 760 AC_CONFIG_HEADERS([config.h])
 761 dnl http://www.mail-archive.com/automake@gnu.org/msg10204.html
 762 AC_CONFIG_FILES([appliance/update.sh],
 763                 [chmod +x appliance/update.sh])
 764 AC_CONFIG_FILES([appliance/supermin-split.sh],
 765                 [chmod +x appliance/supermin-split.sh])
 766 AC_CONFIG_FILES([appliance/supermin-make.sh],
 767                 [chmod +x appliance/supermin-make.sh])
 768 AC_CONFIG_FILES([Makefile
 769                  src/Makefile fish/Makefile po/Makefile.in examples/Makefile
 770                  appliance/Makefile
 771                  appliance/debian/debirf.conf
 772                  images/Makefile
 773                  capitests/Makefile
 774                  regressions/Makefile
 775                  test-tool/Makefile
 776                  ocaml/Makefile ocaml/examples/Makefile
 777                  perl/Makefile
 778                  python/Makefile
 779                  ruby/Makefile ruby/Rakefile
 780                  java/Makefile
 781                  haskell/Makefile
 782                  inspector/Makefile
 783                  tools/Makefile
 784                  libguestfs.pc
 785                  gnulib/lib/Makefile
 786                  gnulib/tests/Makefile
 787                  fuse/Makefile
 788                  ocaml/META perl/Makefile.PL])
 789 AC_OUTPUT
 790
 791 dnl Produce summary.
 792 echo
 793 echo
 794 echo "------------------------------------------------------------"
 795 echo "Thank you for downloading $PACKAGE_STRING"
 796 echo
 797 echo "This is how we have configured the optional components for you today:"
 798 echo
 799 echo    "Daemon .............................. $enable_daemon"
 800 echo    "Appliance ........................... $enable_appliance"
 801 echo    "QEMU ................................ $QEMU"
 802 echo -n "OCaml bindings ...................... "
 803 if test "x$HAVE_OCAML_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 804 echo -n "Perl bindings ....................... "
 805 if test "x$HAVE_PERL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 806 echo -n "Python bindings ..................... "
 807 if test "x$HAVE_PYTHON_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 808 echo -n "Ruby bindings ....................... "
 809 if test "x$HAVE_RUBY_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 810 echo -n "Java bindings ....................... "
 811 if test "x$HAVE_JAVA_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 812 echo -n "Haskell bindings .................... "
 813 if test "x$HAVE_HASKELL_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 814 echo -n "virt-inspector ...................... "
 815 if test "x$HAVE_INSPECTOR_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 816 echo -n "virt-* tools ........................ "
 817 if test "x$HAVE_TOOLS_TRUE" = "x"; then echo "yes"; else echo "no"; fi
 818 echo "supermin appliance .................. $enable_supermin"
 819 echo "FUSE filesystem ..................... $HAVE_FUSE"
 820 echo
 821 echo "If any optional component is configured 'no' when you expected 'yes'"
 822 echo "then you should check the preceeding messages."
 823 echo
 824 echo "Please report bugs back to the mailing list:"
 825 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
 826 echo
 827 echo "Next you should type 'make' to build the package,"
 828 echo "then 'make check' to run the tests."
 829 echo "------------------------------------------------------------"