jonesforth.S

   1 /*      A sometimes minimal FORTH compiler and tutorial for Linux / i386 systems. -*- asm -*-
   2         By Richard W.M. Jones <rich@annexia.org> http://annexia.org/forth
   3         This is PUBLIC DOMAIN (see public domain release statement below).
   4         $Id: jonesforth.S,v 1.28 2007-09-24 00:18:19 rich Exp $
   5
   6         gcc -m32 -nostdlib -static -Wl,-Ttext,0 -o jonesforth jonesforth.S
   7 */
   8         .set JONES_VERSION,28
   9 /*
  10         INTRODUCTION ----------------------------------------------------------------------
  11
  12         FORTH is one of those alien languages which most working programmers regard in the same
  13         way as Haskell, LISP, and so on.  Something so strange that they'd rather any thoughts
  14         of it just go away so they can get on with writing this paying code.  But that's wrong
  15         and if you care at all about programming then you should at least understand all these
  16         languages, even if you will never use them.
  17
  18         LISP is the ultimate high-level language, and features from LISP are being added every
  19         decade to the more common languages.  But FORTH is in some ways the ultimate in low level
  20         programming.  Out of the box it lacks features like dynamic memory management and even
  21         strings.  In fact, at its primitive level it lacks even basic concepts like IF-statements
  22         and loops.
  23
  24         Why then would you want to learn FORTH?  There are several very good reasons.  First
  25         and foremost, FORTH is minimal.  You really can write a complete FORTH in, say, 2000
  26         lines of code.  I don't just mean a FORTH program, I mean a complete FORTH operating
  27         system, environment and language.  You could boot such a FORTH on a bare PC and it would
  28         come up with a prompt where you could start doing useful work.  The FORTH you have here
  29         isn't minimal and uses a Linux process as its 'base PC' (both for the purposes of making
  30         it a good tutorial). It's possible to completely understand the system.  Who can say they
  31         completely understand how Linux works, or gcc?
  32
  33         Secondly FORTH has a peculiar bootstrapping property.  By that I mean that after writing
  34         a little bit of assembly to talk to the hardware and implement a few primitives, all the
  35         rest of the language and compiler is written in FORTH itself.  Remember I said before
  36         that FORTH lacked IF-statements and loops?  Well of course it doesn't really because
  37         such a lanuage would be useless, but my point was rather that IF-statements and loops are
  38         written in FORTH itself.
  39
  40         Now of course this is common in other languages as well, and in those languages we call
  41         them 'libraries'.  For example in C, 'printf' is a library function written in C.  But
  42         in FORTH this goes way beyond mere libraries.  Can you imagine writing C's 'if' in C?
  43         And that brings me to my third reason: If you can write 'if' in FORTH, then why restrict
  44         yourself to the usual if/while/for/switch constructs?  You want a construct that iterates
  45         over every other element in a list of numbers?  You can add it to the language.  What
  46         about an operator which pulls in variables directly from a configuration file and makes
  47         them available as FORTH variables?  Or how about adding Makefile-like dependencies to
  48         the language?  No problem in FORTH.  This concept isn't common in programming languages,
  49         but it has a name (in fact two names): "macros" (by which I mean LISP-style macros, not
  50         the lame C preprocessor) and "domain specific languages" (DSLs).
  51
  52         This tutorial isn't about learning FORTH as the language.  I'll point you to some references
  53         you should read if you're not familiar with using FORTH.  This tutorial is about how to
  54         write FORTH.  In fact, until you understand how FORTH is written, you'll have only a very
  55         superficial understanding of how to use it.
  56
  57         So if you're not familiar with FORTH or want to refresh your memory here are some online
  58         references to read:
  59
  60         http://en.wikipedia.org/wiki/Forth_%28programming_language%29
  61
  62         http://galileo.phys.virginia.edu/classes/551.jvn.fall01/primer.htm
  63
  64         http://wiki.laptop.org/go/Forth_Lessons
  65
  66         http://www.albany.net/~hello/simple.htm
  67
  68         Here is another "Why FORTH?" essay: http://www.jwdt.com/~paysan/why-forth.html
  69
  70         Discussion and criticism of this FORTH here: http://lambda-the-ultimate.org/node/2452
  71
  72         ACKNOWLEDGEMENTS ----------------------------------------------------------------------
  73
  74         This code draws heavily on the design of LINA FORTH (http://home.hccnet.nl/a.w.m.van.der.horst/lina.html)
  75         by Albert van der Horst.  Any similarities in the code are probably not accidental.
  76
  77         Also I used this document (http://ftp.funet.fi/pub/doc/IOCCC/1992/buzzard.2.design) which really
  78         defies easy explanation.
  79
  80         PUBLIC DOMAIN ----------------------------------------------------------------------
  81
  82         I, the copyright holder of this work, hereby release it into the public domain. This applies worldwide.
  83
  84         In case this is not legally possible, I grant any entity the right to use this work for any purpose,
  85         without any conditions, unless such conditions are required by law.
  86
  87         SETTING UP ----------------------------------------------------------------------
  88
  89         Let's get a few housekeeping things out of the way.  Firstly because I need to draw lots of
  90         ASCII-art diagrams to explain concepts, the best way to look at this is using a window which
  91         uses a fixed width font and is at least this wide:
  92
  93  <------------------------------------------------------------------------------------------------------------------------>
  94
  95         Secondly make sure TABS are set to 8 characters.  The following should be a vertical
  96         line.  If not, sort out your tabs.
  97
  98         |
  99         |
 100         |
 101
 102         Thirdly I assume that your screen is at least 50 characters high.
 103
 104         ASSEMBLING ----------------------------------------------------------------------
 105
 106         If you want to actually run this FORTH, rather than just read it, you will need Linux on an
 107         i386.  Linux because instead of programming directly to the hardware on a bare PC which I
 108         could have done, I went for a simpler tutorial by assuming that the 'hardware' is a Linux
 109         process with a few basic system calls (read, write and exit and that's about all).  i386
 110         is needed because I had to write the assembly for a processor, and i386 is by far the most
 111         common.  (Of course when I say 'i386', any 32- or 64-bit x86 processor will do.  I'm compiling
 112         this on a 64 bit AMD Opteron).
 113
 114         Again, to assemble this you will need gcc and gas (the GNU assembler).  The commands to
 115         assemble and run the code (save this file as 'jonesforth.S') are:
 116
 117         gcc -m32 -nostdlib -static -Wl,-Ttext,0 -o jonesforth jonesforth.S
 118         cat jonesforth.f - | ./jonesforth
 119
 120         If you want to run your own FORTH programs you can do:
 121
 122         cat jonesforth.f myprog.f | ./jonesforth
 123
 124         If you want to load your own FORTH code and then continue reading user commands, you can do:
 125
 126         cat jonesforth.f myfunctions.f - | ./jonesforth
 127
 128         ASSEMBLER ----------------------------------------------------------------------
 129
 130         (You can just skip to the next section -- you don't need to be able to read assembler to
 131         follow this tutorial).
 132
 133         However if you do want to read the assembly code here are a few notes about gas (the GNU assembler):
 134
 135         (1) Register names are prefixed with '%', so %eax is the 32 bit i386 accumulator.  The registers
 136             available on i386 are: %eax, %ebx, %ecx, %edx, %esi, %edi, %ebp and %esp, and most of them
 137             have special purposes.
 138
 139         (2) Add, mov, etc. take arguments in the form SRC,DEST.  So mov %eax,%ecx moves %eax -> %ecx
 140
 141         (3) Constants are prefixed with '$', and you mustn't forget it!  If you forget it then it
 142             causes a read from memory instead, so:
 143             mov $2,%eax         moves number 2 into %eax
 144             mov 2,%eax          reads the 32 bit word from address 2 into %eax (ie. most likely a mistake)
 145
 146         (4) gas has a funky syntax for local labels, where '1f' (etc.) means label '1:' "forwards"
 147             and '1b' (etc.) means label '1:' "backwards".
 148
 149         (5) 'ja' is "jump if above", 'jb' for "jump if below", 'je' "jump if equal" etc.
 150
 151         (6) gas has a reasonably nice .macro syntax, and I use them a lot to make the code shorter and
 152             less repetitive.
 153
 154         For more help reading the assembler, do "info gas" at the Linux prompt.
 155
 156         Now the tutorial starts in earnest.
 157
 158         THE DICTIONARY ----------------------------------------------------------------------
 159
 160         In FORTH as you will know, functions are called "words", and just as in other languages they
 161         have a name and a definition.  Here are two FORTH words:
 162
 163         : DOUBLE DUP + ;                \ name is "DOUBLE", definition is "DUP +"
 164         : QUADRUPLE DOUBLE DOUBLE ;     \ name is "QUADRUPLE", definition is "DOUBLE DOUBLE"
 165
 166         Words, both built-in ones and ones which the programmer defines later, are stored in a dictionary
 167         which is just a linked list of dictionary entries.
 168
 169         <--- DICTIONARY ENTRY (HEADER) ----------------------->
 170         +------------------------+--------+---------- - - - - +----------- - - - -
 171         | LINK POINTER           | LENGTH/| NAME              | DEFINITION
 172         |                        | FLAGS  |                   |
 173         +--- (4 bytes) ----------+- byte -+- n bytes  - - - - +----------- - - - -
 174
 175         I'll come to the definition of the word later.  For now just look at the header.  The first
 176         4 bytes are the link pointer.  This points back to the previous word in the dictionary, or, for
 177         the first word in the dictionary it is just a NULL pointer.  Then comes a length/flags byte.
 178         The length of the word can be up to 31 characters (5 bits used) and the top three bits are used
 179         for various flags which I'll come to later.  This is followed by the name itself, and in this
 180         implementation the name is rounded up to a multiple of 4 bytes by padding it with zero bytes.
 181         That's just to ensure that the definition starts on a 32 bit boundary.
 182
 183         A FORTH variable called LATEST contains a pointer to the most recently defined word, in
 184         other words, the head of this linked list.
 185
 186         DOUBLE and QUADRUPLE might look like this:
 187
 188           pointer to previous word
 189            ^
 190            |
 191         +--|------+---+---+---+---+---+---+---+---+------------- - - - -
 192         | LINK    | 6 | D | O | U | B | L | E | 0 | (definition ...)
 193         +---------+---+---+---+---+---+---+---+---+------------- - - - -
 194            ^       len                         padding
 195            |
 196         +--|------+---+---+---+---+---+---+---+---+---+---+---+---+------------- - - - -
 197         | LINK    | 9 | Q | U | A | D | R | U | P | L | E | 0 | 0 | (definition ...)
 198         +---------+---+---+---+---+---+---+---+---+---+---+---+---+------------- - - - -
 199            ^       len                                     padding
 200            |
 201            |
 202           LATEST
 203
 204         You should be able to see from this how you might implement functions to find a word in
 205         the dictionary (just walk along the dictionary entries starting at LATEST and matching
 206         the names until you either find a match or hit the NULL pointer at the end of the dictionary);
 207         and add a word to the dictionary (create a new definition, set its LINK to LATEST, and set
 208         LATEST to point to the new word).  We'll see precisely these functions implemented in
 209         assembly code later on.
 210
 211         One interesting consequence of using a linked list is that you can redefine words, and
 212         a newer definition of a word overrides an older one.  This is an important concept in
 213         FORTH because it means that any word (even "built-in" or "standard" words) can be
 214         overridden with a new definition, either to enhance it, to make it faster or even to
 215         disable it.  However because of the way that FORTH words get compiled, which you'll
 216         understand below, words defined using the old definition of a word continue to use
 217         the old definition.  Only words defined after the new definition use the new definition.
 218
 219         DIRECT THREADED CODE ----------------------------------------------------------------------
 220
 221         Now we'll get to the really crucial bit in understanding FORTH, so go and get a cup of tea
 222         or coffee and settle down.  It's fair to say that if you don't understand this section, then you
 223         won't "get" how FORTH works, and that would be a failure on my part for not explaining it well.
 224         So if after reading this section a few times you don't understand it, please email me
 225         (rich@annexia.org).
 226
 227         Let's talk first about what "threaded code" means.  Imagine a peculiar version of C where
 228         you are only allowed to call functions without arguments.  (Don't worry for now that such a
 229         language would be completely useless!)  So in our peculiar C, code would look like this:
 230
 231         f ()
 232         {
 233           a ();
 234           b ();
 235           c ();
 236         }
 237
 238         and so on.  How would a function, say 'f' above, be compiled by a standard C compiler?
 239         Probably into assembly code like this.  On the right hand side I've written the actual
 240         i386 machine code.
 241
 242         f:
 243           CALL a                        E8 08 00 00 00
 244           CALL b                        E8 1C 00 00 00
 245           CALL c                        E8 2C 00 00 00
 246           ; ignore the return from the function for now
 247
 248         "E8" is the x86 machine code to "CALL" a function.  In the first 20 years of computing
 249         memory was hideously expensive and we might have worried about the wasted space being used
 250         by the repeated "E8" bytes.  We can save 20% in code size (and therefore, in expensive memory)
 251         by compressing this into just:
 252
 253         08 00 00 00             Just the function addresses, without
 254         1C 00 00 00             the CALL prefix.
 255         2C 00 00 00
 256
 257         On a 16-bit machine like the ones which originally ran FORTH the savings are even greater - 33%.
 258
 259         [Historical note: If the execution model that FORTH uses looks strange from the following
 260         paragraphs, then it was motivated entirely by the need to save memory on early computers.
 261         This code compression isn't so important now when our machines have more memory in their L1
 262         caches than those early computers had in total, but the execution model still has some
 263         useful properties].
 264
 265         Of course this code won't run directly any more.  Instead we need to write an interpreter
 266         which takes each pair of bytes and calls it.
 267
 268         On an i386 machine it turns out that we can write this interpreter rather easily, in just
 269         two assembly instructions which turn into just 3 bytes of machine code.  Let's store the
 270         pointer to the next word to execute in the %esi register:
 271
 272                 08 00 00 00     <- We're executing this one now.  %esi is the _next_ one to execute.
 273         %esi -> 1C 00 00 00
 274                 2C 00 00 00
 275
 276         The all-important i386 instruction is called LODSL (or in Intel manuals, LODSW).  It does
 277         two things.  Firstly it reads the memory at %esi into the accumulator (%eax).  Secondly it
 278         increments %esi by 4 bytes.  So after LODSL, the situation now looks like this:
 279
 280                 08 00 00 00     <- We're still executing this one
 281                 1C 00 00 00     <- %eax now contains this address (0x0000001C)
 282         %esi -> 2C 00 00 00
 283
 284         Now we just need to jump to the address in %eax.  This is again just a single x86 instruction
 285         written JMP *(%eax).  And after doing the jump, the situation looks like:
 286
 287                 08 00 00 00
 288                 1C 00 00 00     <- Now we're executing this subroutine.
 289         %esi -> 2C 00 00 00
 290
 291         To make this work, each subroutine is followed by the two instructions 'LODSL; JMP *(%eax)'
 292         which literally make the jump to the next subroutine.
 293
 294         And that brings us to our first piece of actual code!  Well, it's a macro.
 295 */
 296
 297 /* NEXT macro. */
 298         .macro NEXT
 299         lodsl
 300         jmp *(%eax)
 301         .endm
 302
 303 /*      The macro is called NEXT.  That's a FORTH-ism.  It expands to those two instructions.
 304
 305         Every FORTH primitive that we write has to be ended by NEXT.  Think of it kind of like
 306         a return.
 307
 308         The above describes what is known as direct threaded code.
 309
 310         To sum up: We compress our function calls down to a list of addresses and use a somewhat
 311         magical macro to act as a "jump to next function in the list".  We also use one register (%esi)
 312         to act as a kind of instruction pointer, pointing to the next function in the list.
 313
 314         I'll just give you a hint of what is to come by saying that a FORTH definition such as:
 315
 316         : QUADRUPLE DOUBLE DOUBLE ;
 317
 318         actually compiles (almost, not precisely but we'll see why in a moment) to a list of
 319         function addresses for DOUBLE, DOUBLE and a special function called EXIT to finish off.
 320
 321         At this point, REALLY EAGLE-EYED ASSEMBLY EXPERTS are saying "JONES, YOU'VE MADE A MISTAKE!".
 322
 323         I lied about JMP *(%eax).
 324
 325         INDIRECT THREADED CODE ----------------------------------------------------------------------
 326
 327         It turns out that direct threaded code is interesting but only if you want to just execute
 328         a list of functions written in assembly language.  So QUADRUPLE would work only if DOUBLE
 329         was an assembly language function.  In the direct threaded code, QUADRUPLE would look like:
 330
 331                 +------------------+
 332                 | addr of DOUBLE  --------------------> (assembly code to do the double)
 333                 +------------------+                    NEXT
 334         %esi -> | addr of DOUBLE   |
 335                 +------------------+
 336
 337         We can add an extra indirection to allow us to run both words written in assembly language
 338         (primitives written for speed) and words written in FORTH themselves as lists of addresses.
 339
 340         The extra indirection is the reason for the brackets in JMP *(%eax).
 341
 342         Let's have a look at how QUADRUPLE and DOUBLE really look in FORTH:
 343
 344                 : QUADRUPLE DOUBLE DOUBLE ;
 345
 346                 +------------------+
 347                 | codeword         |               : DOUBLE DUP + ;
 348                 +------------------+
 349                 | addr of DOUBLE  ---------------> +------------------+
 350                 +------------------+               | codeword         |
 351                 | addr of DOUBLE   |               +------------------+
 352                 +------------------+               | addr of DUP   --------------> +------------------+
 353                 | addr of EXIT     |               +------------------+            | codeword      -------+
 354                 +------------------+       %esi -> | addr of +     --------+       +------------------+   |
 355                                                    +------------------+    |       | assembly to    <-----+
 356                                                    | addr of EXIT     |    |       | implement DUP    |
 357                                                    +------------------+    |       |    ..            |
 358                                                                            |       |    ..            |
 359                                                                            |       | NEXT             |
 360                                                                            |       +------------------+
 361                                                                            |
 362                                                                            +-----> +------------------+
 363                                                                                    | codeword      -------+
 364                                                                                    +------------------+   |
 365                                                                                    | assembly to   <------+
 366                                                                                    | implement +      |
 367                                                                                    |    ..            |
 368                                                                                    |    ..            |
 369                                                                                    | NEXT             |
 370                                                                                    +------------------+
 371
 372         This is the part where you may need an extra cup of tea/coffee/favourite caffeinated
 373         beverage.  What has changed is that I've added an extra pointer to the beginning of
 374         the definitions.  In FORTH this is sometimes called the "codeword".  The codeword is
 375         a pointer to the interpreter to run the function.  For primitives written in
 376         assembly language, the "interpreter" just points to the actual assembly code itself.
 377         They don't need interpreting, they just run.
 378
 379         In words written in FORTH (like QUADRUPLE and DOUBLE), the codeword points to an interpreter
 380         function.
 381
 382         I'll show you the interpreter function shortly, but let's recall our indirect
 383         JMP *(%eax) with the "extra" brackets.  Take the case where we're executing DOUBLE
 384         as shown, and DUP has been called.  Note that %esi is pointing to the address of +
 385
 386         The assembly code for DUP eventually does a NEXT.  That:
 387
 388         (1) reads the address of + into %eax            %eax points to the codeword of +
 389         (2) increments %esi by 4
 390         (3) jumps to the indirect %eax                  jumps to the address in the codeword of +,
 391                                                         ie. the assembly code to implement +
 392
 393                 +------------------+
 394                 | codeword         |
 395                 +------------------+
 396                 | addr of DOUBLE  ---------------> +------------------+
 397                 +------------------+               | codeword         |
 398                 | addr of DOUBLE   |               +------------------+
 399                 +------------------+               | addr of DUP   --------------> +------------------+
 400                 | addr of EXIT     |               +------------------+            | codeword      -------+
 401                 +------------------+               | addr of +     --------+       +------------------+   |
 402                                                    +------------------+    |       | assembly to    <-----+
 403                                            %esi -> | addr of EXIT     |    |       | implement DUP    |
 404                                                    +------------------+    |       |    ..            |
 405                                                                            |       |    ..            |
 406                                                                            |       | NEXT             |
 407                                                                            |       +------------------+
 408                                                                            |
 409                                                                            +-----> +------------------+
 410                                                                                    | codeword      -------+
 411                                                                                    +------------------+   |
 412                                                                         now we're  | assembly to    <-----+
 413                                                                         executing  | implement +      |
 414                                                                         this       |    ..            |
 415                                                                         function   |    ..            |
 416                                                                                    | NEXT             |
 417                                                                                    +------------------+
 418
 419         So I hope that I've convinced you that NEXT does roughly what you'd expect.  This is
 420         indirect threaded code.
 421
 422         I've glossed over four things.  I wonder if you can guess without reading on what they are?
 423
 424         .
 425         .
 426         .
 427
 428         My list of four things are: (1) What does "EXIT" do?  (2) which is related to (1) is how do
 429         you call into a function, ie. how does %esi start off pointing at part of QUADRUPLE, but
 430         then point at part of DOUBLE.  (3) What goes in the codeword for the words which are written
 431         in FORTH?  (4) How do you compile a function which does anything except call other functions
 432         ie. a function which contains a number like : DOUBLE 2 * ; ?
 433
 434         THE INTERPRETER AND RETURN STACK ------------------------------------------------------------
 435
 436         Going at these in no particular order, let's talk about issues (3) and (2), the interpreter
 437         and the return stack.
 438
 439         Words which are defined in FORTH need a codeword which points to a little bit of code to
 440         give them a "helping hand" in life.  They don't need much, but they do need what is known
 441         as an "interpreter", although it doesn't really "interpret" in the same way that, say,
 442         Java bytecode used to be interpreted (ie. slowly).  This interpreter just sets up a few
 443         machine registers so that the word can then execute at full speed using the indirect
 444         threaded model above.
 445
 446         One of the things that needs to happen when QUADRUPLE calls DOUBLE is that we save the old
 447         %esi ("instruction pointer") and create a new one pointing to the first word in DOUBLE.
 448         Because we will need to restore the old %esi at the end of DOUBLE (this is, after all, like
 449         a function call), we will need a stack to store these "return addresses" (old values of %esi).
 450
 451         As you will have read, when reading the background documentation, FORTH has two stacks,
 452         an ordinary stack for parameters, and a return stack which is a bit more mysterious.  But
 453         our return stack is just the stack I talked about in the previous paragraph, used to save
 454         %esi when calling from a FORTH word into another FORTH word.
 455
 456         In this FORTH, we are using the normal stack pointer (%esp) for the parameter stack.
 457         We will use the i386's "other" stack pointer (%ebp, usually called the "frame pointer")
 458         for our return stack.
 459
 460         I've got two macros which just wrap up the details of using %ebp for the return stack.
 461         You use them as for example "PUSHRSP %eax" (push %eax on the return stack) or "POPRSP %ebx"
 462         (pop top of return stack into %ebx).
 463 */
 464
 465 /* Macros to deal with the return stack. */
 466         .macro PUSHRSP reg
 467         lea -4(%ebp),%ebp       // push reg on to return stack
 468         movl \reg,(%ebp)
 469         .endm
 470
 471         .macro POPRSP reg
 472         mov (%ebp),\reg         // pop top of return stack to reg
 473         lea 4(%ebp),%ebp
 474         .endm
 475
 476 /*
 477         And with that we can now talk about the interpreter.
 478
 479         In FORTH the interpreter function is often called DOCOL (I think it means "DO COLON" because
 480         all FORTH definitions start with a colon, as in : DOUBLE DUP + ;
 481
 482         The "interpreter" (it's not really "interpreting") just needs to push the old %esi on the
 483         stack and set %esi to the first word in the definition.  Remember that we jumped to the
 484         function using JMP *(%eax)?  Well a consequence of that is that conveniently %eax contains
 485         the address of this codeword, so just by adding 4 to it we get the address of the first
 486         data word.  Finally after setting up %esi, it just does NEXT which causes that first word
 487         to run.
 488 */
 489
 490 /* DOCOL - the interpreter! */
 491         .text
 492         .align 4
 493 DOCOL:
 494         PUSHRSP %esi            // push %esi on to the return stack
 495         addl $4,%eax            // %eax points to codeword, so make
 496         movl %eax,%esi          // %esi point to first data word
 497         NEXT
 498
 499 /*
 500         Just to make this absolutely clear, let's see how DOCOL works when jumping from QUADRUPLE
 501         into DOUBLE:
 502
 503                 QUADRUPLE:
 504                 +------------------+
 505                 | codeword         |
 506                 +------------------+               DOUBLE:
 507                 | addr of DOUBLE  ---------------> +------------------+
 508                 +------------------+       %eax -> | addr of DOCOL    |
 509         %esi -> | addr of DOUBLE   |               +------------------+
 510                 +------------------+               | addr of DUP      |
 511                 | addr of EXIT     |               +------------------+
 512                 +------------------+               | etc.             |
 513
 514         First, the call to DOUBLE calls DOCOL (the codeword of DOUBLE).  DOCOL does this:  It
 515         pushes the old %esi on the return stack.  %eax points to the codeword of DOUBLE, so we
 516         just add 4 on to it to get our new %esi:
 517
 518                 QUADRUPLE:
 519                 +------------------+
 520                 | codeword         |
 521                 +------------------+               DOUBLE:
 522                 | addr of DOUBLE  ---------------> +------------------+
 523 top of return   +------------------+       %eax -> | addr of DOCOL    |
 524 stack points -> | addr of DOUBLE   |       + 4 =   +------------------+
 525                 +------------------+       %esi -> | addr of DUP      |
 526                 | addr of EXIT     |               +------------------+
 527                 +------------------+               | etc.             |
 528
 529         Then we do NEXT, and because of the magic of threaded code that increments %esi again
 530         and calls DUP.
 531
 532         Well, it seems to work.
 533
 534         One minor point here.  Because DOCOL is the first bit of assembly actually to be defined
 535         in this file (the others were just macros), and because I usually compile this code with the
 536         text segment starting at address 0, DOCOL has address 0.  So if you are disassembling the
 537         code and see a word with a codeword of 0, you will immediately know that the word is
 538         written in FORTH (it's not an assembler primitive) and so uses DOCOL as the interpreter.
 539
 540         STARTING UP ----------------------------------------------------------------------
 541
 542         Now let's get down to nuts and bolts.  When we start the program we need to set up
 543         a few things like the return stack.  But as soon as we can, we want to jump into FORTH
 544         code (albeit much of the "early" FORTH code will still need to be written as
 545         assembly language primitives).
 546
 547         This is what the set up code does.  Does a tiny bit of house-keeping, sets up the
 548         separate return stack (NB: Linux gives us the ordinary parameter stack already), then
 549         immediately jumps to a FORTH word called COLD.  COLD stands for cold-start.  In ISO
 550         FORTH (but not in this FORTH), COLD can be called at any time to completely reset
 551         the state of FORTH, and there is another word called WARM which does a partial reset.
 552 */
 553
 554 /* ELF entry point. */
 555         .text
 556         .globl _start
 557 _start:
 558         cld
 559         mov %esp,var_S0         // Store the initial data stack pointer.
 560         mov $return_stack,%ebp  // Initialise the return stack.
 561
 562         mov $cold_start,%esi    // Initialise interpreter.
 563         NEXT                    // Run interpreter!
 564
 565         .section .rodata
 566 cold_start:                     // High-level code without a codeword.
 567         .int COLD
 568
 569 /*
 570         We also allocate some space for the return stack and some space to store user
 571         definitions.  These are static memory allocations using fixed-size buffers, but it
 572         wouldn't be a great deal of work to make them dynamic.
 573 */
 574
 575         .bss
 576 /* FORTH return stack. */
 577         .set RETURN_STACK_SIZE,8192
 578         .align 4096
 579         .space RETURN_STACK_SIZE
 580 return_stack:                   // Initial top of return stack.
 581
 582 /* The user definitions area: space for user-defined words and general memory allocations. */
 583         .set USER_DEFS_SIZE,65536
 584         .align 4096
 585 user_defs_start:
 586         .space USER_DEFS_SIZE
 587
 588 /* This is used as a temporary input buffer when reading from files or the terminal. */
 589         .set BUFFER_SIZE,4096
 590         .align 4096
 591 buffer:
 592 _initbufftop:
 593         .space BUFFER_SIZE
 594 buffend:
 595 currkey:
 596         .int buffer
 597 bufftop:
 598         .int _initbufftop
 599
 600 /*
 601         BUILT-IN WORDS ----------------------------------------------------------------------
 602
 603         Remember our dictionary entries (headers).  Let's bring those together with the codeword
 604         and data words to see how : DOUBLE DUP + ; really looks in memory.
 605
 606           pointer to previous word
 607            ^
 608            |
 609         +--|------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
 610         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
 611         +---------+---+---+---+---+---+---+---+---+------------+--|---------+------------+------------+
 612            ^       len                         pad  codeword      |
 613            |                                                      V
 614           LINK in next word                             points to codeword of DUP
 615
 616         Initially we can't just write ": DOUBLE DUP + ;" (ie. that literal string) here because we
 617         don't yet have anything to read the string, break it up at spaces, parse each word, etc. etc.
 618         So instead we will have to define built-in words using the GNU assembler data constructors
 619         (like .int, .byte, .string, .ascii and so on -- look them up in the gas info page if you are
 620         unsure of them).
 621
 622         The long way would be:
 623         .int <link to previous word>
 624         .byte 6                 // len
 625         .ascii "DOUBLE"         // string
 626         .byte 0                 // padding
 627 DOUBLE: .int DOCOL              // codeword
 628         .int DUP                // pointer to codeword of DUP
 629         .int PLUS               // pointer to codeword of +
 630         .int EXIT               // pointer to codeword of EXIT
 631
 632         That's going to get quite tedious rather quickly, so here I define an assembler macro
 633         so that I can just write:
 634
 635         defword "DOUBLE",6,,DOUBLE
 636         .int DUP,PLUS,EXIT
 637
 638         and I'll get exactly the same effect.
 639
 640         Don't worry too much about the exact implementation details of this macro - it's complicated!
 641 */
 642
 643 /* Flags - these are discussed later. */
 644         .set F_IMMED,0x80
 645         .set F_HIDDEN,0x20
 646         .set F_LENMASK,0x1f     // length mask
 647
 648         // Store the chain of links.
 649         .set link,0
 650
 651         .macro defword name, namelen, flags=0, label
 652         .section .rodata
 653         .align 4
 654         .globl name_\label
 655 name_\label :
 656         .int link               // link
 657         .set link,name_\label
 658         .byte \flags+\namelen   // flags + length byte
 659         .ascii "\name"          // the name
 660         .align 4
 661         .globl \label
 662 \label :
 663         .int DOCOL              // codeword - the interpreter
 664         // list of word pointers follow
 665         .endm
 666
 667 /*
 668         Similarly I want a way to write words written in assembly language.  There will quite a few
 669         of these to start with because, well, everything has to start in assembly before there's
 670         enough "infrastructure" to be able to start writing FORTH words, but also I want to define
 671         some common FORTH words in assembly language for speed, even though I could write them in FORTH.
 672
 673         This is what DUP looks like in memory:
 674
 675           pointer to previous word
 676            ^
 677            |
 678         +--|------+---+---+---+---+------------+
 679         | LINK    | 3 | D | U | P | code_DUP ---------------------> points to the assembly
 680         +---------+---+---+---+---+------------+                    code used to write DUP,
 681            ^       len              codeword                        which ends with NEXT.
 682            |
 683           LINK in next word
 684
 685         Again, for brevity in writing the header I'm going to write an assembler macro called defcode.
 686 */
 687
 688         .macro defcode name, namelen, flags=0, label
 689         .section .rodata
 690         .align 4
 691         .globl name_\label
 692 name_\label :
 693         .int link               // link
 694         .set link,name_\label
 695         .byte \flags+\namelen   // flags + length byte
 696         .ascii "\name"          // the name
 697         .align 4
 698         .globl \label
 699 \label :
 700         .int code_\label        // codeword
 701         .text
 702         .align 4
 703         .globl code_\label
 704 code_\label :                   // assembler code follows
 705         .endm
 706
 707 /*
 708         Now some easy FORTH primitives.  These are written in assembly for speed.  If you understand
 709         i386 assembly language then it is worth reading these.  However if you don't understand assembly
 710         you can skip the details.
 711 */
 712
 713         defcode "DUP",3,,DUP
 714         pop %eax                // duplicate top of stack
 715         push %eax
 716         push %eax
 717         NEXT
 718
 719         defcode "DROP",4,,DROP
 720         pop %eax                // drop top of stack
 721         NEXT
 722
 723         defcode "SWAP",4,,SWAP
 724         pop %eax                // swap top of stack
 725         pop %ebx
 726         push %eax
 727         push %ebx
 728         NEXT
 729
 730         defcode "OVER",4,,OVER
 731         mov 4(%esp),%eax        // get the second element of stack
 732         push %eax               // and push it on top
 733         NEXT
 734
 735         defcode "ROT",3,,ROT
 736         pop %eax
 737         pop %ebx
 738         pop %ecx
 739         push %eax
 740         push %ecx
 741         push %ebx
 742         NEXT
 743
 744         defcode "-ROT",4,,NROT
 745         pop %eax
 746         pop %ebx
 747         pop %ecx
 748         push %ebx
 749         push %eax
 750         push %ecx
 751         NEXT
 752
 753         defcode "1+",2,,INCR
 754         incl (%esp)             // increment top of stack
 755         NEXT
 756
 757         defcode "1-",2,,DECR
 758         decl (%esp)             // decrement top of stack
 759         NEXT
 760
 761         defcode "4+",2,,INCR4
 762         addl $4,(%esp)          // add 4 to top of stack
 763         NEXT
 764
 765         defcode "4-",2,,DECR4
 766         subl $4,(%esp)          // subtract 4 from top of stack
 767         NEXT
 768
 769         defcode "+",1,,ADD
 770         pop %eax                // get top of stack
 771         addl %eax,(%esp)        // and add it to next word on stack
 772         NEXT
 773
 774         defcode "-",1,,SUB
 775         pop %eax                // get top of stack
 776         subl %eax,(%esp)        // and subtract it from next word on stack
 777         NEXT
 778
 779         defcode "*",1,,MUL
 780         pop %eax
 781         pop %ebx
 782         imull %ebx,%eax
 783         push %eax               // ignore overflow
 784         NEXT
 785
 786         defcode "/",1,,DIV
 787         xor %edx,%edx
 788         pop %ebx
 789         pop %eax
 790         idivl %ebx
 791         push %eax               // push quotient
 792         NEXT
 793
 794         defcode "MOD",3,,MOD
 795         xor %edx,%edx
 796         pop %ebx
 797         pop %eax
 798         idivl %ebx
 799         push %edx               // push remainder
 800         NEXT
 801
 802         defcode "=",1,,EQU      // top two words are equal?
 803         pop %eax
 804         pop %ebx
 805         cmp %ebx,%eax
 806         je 1f
 807         pushl $0
 808         NEXT
 809 1:      pushl $1
 810         NEXT
 811
 812         defcode "<>",2,,NEQU    // top two words are not equal?
 813         pop %eax
 814         pop %ebx
 815         cmp %ebx,%eax
 816         je 1f
 817         pushl $1
 818         NEXT
 819 1:      pushl $0
 820         NEXT
 821
 822         defcode "<",1,,LT
 823         pop %eax
 824         pop %ebx
 825         cmp %eax,%ebx
 826         jl 1f
 827         pushl $0
 828         NEXT
 829 1:      pushl $1
 830         NEXT
 831
 832         defcode ">",1,,GT
 833         pop %eax
 834         pop %ebx
 835         cmp %eax,%ebx
 836         jg 1f
 837         pushl $0
 838         NEXT
 839 1:      pushl $1
 840         NEXT
 841
 842         defcode "<=",2,,LE
 843         pop %eax
 844         pop %ebx
 845         cmp %eax,%ebx
 846         jle 1f
 847         pushl $0
 848         NEXT
 849 1:      pushl $1
 850         NEXT
 851
 852         defcode ">=",2,,GE
 853         pop %eax
 854         pop %ebx
 855         cmp %eax,%ebx
 856         jge 1f
 857         pushl $0
 858         NEXT
 859 1:      pushl $1
 860         NEXT
 861
 862         defcode "0=",2,,ZEQU    // top of stack equals 0?
 863         pop %eax
 864         test %eax,%eax
 865         jz 1f
 866         pushl $0
 867         NEXT
 868 1:      pushl $1
 869         NEXT
 870
 871         defcode "0<>",3,,ZNEQU  // top of stack not 0?
 872         pop %eax
 873         test %eax,%eax
 874         jnz 1f
 875         pushl $0
 876         NEXT
 877 1:      pushl $1
 878         NEXT
 879
 880         defcode "0<",2,,ZLT
 881         pop %eax
 882         test %eax,%eax
 883         jl 1f
 884         pushl $0
 885         NEXT
 886 1:      pushl $1
 887         NEXT
 888
 889         defcode "0>",2,,ZGT
 890         pop %eax
 891         test %eax,%eax
 892         jg 1f
 893         pushl $0
 894         NEXT
 895 1:      pushl $1
 896         NEXT
 897
 898         defcode "0<=",3,,ZLE
 899         pop %eax
 900         test %eax,%eax
 901         jle 1f
 902         pushl $0
 903         NEXT
 904 1:      pushl $1
 905         NEXT
 906
 907         defcode "0>=",3,,ZGE
 908         pop %eax
 909         test %eax,%eax
 910         jge 1f
 911         pushl $0
 912         NEXT
 913 1:      pushl $1
 914         NEXT
 915
 916         defcode "AND",3,,AND
 917         pop %eax
 918         andl %eax,(%esp)
 919         NEXT
 920
 921         defcode "OR",2,,OR
 922         pop %eax
 923         orl %eax,(%esp)
 924         NEXT
 925
 926         defcode "XOR",3,,XOR
 927         pop %eax
 928         xorl %eax,(%esp)
 929         NEXT
 930
 931         defcode "INVERT",6,,INVERT // this is the FORTH bitwise "NOT" function
 932         notl (%esp)
 933         NEXT
 934
 935 /*
 936         RETURNING FROM FORTH WORDS ----------------------------------------------------------------------
 937
 938         Time to talk about what happens when we EXIT a function.  In this diagram QUADRUPLE has called
 939         DOUBLE, and DOUBLE is about to exit (look at where %esi is pointing):
 940
 941                 QUADRUPLE
 942                 +------------------+
 943                 | codeword         |
 944                 +------------------+               DOUBLE
 945                 | addr of DOUBLE  ---------------> +------------------+
 946                 +------------------+               | codeword         |
 947                 | addr of DOUBLE   |               +------------------+
 948                 +------------------+               | addr of DUP      |
 949                 | addr of EXIT     |               +------------------+
 950                 +------------------+               | addr of +        |
 951                                                    +------------------+
 952                                            %esi -> | addr of EXIT     |
 953                                                    +------------------+
 954
 955         What happens when the + function does NEXT?  Well, the following code is executed.
 956 */
 957
 958         defcode "EXIT",4,,EXIT
 959         POPRSP %esi             // pop return stack into %esi
 960         NEXT
 961
 962 /*
 963         EXIT gets the old %esi which we saved from before on the return stack, and puts it in %esi.
 964         So after this (but just before NEXT) we get:
 965
 966                 QUADRUPLE
 967                 +------------------+
 968                 | codeword         |
 969                 +------------------+               DOUBLE
 970                 | addr of DOUBLE  ---------------> +------------------+
 971                 +------------------+               | codeword         |
 972         %esi -> | addr of DOUBLE   |               +------------------+
 973                 +------------------+               | addr of DUP      |
 974                 | addr of EXIT     |               +------------------+
 975                 +------------------+               | addr of +        |
 976                                                    +------------------+
 977                                                    | addr of EXIT     |
 978                                                    +------------------+
 979
 980         And NEXT just completes the job by, well in this case just by calling DOUBLE again :-)
 981
 982         LITERALS ----------------------------------------------------------------------
 983
 984         The final point I "glossed over" before was how to deal with functions that do anything
 985         apart from calling other functions.  For example, suppose that DOUBLE was defined like this:
 986
 987         : DOUBLE 2 * ;
 988
 989         It does the same thing, but how do we compile it since it contains the literal 2?  One way
 990         would be to have a function called "2" (which you'd have to write in assembler), but you'd need
 991         a function for every single literal that you wanted to use.
 992
 993         FORTH solves this by compiling the function using a special word called LIT:
 994
 995         +---------------------------+-------+-------+-------+-------+-------+
 996         | (usual header of DOUBLE)  | DOCOL | LIT   | 2     | *     | EXIT  |
 997         +---------------------------+-------+-------+-------+-------+-------+
 998
 999         LIT is executed in the normal way, but what it does next is definitely not normal.  It
1000         looks at %esi (which now points to the literal 2), grabs it, pushes it on the stack, then
1001         manipulates %esi in order to skip the literal as if it had never been there.
1002
1003         What's neat is that the whole grab/manipulate can be done using a single byte single
1004         i386 instruction, our old friend LODSL.  Rather than me drawing more ASCII-art diagrams,
1005         see if you can find out how LIT works:
1006 */
1007
1008         defcode "LIT",3,,LIT
1009         // %esi points to the next command, but in this case it points to the next
1010         // literal 32 bit integer.  Get that literal into %eax and increment %esi.
1011         // On x86, it's a convenient single byte instruction!  (cf. NEXT macro)
1012         lodsl
1013         push %eax               // push the literal number on to stack
1014         NEXT
1015
1016 /*
1017         MEMORY ----------------------------------------------------------------------
1018
1019         As important point about FORTH is that it gives you direct access to the lowest levels
1020         of the machine.  Manipulating memory directly is done frequently in FORTH, and these are
1021         the primitive words for doing it.
1022 */
1023
1024         defcode "!",1,,STORE
1025         pop %ebx                // address to store at
1026         pop %eax                // data to store there
1027         mov %eax,(%ebx)         // store it
1028         NEXT
1029
1030         defcode "@",1,,FETCH
1031         pop %ebx                // address to fetch
1032         mov (%ebx),%eax         // fetch it
1033         push %eax               // push value onto stack
1034         NEXT
1035
1036         defcode "+!",2,,ADDSTORE
1037         pop %ebx                // address
1038         pop %eax                // the amount to add
1039         addl %eax,(%ebx)        // add it
1040         NEXT
1041
1042         defcode "-!",2,,SUBSTORE
1043         pop %ebx                // address
1044         pop %eax                // the amount to subtract
1045         subl %eax,(%ebx)        // add it
1046         NEXT
1047
1048 /* ! and @ (STORE and FETCH) store 32-bit words.  It's also useful to be able to read and write bytes.
1049  * I don't know whether FORTH has these words, so I invented my own, called !b and @b.
1050  * Byte-oriented operations only work on architectures which permit them (i386 is one of those).
1051  * UPDATE: writing a byte to the dictionary pointer is called C, in FORTH.
1052  */
1053         defcode "!b",2,,STOREBYTE
1054         pop %ebx                // address to store at
1055         pop %eax                // data to store there
1056         movb %al,(%ebx)         // store it
1057         NEXT
1058
1059         defcode "@b",2,,FETCHBYTE
1060         pop %ebx                // address to fetch
1061         xor %eax,%eax
1062         movb (%ebx),%al         // fetch it
1063         push %eax               // push value onto stack
1064         NEXT
1065
1066 /*
1067         BUILT-IN VARIABLES ----------------------------------------------------------------------
1068
1069         These are some built-in variables and related standard FORTH words.  Of these, the only one that we
1070         have discussed so far was LATEST, which points to the last (most recently defined) word in the
1071         FORTH dictionary.  LATEST is also a FORTH word which pushes the address of LATEST (the variable)
1072         on to the stack, so you can read or write it using @ and ! operators.  For example, to print
1073         the current value of LATEST (and this can apply to any FORTH variable) you would do:
1074
1075         LATEST @ . CR
1076
1077         To make defining variables shorter, I'm using a macro called defvar, similar to defword and
1078         defcode above.  (In fact the defvar macro uses defcode to do the dictionary header).
1079 */
1080
1081         .macro defvar name, namelen, flags=0, label, initial=0
1082         defcode \name,\namelen,\flags,\label
1083         push $var_\name
1084         NEXT
1085         .data
1086         .align 4
1087 var_\name :
1088         .int \initial
1089         .endm
1090
1091 /*
1092         The built-in variables are:
1093
1094         STATE           Is the interpreter executing code (0) or compiling a word (non-zero)?
1095         LATEST          Points to the latest (most recently defined) word in the dictionary.
1096         HERE            Points to the next free byte of memory.  When compiling, compiled words go here.
1097         _X              These are three scratch variables, used by some standard dictionary words.
1098         _Y
1099         _Z
1100         S0              Stores the address of the top of the parameter stack.
1101         BASE            The current base for printing and reading numbers.
1102
1103 */
1104         defvar "STATE",5,,STATE
1105         defvar "HERE",4,,HERE,user_defs_start
1106         defvar "LATEST",6,,LATEST,name_SYSEXIT // SYSEXIT must be last in built-in dictionary
1107         defvar "_X",2,,TX
1108         defvar "_Y",2,,TY
1109         defvar "_Z",2,,TZ
1110         defvar "S0",2,,SZ
1111         defvar "BASE",4,,BASE,10
1112
1113 /*
1114         BUILT-IN CONSTANTS ----------------------------------------------------------------------
1115
1116         It's also useful to expose a few constants to FORTH.  When the word is executed it pushes a
1117         constant value on the stack.
1118
1119         The built-in constants are:
1120
1121         VERSION         Is the current version of this FORTH.
1122         R0              The address of the top of the return stack.
1123         DOCOL           Pointer to DOCOL.
1124         F_IMMED         The IMMEDIATE flag's actual value.
1125         F_HIDDEN        The HIDDEN flag's actual value.
1126         F_LENMASK       The length mask.
1127 */
1128
1129         .macro defconst name, namelen, flags=0, label, value
1130         defcode \name,\namelen,\flags,\label
1131         push $\value
1132         NEXT
1133         .endm
1134
1135         defconst "VERSION",7,,VERSION,JONES_VERSION
1136         defconst "R0",2,,RZ,return_stack
1137         defconst "DOCOL",5,,__DOCOL,DOCOL
1138         defconst "F_IMMED",7,,__F_IMMED,F_IMMED
1139         defconst "F_HIDDEN",8,,__F_HIDDEN,F_HIDDEN
1140         defconst "F_LENMASK",9,,__F_LENMASK,F_LENMASK
1141
1142 /*
1143         RETURN STACK ----------------------------------------------------------------------
1144
1145         These words allow you to access the return stack.  Recall that the register %ebp always points to
1146         the top of the return stack.
1147 */
1148
1149         defcode ">R",2,,TOR
1150         pop %eax                // pop parameter stack into %eax
1151         PUSHRSP %eax            // push it on to the return stack
1152         NEXT
1153
1154         defcode "R>",2,,FROMR
1155         POPRSP %eax             // pop return stack on to %eax
1156         push %eax               // and push on to parameter stack
1157         NEXT
1158
1159         defcode "RSP@",4,,RSPFETCH
1160         push %ebp
1161         NEXT
1162
1163         defcode "RSP!",4,,RSPSTORE
1164         pop %ebp
1165         NEXT
1166
1167         defcode "RDROP",5,,RDROP
1168         lea 4(%ebp),%ebp        // pop return stack and throw away
1169         NEXT
1170
1171 /*
1172         PARAMETER (DATA) STACK ----------------------------------------------------------------------
1173
1174         These functions allow you to manipulate the parameter stack.  Recall that Linux sets up the parameter
1175         stack for us, and it is accessed through %esp.
1176 */
1177
1178         defcode "DSP@",4,,DSPFETCH
1179         mov %esp,%eax
1180         push %eax
1181         NEXT
1182
1183         defcode "DSP!",4,,DSPSTORE
1184         pop %esp
1185         NEXT
1186
1187 /*
1188         INPUT AND OUTPUT ----------------------------------------------------------------------
1189
1190         These are our first really meaty/complicated FORTH primitives.  I have chosen to write them in
1191         assembler, but surprisingly in "real" FORTH implementations these are often written in terms
1192         of more fundamental FORTH primitives.  I chose to avoid that because I think that just obscures
1193         the implementation.  After all, you may not understand assembler but you can just think of it
1194         as an opaque block of code that does what it says.
1195
1196         Let's discuss input first.
1197
1198         The FORTH word KEY reads the next byte from stdin (and pushes it on the parameter stack).
1199         So if KEY is called and someone hits the space key, then the number 32 (ASCII code of space)
1200         is pushed on the stack.
1201
1202         In FORTH there is no distinction between reading code and reading input.  We might be reading
1203         and compiling code, we might be reading words to execute, we might be asking for the user
1204         to type their name -- ultimately it all comes in through KEY.
1205
1206         The implementation of KEY uses an input buffer of a certain size (defined at the end of the
1207         program).  It calls the Linux read(2) system call to fill this buffer and tracks its position
1208         in the buffer using a couple of variables, and if it runs out of input buffer then it refills
1209         it automatically.  The other thing that KEY does is if it detects that stdin has closed, it
1210         exits the program, which is why when you hit ^D the FORTH system cleanly exits.
1211 */
1212
1213 #include <asm-i386/unistd.h>
1214
1215         defcode "KEY",3,,KEY
1216         call _KEY
1217         push %eax               // push return value on stack
1218         NEXT
1219 _KEY:
1220         mov (currkey),%ebx
1221         cmp (bufftop),%ebx
1222         jge 1f
1223         xor %eax,%eax
1224         mov (%ebx),%al
1225         inc %ebx
1226         mov %ebx,(currkey)
1227         ret
1228
1229 1:      // out of input; use read(2) to fetch more input from stdin
1230         xor %ebx,%ebx           // 1st param: stdin
1231         mov $buffer,%ecx        // 2nd param: buffer
1232         mov %ecx,currkey
1233         mov $buffend-buffer,%edx // 3rd param: max length
1234         mov $__NR_read,%eax     // syscall: read
1235         int $0x80
1236         test %eax,%eax          // If %eax <= 0, then exit.
1237         jbe 2f
1238         addl %eax,%ecx          // buffer+%eax = bufftop
1239         mov %ecx,bufftop
1240         jmp _KEY
1241
1242 2:      // error or out of input: exit
1243         xor %ebx,%ebx
1244         mov $__NR_exit,%eax     // syscall: exit
1245         int $0x80
1246
1247 /*
1248         By contrast, output is much simpler.  The FORTH word EMIT writes out a single byte to stdout.
1249         This implementation just uses the write system call.  No attempt is made to buffer output, but
1250         it would be a good exercise to add it.
1251 */
1252
1253         defcode "EMIT",4,,EMIT
1254         pop %eax
1255         call _EMIT
1256         NEXT
1257 _EMIT:
1258         mov $1,%ebx             // 1st param: stdout
1259
1260         // write needs the address of the byte to write
1261         mov %al,(2f)
1262         mov $2f,%ecx            // 2nd param: address
1263
1264         mov $1,%edx             // 3rd param: nbytes = 1
1265
1266         mov $__NR_write,%eax    // write syscall
1267         int $0x80
1268         ret
1269
1270         .bss
1271 2:      .space 1                // scratch used by EMIT
1272
1273 /*
1274         Back to input, WORD is a FORTH word which reads the next full word of input.
1275
1276         What it does in detail is that it first skips any blanks (spaces, tabs, newlines and so on).
1277         Then it calls KEY to read characters into an internal buffer until it hits a blank.  Then it
1278         calculates the length of the word it read and returns the address and the length as
1279         two words on the stack (with address at the top).
1280
1281         Notice that WORD has a single internal buffer which it overwrites each time (rather like
1282         a static C string).  Also notice that WORD's internal buffer is just 32 bytes long and
1283         there is NO checking for overflow.  31 bytes happens to be the maximum length of a
1284         FORTH word that we support, and that is what WORD is used for: to read FORTH words when
1285         we are compiling and executing code.  The returned strings are not NUL-terminated, so
1286         in some crazy-world you could define FORTH words containing ASCII NULs, although why
1287         you'd want to is a bit beyond me.
1288
1289         WORD is not suitable for just reading strings (eg. user input) because of all the above
1290         peculiarities and limitations.
1291
1292         Note that when executing, you'll see:
1293         WORD FOO
1294         which puts "FOO" and length 3 on the stack, but when compiling:
1295         : BAR WORD FOO ;
1296         is an error (or at least it doesn't do what you might expect).  Later we'll talk about compiling
1297         and immediate mode, and you'll understand why.
1298 */
1299
1300         defcode "WORD",4,,WORD
1301         call _WORD
1302         push %ecx               // push length
1303         push %edi               // push base address
1304         NEXT
1305
1306 _WORD:
1307         /* Search for first non-blank character.  Also skip \ comments. */
1308 1:
1309         call _KEY               // get next key, returned in %eax
1310         cmpb $'\\',%al          // start of a comment?
1311         je 3f                   // if so, skip the comment
1312         cmpb $' ',%al
1313         jbe 1b                  // if so, keep looking
1314
1315         /* Search for the end of the word, storing chars as we go. */
1316         mov $5f,%edi            // pointer to return buffer
1317 2:
1318         stosb                   // add character to return buffer
1319         call _KEY               // get next key, returned in %al
1320         cmpb $' ',%al           // is blank?
1321         ja 2b                   // if not, keep looping
1322
1323         /* Return the word (well, the static buffer) and length. */
1324         sub $5f,%edi
1325         mov %edi,%ecx           // return length of the word
1326         mov $5f,%edi            // return address of the word
1327         ret
1328
1329         /* Code to skip \ comments to end of the current line. */
1330 3:
1331         call _KEY
1332         cmpb $'\n',%al          // end of line yet?
1333         jne 3b
1334         jmp 1b
1335
1336         .bss
1337         // A static buffer where WORD returns.  Subsequent calls
1338         // overwrite this buffer.  Maximum word length is 32 chars.
1339 5:      .space 32
1340
1341 /*
1342         . (also called DOT) prints the top of the stack as an integer in the current BASE.
1343 */
1344
1345         defcode ".",1,,DOT
1346         pop %eax                // Get the number to print into %eax
1347         call _DOT               // Easier to do this recursively ...
1348         NEXT
1349 _DOT:
1350         mov var_BASE,%ecx       // Get current BASE
1351 1:
1352         cmp %ecx,%eax           // %eax < BASE?  If so jump to print immediately.
1353         jb 2f
1354         xor %edx,%edx           // %edx:%eax / %ecx -> quotient %eax, remainder %edx
1355         idivl %ecx
1356         pushl %edx              // Print quotient (top half) first ...
1357         call _DOT
1358         popl %eax               // ... then loop to print remainder
1359         jmp 1b
1360 2:                              // %eax < BASE so print immediately.
1361         movl $digits,%edx
1362         addl %eax,%edx
1363         movb (%edx),%al         // Note top bits are already zero.
1364         call _EMIT
1365         ret
1366         .section .rodata
1367 digits: .ascii "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1368
1369 /*
1370         Almost the opposite of DOT (but not quite), SNUMBER parses a numeric string such as one returned
1371         by WORD and pushes the number on the parameter stack.
1372
1373         This function does absolutely no error checking, and in particular the length of the string
1374         must be >= 1 bytes, and should contain only digits 0-9.  If it doesn't you'll get random results.
1375
1376         This function is only used when reading literal numbers in code, and shouldn't really be used
1377         in user code at all.
1378 */
1379         defcode "SNUMBER",7,,SNUMBER
1380         pop %edi
1381         pop %ecx
1382         call _SNUMBER
1383         push %eax
1384         NEXT
1385 _SNUMBER:
1386         xor %eax,%eax
1387         xor %ebx,%ebx
1388 1:
1389         imull $10,%eax          // %eax *= 10
1390         movb (%edi),%bl
1391         inc %edi
1392         subb $'0',%bl           // ASCII -> digit
1393         add %ebx,%eax
1394         dec %ecx
1395         jnz 1b
1396         ret
1397
1398 /*
1399         DICTIONARY LOOK UPS ----------------------------------------------------------------------
1400
1401         We're building up to our prelude on how FORTH code is compiled, but first we need yet more infrastructure.
1402
1403         The FORTH word FIND takes a string (a word as parsed by WORD -- see above) and looks it up in the
1404         dictionary.  What it actually returns is the address of the dictionary header, if it finds it,
1405         or 0 if it didn't.
1406
1407         So if DOUBLE is defined in the dictionary, then WORD DOUBLE FIND returns the following pointer:
1408
1409     pointer to this
1410         |
1411         |
1412         V
1413         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1414         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1415         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1416
1417         See also >CFA and >DFA.
1418
1419         FIND doesn't find dictionary entries which are flagged as HIDDEN.  See below for why.
1420 */
1421
1422         defcode "FIND",4,,FIND
1423         pop %edi                // %edi = address
1424         pop %ecx                // %ecx = length
1425         call _FIND
1426         push %eax
1427         NEXT
1428
1429 _FIND:
1430         push %esi               // Save %esi so we can use it in string comparison.
1431
1432         // Now we start searching backwards through the dictionary for this word.
1433         mov var_LATEST,%edx     // LATEST points to name header of the latest word in the dictionary
1434 1:
1435         test %edx,%edx          // NULL pointer?  (end of the linked list)
1436         je 4f
1437
1438         // Compare the length expected and the length of the word.
1439         // Note that if the F_HIDDEN flag is set on the word, then by a bit of trickery
1440         // this won't pick the word (the length will appear to be wrong).
1441         xor %eax,%eax
1442         movb 4(%edx),%al        // %al = flags+length field
1443         andb $(F_HIDDEN|F_LENMASK),%al // %al = name length
1444         cmpb %cl,%al            // Length is the same?
1445         jne 2f
1446
1447         // Compare the strings in detail.
1448         push %ecx               // Save the length
1449         push %edi               // Save the address (repe cmpsb will move this pointer)
1450         lea 5(%edx),%esi        // Dictionary string we are checking against.
1451         repe cmpsb              // Compare the strings.
1452         pop %edi
1453         pop %ecx
1454         jne 2f                  // Not the same.
1455
1456         // The strings are the same - return the header pointer in %eax
1457         pop %esi
1458         mov %edx,%eax
1459         ret
1460
1461 2:
1462         mov (%edx),%edx         // Move back through the link field to the previous word
1463         jmp 1b                  // .. and loop.
1464
1465 4:      // Not found.
1466         pop %esi
1467         xor %eax,%eax           // Return zero to indicate not found.
1468         ret
1469
1470 /*
1471         FIND returns the dictionary pointer, but when compiling we need the codeword pointer (recall
1472         that FORTH definitions are compiled into lists of codeword pointers).  The standard FORTH
1473         word >CFA turns a dictionary pointer into a codeword pointer.
1474
1475         The example below shows the result of:
1476
1477                 WORD DOUBLE FIND >CFA
1478
1479         FIND returns a pointer to this
1480         |                               >CFA converts it to a pointer to this
1481         |                                          |
1482         V                                          V
1483         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1484         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1485         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1486
1487         Notes:
1488
1489         Because names vary in length, this isn't just a simple increment.
1490
1491         In this FORTH you cannot easily turn a codeword pointer back into a dictionary entry pointer, but
1492         that is not true in most FORTH implementations where they store a back pointer in the definition
1493         (with an obvious memory/complexity cost).  The reason they do this is that it is useful to be
1494         able to go backwards (codeword -> dictionary entry) in order to decompile FORTH definitions.
1495
1496         What does CFA stand for?  My best guess is "Code Field Address".
1497 */
1498
1499         defcode ">CFA",4,,TCFA
1500         pop %edi
1501         call _TCFA
1502         push %edi
1503         NEXT
1504 _TCFA:
1505         xor %eax,%eax
1506         add $4,%edi             // Skip link pointer.
1507         movb (%edi),%al         // Load flags+len into %al.
1508         inc %edi                // Skip flags+len byte.
1509         andb $F_LENMASK,%al     // Just the length, not the flags.
1510         add %eax,%edi           // Skip the name.
1511         addl $3,%edi            // The codeword is 4-byte aligned.
1512         andl $~3,%edi
1513         ret
1514
1515 /*
1516         Related to >CFA is >DFA which takes a dictionary entry address as returned by FIND and
1517         returns a pointer to the first data field.
1518
1519         FIND returns a pointer to this
1520         |                               >CFA converts it to a pointer to this
1521         |                                          |
1522         |                                          |    >DFA converts it to a pointer to this
1523         |                                          |             |
1524         V                                          V             V
1525         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1526         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1527         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1528
1529         (Note to those following the source of FIG-FORTH / ciforth: My >DFA definition is
1530         different from theirs, because they have an extra indirection).
1531
1532         You can see that >DFA is easily defined in FORTH just by adding 4 to the result of >CFA.
1533 */
1534
1535         defword ">DFA",4,,TDFA
1536         .int TCFA               // >CFA         (get code field address)
1537         .int INCR4              // 4+           (add 4 to it to get to next word)
1538         .int EXIT               // EXIT         (return from FORTH word)
1539
1540 /*
1541         COMPILING ----------------------------------------------------------------------
1542
1543         Now we'll talk about how FORTH compiles words.  Recall that a word definition looks like this:
1544
1545                 : DOUBLE DUP + ;
1546
1547         and we have to turn this into:
1548
1549           pointer to previous word
1550            ^
1551            |
1552         +--|------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1553         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1554         +---------+---+---+---+---+---+---+---+---+------------+--|---------+------------+------------+
1555            ^       len                         pad  codeword      |
1556            |                                                      V
1557           LATEST points here                            points to codeword of DUP
1558
1559         There are several problems to solve.  Where to put the new word?  How do we read words?  How
1560         do we define the words : (COLON) and ; (SEMICOLON)?
1561
1562         FORTH solves this rather elegantly and as you might expect in a very low-level way which
1563         allows you to change how the compiler works on your own code.
1564
1565         FORTH has an INTERPRETER function (a true interpreter this time, not DOCOL) which runs in a
1566         loop, reading words (using WORD), looking them up (using FIND), turning them into codeword
1567         pointers (using >CFA) and deciding what to do with them.
1568
1569         What it does depends on the mode of the interpreter (in variable STATE).
1570
1571         When STATE is zero, the interpreter just runs each word as it looks them up.  This is known as
1572         immediate mode.
1573
1574         The interesting stuff happens when STATE is non-zero -- compiling mode.  In this mode the
1575         interpreter appends the codeword pointer to user memory (the HERE variable points to the next
1576         free byte of user memory).
1577
1578         So you may be able to see how we could define : (COLON).  The general plan is:
1579
1580         (1) Use WORD to read the name of the function being defined.
1581
1582         (2) Construct the dictionary entry -- just the header part -- in user memory:
1583
1584     pointer to previous word (from LATEST)                      +-- Afterwards, HERE points here, where
1585            ^                                                    |   the interpreter will start appending
1586            |                                                    V   codewords.
1587         +--|------+---+---+---+---+---+---+---+---+------------+
1588         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      |
1589         +---------+---+---+---+---+---+---+---+---+------------+
1590                    len                         pad  codeword
1591
1592         (3) Set LATEST to point to the newly defined word, ...
1593
1594         (4) .. and most importantly leave HERE pointing just after the new codeword.  This is where
1595             the interpreter will append codewords.
1596
1597         (5) Set STATE to 1.  This goes into compile mode so the interpreter starts appending codewords to
1598             our partially-formed header.
1599
1600         After : has run, our input is here:
1601
1602         : DOUBLE DUP + ;
1603                  ^
1604                  |
1605                 Next byte returned by KEY will be the 'D' character of DUP
1606
1607         so the interpreter (now it's in compile mode, so I guess it's really the compiler) reads "DUP",
1608         looks it up in the dictionary, gets its codeword pointer, and appends it:
1609
1610                                                                              +-- HERE updated to point here.
1611                                                                              |
1612                                                                              V
1613         +---------+---+---+---+---+---+---+---+---+------------+------------+
1614         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        |
1615         +---------+---+---+---+---+---+---+---+---+------------+------------+
1616                    len                         pad  codeword
1617
1618         Next we read +, get the codeword pointer, and append it:
1619
1620                                                                                           +-- HERE updated to point here.
1621                                                                                           |
1622                                                                                           V
1623         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+
1624         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          |
1625         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+
1626                    len                         pad  codeword
1627
1628         The issue is what happens next.  Obviously what we _don't_ want to happen is that we
1629         read ";" and compile it and go on compiling everything afterwards.
1630
1631         At this point, FORTH uses a trick.  Remember the length byte in the dictionary definition
1632         isn't just a plain length byte, but can also contain flags.  One flag is called the
1633         IMMEDIATE flag (F_IMMED in this code).  If a word in the dictionary is flagged as
1634         IMMEDIATE then the interpreter runs it immediately _even if it's in compile mode_.
1635
1636         This is how the word ; (SEMICOLON) works -- as a word flagged in the dictionary as IMMEDIATE.
1637         And all it does is append the codeword for EXIT on to the current definition and switch
1638         back to immediate mode (set STATE back to 0).  Shortly we'll see the actual definition
1639         of ; and we'll see that it's really a very simple definition, declared IMMEDIATE.
1640
1641         After the interpreter reads ; and executes it 'immediately', we get this:
1642
1643         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1644         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      | DUP        | +          | EXIT       |
1645         +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1646                    len                         pad  codeword                                           ^
1647                                                                                                        |
1648                                                                                                       HERE
1649
1650         STATE is set to 0.
1651
1652         And that's it, job done, our new definition is compiled, and we're back in immediate mode
1653         just reading and executing words, perhaps including a call to test our new word DOUBLE.
1654
1655         The only last wrinkle in this is that while our word was being compiled, it was in a
1656         half-finished state.  We certainly wouldn't want DOUBLE to be called somehow during
1657         this time.  There are several ways to stop this from happening, but in FORTH what we
1658         do is flag the word with the HIDDEN flag (F_HIDDEN in this code) just while it is
1659         being compiled.  This prevents FIND from finding it, and thus in theory stops any
1660         chance of it being called.
1661
1662         The above explains how compiling, : (COLON) and ; (SEMICOLON) works and in a moment I'm
1663         going to define them.  The : (COLON) function can be made a little bit more general by writing
1664         it in two parts.  The first part, called CREATE, makes just the header:
1665
1666                                                    +-- Afterwards, HERE points here.
1667                                                    |
1668                                                    V
1669         +---------+---+---+---+---+---+---+---+---+
1670         | LINK    | 6 | D | O | U | B | L | E | 0 |
1671         +---------+---+---+---+---+---+---+---+---+
1672                    len                         pad
1673
1674         and the second part, the actual definition of : (COLON), calls CREATE and appends the
1675         DOCOL codeword, so leaving:
1676
1677                                                                 +-- Afterwards, HERE points here.
1678                                                                 |
1679                                                                 V
1680         +---------+---+---+---+---+---+---+---+---+------------+
1681         | LINK    | 6 | D | O | U | B | L | E | 0 | DOCOL      |
1682         +---------+---+---+---+---+---+---+---+---+------------+
1683                    len                         pad  codeword
1684
1685         CREATE is a standard FORTH word and the advantage of this split is that we can reuse it to
1686         create other types of words (not just ones which contain code, but words which contain variables,
1687         constants and other data).
1688 */
1689
1690         defcode "CREATE",6,,CREATE
1691
1692         // Get the word.
1693         call _WORD              // Returns %ecx = length, %edi = pointer to word.
1694         mov %edi,%ebx           // %ebx = address of the word
1695
1696         // Link pointer.
1697         movl var_HERE,%edi      // %edi is the address of the header
1698         movl var_LATEST,%eax    // Get link pointer
1699         stosl                   // and store it in the header.
1700
1701         // Length byte and the word itself.
1702         mov %cl,%al             // Get the length.
1703         stosb                   // Store the length/flags byte.
1704         push %esi
1705         mov %ebx,%esi           // %esi = word
1706         rep movsb               // Copy the word
1707         pop %esi
1708         addl $3,%edi            // Align to next 4 byte boundary.
1709         andl $~3,%edi
1710
1711         // Update LATEST and HERE.
1712         movl var_HERE,%eax
1713         movl %eax,var_LATEST
1714         movl %edi,var_HERE
1715         NEXT
1716
1717 /*
1718         Because I want to define : (COLON) in FORTH, not assembler, we need a few more FORTH words
1719         to use.
1720
1721         The first is , (COMMA) which is a standard FORTH word which appends a 32 bit integer to the user
1722         data area pointed to by HERE, and adds 4 to HERE.  So the action of , (COMMA) is:
1723
1724                                                         previous value of HERE
1725                                                                  |
1726                                                                  V
1727         +---------+---+---+---+---+---+---+---+---+-- - - - - --+------------+
1728         | LINK    | 6 | D | O | U | B | L | E | 0 |             |  <data>    |
1729         +---------+---+---+---+---+---+---+---+---+-- - - - - --+------------+
1730                    len                         pad                            ^
1731                                                                               |
1732                                                                         new value of HERE
1733
1734         and <data> is whatever 32 bit integer was at the top of the stack.
1735
1736         , (COMMA) is quite a fundamental operation when compiling.  It is used to append codewords
1737         to the current word that is being compiled.
1738 */
1739
1740         defcode ",",1,,COMMA
1741         pop %eax                // Code pointer to store.
1742         call _COMMA
1743         NEXT
1744 _COMMA:
1745         movl var_HERE,%edi      // HERE
1746         stosl                   // Store it.
1747         movl %edi,var_HERE      // Update HERE (incremented)
1748         ret
1749
1750 /*
1751         Our definitions of : (COLON) and ; (SEMICOLON) will need to switch to and from compile mode.
1752
1753         Immediate mode vs. compile mode is stored in the global variable STATE, and by updating this
1754         variable we can switch between the two modes.
1755
1756         For various reasons which may become apparent later, FORTH defines two standard words called
1757         [ and ] (LBRAC and RBRAC) which switch between modes:
1758
1759         Word    Assembler       Action          Effect
1760         [       LBRAC           STATE := 0      Switch to immediate mode.
1761         ]       RBRAC           STATE := 1      Switch to compile mode.
1762
1763         [ (LBRAC) is an IMMEDIATE word.  The reason is as follows: If we are in compile mode and the
1764         interpreter saw [ then it would compile it rather than running it.  We would never be able to
1765         switch back to immediate mode!  So we flag the word as IMMEDIATE so that even in compile mode
1766         the word runs immediately, switching us back to immediate mode.
1767 */
1768
1769         defcode "[",1,F_IMMED,LBRAC
1770         xor %eax,%eax
1771         movl %eax,var_STATE     // Set STATE to 0.
1772         NEXT
1773
1774         defcode "]",1,,RBRAC
1775         movl $1,var_STATE       // Set STATE to 1.
1776         NEXT
1777
1778 /*
1779         Now we can define : (COLON) using CREATE.  It just calls CREATE, appends DOCOL (the codeword), sets
1780         the word HIDDEN and goes into compile mode.
1781 */
1782
1783         defword ":",1,,COLON
1784         .int CREATE             // CREATE the dictionary entry / header
1785         .int LIT, DOCOL, COMMA  // Append DOCOL  (the codeword).
1786         .int LATEST, FETCH, HIDDEN // Make the word hidden (see below for definition).
1787         .int RBRAC              // Go into compile mode.
1788         .int EXIT               // Return from the function.
1789
1790 /*
1791         ; (SEMICOLON) is also elegantly simple.  Notice the F_IMMED flag.
1792 */
1793
1794         defword ";",1,F_IMMED,SEMICOLON
1795         .int LIT, EXIT, COMMA   // Append EXIT (so the word will return).
1796         .int LATEST, FETCH, HIDDEN // Toggle hidden flag -- unhide the word (see below for definition).
1797         .int LBRAC              // Go back to IMMEDIATE mode.
1798         .int EXIT               // Return from the function.
1799
1800 /*
1801         EXTENDING THE COMPILER ----------------------------------------------------------------------
1802
1803         Words flagged with IMMEDIATE (F_IMMED) aren't just for the FORTH compiler to use.  You can define
1804         your own IMMEDIATE words too, and this is a crucial aspect when extending basic FORTH, because
1805         it allows you in effect to extend the compiler itself.  Does gcc let you do that?
1806
1807         Standard FORTH words like IF, WHILE, ." and so on are all written as extensions to the basic
1808         compiler, and are all IMMEDIATE words.
1809
1810         The IMMEDIATE word toggles the F_IMMED (IMMEDIATE flag) on the most recently defined word,
1811         or on the current word if you call it in the middle of a definition.
1812
1813         Typical usage is:
1814
1815         : MYIMMEDWORD IMMEDIATE
1816                 ...definition...
1817         ;
1818
1819         but some FORTH programmers write this instead:
1820
1821         : MYIMMEDWORD
1822                 ...definition...
1823         ; IMMEDIATE
1824
1825         The two usages are equivalent, to a first approximation.
1826 */
1827
1828         defcode "IMMEDIATE",9,F_IMMED,IMMEDIATE
1829         movl var_LATEST,%edi    // LATEST word.
1830         addl $4,%edi            // Point to name/flags byte.
1831         xorb $F_IMMED,(%edi)    // Toggle the IMMED bit.
1832         NEXT
1833
1834 /*
1835         'addr HIDDEN' toggles the hidden flag (F_HIDDEN) of the word defined at addr.  To hide the
1836         most recently defined word (used above in : and ; definitions) you would do:
1837
1838                 LATEST @ HIDDEN
1839
1840         Setting this flag stops the word from being found by FIND, and so can be used to make 'private'
1841         words.  For example, to break up a large word into smaller parts you might do:
1842
1843                 : SUB1 ... subword ... ;
1844                 : SUB2 ... subword ... ;
1845                 : SUB3 ... subword ... ;
1846                 : MAIN ... defined in terms of SUB1, SUB2, SUB3 ... ;
1847                 WORD SUB1 FIND HIDDEN           \ Hide SUB1
1848                 WORD SUB2 FIND HIDDEN           \ Hide SUB2
1849                 WORD SUB3 FIND HIDDEN           \ Hide SUB3
1850
1851         After this, only MAIN is 'exported' or seen by the rest of the program.
1852 */
1853
1854         defcode "HIDDEN",6,,HIDDEN
1855         pop %edi                // Dictionary entry.
1856         addl $4,%edi            // Point to name/flags byte.
1857         xorb $F_HIDDEN,(%edi)   // Toggle the HIDDEN bit.
1858         NEXT
1859
1860 /*
1861         ' (TICK) is a standard FORTH word which returns the codeword pointer of the next word.
1862
1863         The common usage is:
1864
1865         ' FOO ,
1866
1867         which appends the codeword of FOO to the current word we are defining (this only works in compiled code).
1868
1869         You tend to use ' in IMMEDIATE words.  For example an alternate (and rather useless) way to define
1870         a literal 2 might be:
1871
1872         : LIT2 IMMEDIATE
1873                 ' LIT ,         \ Appends LIT to the currently-being-defined word
1874                 2 ,             \ Appends the number 2 to the currently-being-defined word
1875         ;
1876
1877         So you could do:
1878
1879         : DOUBLE LIT2 * ;
1880
1881         (If you don't understand how LIT2 works, then you should review the material about compiling words
1882         and immediate mode).
1883
1884         This definition of ' uses a cheat which I copied from buzzard92.  As a result it only works in
1885         compiled code.  It is possible to write a version of ' based on WORD, FIND, >CFA which works in
1886         immediate mode too.
1887 */
1888         defcode "'",1,,TICK
1889         lodsl                   // Get the address of the next word and skip it.
1890         pushl %eax              // Push it on the stack.
1891         NEXT
1892
1893 /*
1894         BRANCHING ----------------------------------------------------------------------
1895
1896         It turns out that all you need in order to define looping constructs, IF-statements, etc.
1897         are two primitives.
1898
1899         BRANCH is an unconditional branch. 0BRANCH is a conditional branch (it only branches if the
1900         top of stack is zero).
1901
1902         The diagram below shows how BRANCH works in some imaginary compiled word.  When BRANCH executes,
1903         %esi starts by pointing to the offset field (compare to LIT above):
1904
1905         +---------------------+-------+---- - - ---+------------+------------+---- - - - ----+------------+
1906         | (Dictionary header) | DOCOL |            | BRANCH     | offset     | (skipped)     | word       |
1907         +---------------------+-------+---- - - ---+------------+-----|------+---- - - - ----+------------+
1908                                                                    ^  |                       ^
1909                                                                    |  |                       |
1910                                                                    |  +-----------------------+
1911                                                                   %esi added to offset
1912
1913         The offset is added to %esi to make the new %esi, and the result is that when NEXT runs, execution
1914         continues at the branch target.  Negative offsets work as expected.
1915
1916         0BRANCH is the same except the branch happens conditionally.
1917
1918         Now standard FORTH words such as IF, THEN, ELSE, WHILE, REPEAT, etc. can be implemented entirely
1919         in FORTH.  They are IMMEDIATE words which append various combinations of BRANCH or 0BRANCH
1920         into the word currently being compiled.
1921
1922         As an example, code written like this:
1923
1924                 condition-code IF true-part THEN rest-code
1925
1926         compiles to:
1927
1928                 condition-code 0BRANCH OFFSET true-part rest-code
1929                                           |             ^
1930                                           |             |
1931                                           +-------------+
1932 */
1933
1934         defcode "BRANCH",6,,BRANCH
1935         add (%esi),%esi         // add the offset to the instruction pointer
1936         NEXT
1937
1938         defcode "0BRANCH",7,,ZBRANCH
1939         pop %eax
1940         test %eax,%eax          // top of stack is zero?
1941         jz code_BRANCH          // if so, jump back to the branch function above
1942         lodsl                   // otherwise we need to skip the offset
1943         NEXT
1944
1945 /*
1946         PRINTING STRINGS ----------------------------------------------------------------------
1947
1948         LITSTRING and EMITSTRING are primitives used to implement the ." and S" operators
1949         (which are written in FORTH).  See the definition of those operators below.
1950 */
1951
1952         defcode "LITSTRING",9,,LITSTRING
1953         lodsl                   // get the length of the string
1954         push %eax               // push it on the stack
1955         push %esi               // push the address of the start of the string
1956         addl %eax,%esi          // skip past the string
1957         addl $3,%esi            // but round up to next 4 byte boundary
1958         andl $~3,%esi
1959         NEXT
1960
1961         defcode "EMITSTRING",10,,EMITSTRING
1962         mov $1,%ebx             // 1st param: stdout
1963         pop %ecx                // 2nd param: address of string
1964         pop %edx                // 3rd param: length of string
1965         mov $__NR_write,%eax    // write syscall
1966         int $0x80
1967         NEXT
1968
1969 /*
1970         COLD START AND INTERPRETER ----------------------------------------------------------------------
1971
1972         COLD is the first FORTH function called, almost immediately after the FORTH system "boots".
1973
1974         INTERPRETER is the FORTH interpreter ("toploop", "toplevel" or "REPL" might be a more accurate
1975         description -- see: http://en.wikipedia.org/wiki/REPL).
1976 */
1977
1978         // COLD must not return (ie. must not call EXIT).
1979         defword "COLD",4,,COLD
1980         .int INTERPRETER        // call the interpreter loop (never returns)
1981         .int LIT,1,SYSEXIT      // hmmm, but in case it does, exit(1).
1982
1983 /* This interpreter is pretty simple, but remember that in FORTH you can always override
1984  * it later with a more powerful one!
1985  */
1986         defword "INTERPRETER",11,,INTERPRETER
1987         .int INTERPRET,RDROP,INTERPRETER
1988
1989         defcode "INTERPRET",9,,INTERPRET
1990         call _WORD              // Returns %ecx = length, %edi = pointer to word.
1991
1992         // Is it in the dictionary?
1993         xor %eax,%eax
1994         movl %eax,interpret_is_lit // Not a literal number (not yet anyway ...)
1995         call _FIND              // Returns %eax = pointer to header or 0 if not found.
1996         test %eax,%eax          // Found?
1997         jz 1f
1998
1999         // In the dictionary.  Is it an IMMEDIATE codeword?
2000         mov %eax,%edi           // %edi = dictionary entry
2001         movb 4(%edi),%al        // Get name+flags.
2002         push %ax                // Just save it for now.
2003         call _TCFA              // Convert dictionary entry (in %edi) to codeword pointer.
2004         pop %ax
2005         andb $F_IMMED,%al       // Is IMMED flag set?
2006         mov %edi,%eax
2007         jnz 4f                  // If IMMED, jump straight to executing.
2008
2009         jmp 2f
2010
2011 1:      // Not in the dictionary (not a word) so assume it's a literal number.
2012         incl interpret_is_lit
2013         call _SNUMBER           // Returns the parsed number in %eax
2014         mov %eax,%ebx
2015         mov $LIT,%eax           // The word is LIT
2016
2017 2:      // Are we compiling or executing?
2018         movl var_STATE,%edx
2019         test %edx,%edx
2020         jz 4f                   // Jump if executing.
2021
2022         // Compiling - just append the word to the current dictionary definition.
2023         call _COMMA
2024         mov interpret_is_lit,%ecx // Was it a literal?
2025         test %ecx,%ecx
2026         jz 3f
2027         mov %ebx,%eax           // Yes, so LIT is followed by a number.
2028         call _COMMA
2029 3:      NEXT
2030
2031 4:      // Executing - run it!
2032         mov interpret_is_lit,%ecx // Literal?
2033         test %ecx,%ecx          // Literal?
2034         jnz 5f
2035
2036         // Not a literal, execute it now.  This never returns, but the codeword will
2037         // eventually call NEXT which will reenter the loop in INTERPRETER.
2038         jmp *(%eax)
2039
2040 5:      // Executing a literal, which means push it on the stack.
2041         push %ebx
2042         NEXT
2043
2044         .data
2045         .align 4
2046 interpret_is_lit:
2047         .int 0                  // Flag used to record if reading a literal
2048
2049 /*
2050         ODDS AND ENDS ----------------------------------------------------------------------
2051
2052         CHAR puts the ASCII code of the first character of the following word on the stack.  For example
2053         CHAR A puts 65 on the stack.
2054
2055         SYSEXIT exits the process using Linux exit syscall.
2056
2057         In this FORTH, SYSEXIT must be the last word in the built-in (assembler) dictionary because we
2058         initialise the LATEST variable to point to it.  This means that if you want to extend the assembler
2059         part, you must put new words before SYSEXIT, or else change how LATEST is initialised.
2060 */
2061
2062         defcode "CHAR",4,,CHAR
2063         call _WORD              // Returns %ecx = length, %edi = pointer to word.
2064         xor %eax,%eax
2065         movb (%edi),%al         // Get the first character of the word.
2066         push %eax               // Push it onto the stack.
2067         NEXT
2068
2069         // NB: SYSEXIT must be the last entry in the built-in dictionary.
2070         defcode SYSEXIT,7,,SYSEXIT
2071         pop %ebx
2072         mov $__NR_exit,%eax
2073         int $0x80
2074
2075 /*
2076         START OF FORTH CODE ----------------------------------------------------------------------
2077
2078         We've now reached the stage where the FORTH system is running and self-hosting.  All further
2079         words can be written as FORTH itself, including words like IF, THEN, .", etc which in most
2080         languages would be considered rather fundamental.
2081
2082         I used to append this here in the assembly file, but I got sick of fighting against gas's
2083         stupid (lack of) multiline string syntax.  So now that is in a separate file called jonesforth.f
2084
2085         If you don't already have that file, download it from http://annexia.org/forth in order
2086         to continue the tutorial.
2087 */
2088
2089 /* END OF jonesforth.S */