1 /* A sometimes minimal FORTH compiler and tutorial for Linux / i386 systems. -*- asm -*-
2 By Richard W.M. Jones <rich@annexia.org> http://annexia.org/forth
3 This is PUBLIC DOMAIN (see public domain release statement below).
4 $Id: jonesforth.S,v 1.26 2007-09-23 23:17:56 rich Exp $
6 gcc -m32 -nostdlib -static -Wl,-Ttext,0 -o jonesforth jonesforth.S
10 INTRODUCTION ----------------------------------------------------------------------
12 FORTH is one of those alien languages which most working programmers regard in the same
13 way as Haskell, LISP, and so on. Something so strange that they'd rather any thoughts
14 of it just go away so they can get on with writing this paying code. But that's wrong
15 and if you care at all about programming then you should at least understand all these
16 languages, even if you will never use them.
18 LISP is the ultimate high-level language, and features from LISP are being added every
19 decade to the more common languages. But FORTH is in some ways the ultimate in low level
20 programming. Out of the box it lacks features like dynamic memory management and even
21 strings. In fact, at its primitive level it lacks even basic concepts like IF-statements
24 Why then would you want to learn FORTH? There are several very good reasons. First
25 and foremost, FORTH is minimal. You really can write a complete FORTH in, say, 2000
26 lines of code. I don't just mean a FORTH program, I mean a complete FORTH operating
27 system, environment and language. You could boot such a FORTH on a bare PC and it would
28 come up with a prompt where you could start doing useful work. The FORTH you have here
29 isn't minimal and uses a Linux process as its 'base PC' (both for the purposes of making
30 it a good tutorial). It's possible to completely understand the system. Who can say they
31 completely understand how Linux works, or gcc?
33 Secondly FORTH has a peculiar bootstrapping property. By that I mean that after writing
34 a little bit of assembly to talk to the hardware and implement a few primitives, all the
35 rest of the language and compiler is written in FORTH itself. Remember I said before
36 that FORTH lacked IF-statements and loops? Well of course it doesn't really because
37 such a lanuage would be useless, but my point was rather that IF-statements and loops are
38 written in FORTH itself.
40 Now of course this is common in other languages as well, and in those languages we call
41 them 'libraries'. For example in C, 'printf' is a library function written in C. But
42 in FORTH this goes way beyond mere libraries. Can you imagine writing C's 'if' in C?
43 And that brings me to my third reason: If you can write 'if' in FORTH, then why restrict
44 yourself to the usual if/while/for/switch constructs? You want a construct that iterates
45 over every other element in a list of numbers? You can add it to the language. What
46 about an operator which pulls in variables directly from a configuration file and makes
47 them available as FORTH variables? Or how about adding Makefile-like dependencies to
48 the language? No problem in FORTH. This concept isn't common in programming languages,
49 but it has a name (in fact two names): "macros" (by which I mean LISP-style macros, not
50 the lame C preprocessor) and "domain specific languages" (DSLs).
52 This tutorial isn't about learning FORTH as the language. I'll point you to some references
53 you should read if you're not familiar with using FORTH. This tutorial is about how to
54 write FORTH. In fact, until you understand how FORTH is written, you'll have only a very
55 superficial understanding of how to use it.
57 So if you're not familiar with FORTH or want to refresh your memory here are some online
60 http://en.wikipedia.org/wiki/Forth_%28programming_language%29
62 http://galileo.phys.virginia.edu/classes/551.jvn.fall01/primer.htm
64 http://wiki.laptop.org/go/Forth_Lessons
66 http://www.albany.net/~hello/simple.htm
68 Here is another "Why FORTH?" essay: http://www.jwdt.com/~paysan/why-forth.html
70 Discussion and criticism of this FORTH here: http://lambda-the-ultimate.org/node/2452
72 ACKNOWLEDGEMENTS ----------------------------------------------------------------------
74 This code draws heavily on the design of LINA FORTH (http://home.hccnet.nl/a.w.m.van.der.horst/lina.html)
75 by Albert van der Horst. Any similarities in the code are probably not accidental.
77 Also I used this document (http://ftp.funet.fi/pub/doc/IOCCC/1992/buzzard.2.design) which really
78 defies easy explanation.
80 PUBLIC DOMAIN ----------------------------------------------------------------------
82 I, the copyright holder of this work, hereby release it into the public domain. This applies worldwide.
84 In case this is not legally possible, I grant any entity the right to use this work for any purpose,
85 without any conditions, unless such conditions are required by law.
87 SETTING UP ----------------------------------------------------------------------
89 Let's get a few housekeeping things out of the way. Firstly because I need to draw lots of
90 ASCII-art diagrams to explain concepts, the best way to look at this is using a window which
91 uses a fixed width font and is at least this wide:
93 <------------------------------------------------------------------------------------------------------------------------>
95 Secondly make sure TABS are set to 8 characters. The following should be a vertical
96 line. If not, sort out your tabs.
102 Thirdly I assume that your screen is at least 50 characters high.
104 ASSEMBLING ----------------------------------------------------------------------
106 If you want to actually run this FORTH, rather than just read it, you will need Linux on an
107 i386. Linux because instead of programming directly to the hardware on a bare PC which I
108 could have done, I went for a simpler tutorial by assuming that the 'hardware' is a Linux
109 process with a few basic system calls (read, write and exit and that's about all). i386
110 is needed because I had to write the assembly for a processor, and i386 is by far the most
111 common. (Of course when I say 'i386', any 32- or 64-bit x86 processor will do. I'm compiling
112 this on a 64 bit AMD Opteron).
114 Again, to assemble this you will need gcc and gas (the GNU assembler). The commands to
115 assemble and run the code (save this file as 'jonesforth.S') are:
117 gcc -m32 -nostdlib -static -Wl,-Ttext,0 -o jonesforth jonesforth.S
120 You will see lots of 'Warning: unterminated string; newline inserted' messages from the
121 assembler. That's just because the GNU assembler doesn't have a good syntax for multi-line
122 strings (or rather it used to, but the developers removed it!) so I've abused the syntax
123 slightly to make things readable. Ignore these warnings.
125 If you want to run your own FORTH programs you can do:
127 ./jonesforth < myprog.f
129 If you want to load your own FORTH code and then continue reading user commands, you can do:
131 cat myfunctions.f - | ./jonesforth
133 ASSEMBLER ----------------------------------------------------------------------
135 (You can just skip to the next section -- you don't need to be able to read assembler to
136 follow this tutorial).
138 However if you do want to read the assembly code here are a few notes about gas (the GNU assembler):
140 (1) Register names are prefixed with '%', so %eax is the 32 bit i386 accumulator. The registers
141 available on i386 are: %eax, %ebx, %ecx, %edx, %esi, %edi, %ebp and %esp, and most of them
142 have special purposes.
144 (2) Add, mov, etc. take arguments in the form SRC,DEST. So mov %eax,%ecx moves %eax -> %ecx
146 (3) Constants are prefixed with '$', and you mustn't forget it! If you forget it then it
147 causes a read from memory instead, so:
148 mov $2,%eax moves number 2 into %eax
149 mov 2,%eax reads the 32 bit word from address 2 into %eax (ie. most likely a mistake)
151 (4) gas has a funky syntax for local labels, where '1f' (etc.) means label '1:' "forwards"
152 and '1b' (etc.) means label '1:' "backwards".
154 (5) 'ja' is "jump if above", 'jb' for "jump if below", 'je' "jump if equal" etc.
156 (6) gas has a reasonably nice .macro syntax, and I use them a lot to make the code shorter and
159 For more help reading the assembler, do "info gas" at the Linux prompt.
161 Now the tutorial starts in earnest.
163 THE DICTIONARY ----------------------------------------------------------------------
165 In FORTH as you will know, functions are called "words", and just as in other languages they
166 have a name and a definition. Here are two FORTH words:
168 : DOUBLE DUP + ; \ name is "DOUBLE", definition is "DUP +"
169 : QUADRUPLE DOUBLE DOUBLE ; \ name is "QUADRUPLE", definition is "DOUBLE DOUBLE"
171 Words, both built-in ones and ones which the programmer defines later, are stored in a dictionary
172 which is just a linked list of dictionary entries.
174 <--- DICTIONARY ENTRY (HEADER) ----------------------->
175 +------------------------+--------+---------- - - - - +----------- - - - -
176 | LINK POINTER | LENGTH/| NAME | DEFINITION
178 +--- (4 bytes) ----------+- byte -+- n bytes - - - - +----------- - - - -
180 I'll come to the definition of the word later. For now just look at the header. The first
181 4 bytes are the link pointer. This points back to the previous word in the dictionary, or, for
182 the first word in the dictionary it is just a NULL pointer. Then comes a length/flags byte.
183 The length of the word can be up to 31 characters (5 bits used) and the top three bits are used
184 for various flags which I'll come to later. This is followed by the name itself, and in this
185 implementation the name is rounded up to a multiple of 4 bytes by padding it with zero bytes.
186 That's just to ensure that the definition starts on a 32 bit boundary.
188 A FORTH variable called LATEST contains a pointer to the most recently defined word, in
189 other words, the head of this linked list.
191 DOUBLE and QUADRUPLE might look like this:
193 pointer to previous word
196 +--|------+---+---+---+---+---+---+---+---+------------- - - - -
197 | LINK | 6 | D | O | U | B | L | E | 0 | (definition ...)
198 +---------+---+---+---+---+---+---+---+---+------------- - - - -
201 +--|------+---+---+---+---+---+---+---+---+---+---+---+---+------------- - - - -
202 | LINK | 9 | Q | U | A | D | R | U | P | L | E | 0 | 0 | (definition ...)
203 +---------+---+---+---+---+---+---+---+---+---+---+---+---+------------- - - - -
209 You should be able to see from this how you might implement functions to find a word in
210 the dictionary (just walk along the dictionary entries starting at LATEST and matching
211 the names until you either find a match or hit the NULL pointer at the end of the dictionary);
212 and add a word to the dictionary (create a new definition, set its LINK to LATEST, and set
213 LATEST to point to the new word). We'll see precisely these functions implemented in
214 assembly code later on.
216 One interesting consequence of using a linked list is that you can redefine words, and
217 a newer definition of a word overrides an older one. This is an important concept in
218 FORTH because it means that any word (even "built-in" or "standard" words) can be
219 overridden with a new definition, either to enhance it, to make it faster or even to
220 disable it. However because of the way that FORTH words get compiled, which you'll
221 understand below, words defined using the old definition of a word continue to use
222 the old definition. Only words defined after the new definition use the new definition.
224 DIRECT THREADED CODE ----------------------------------------------------------------------
226 Now we'll get to the really crucial bit in understanding FORTH, so go and get a cup of tea
227 or coffee and settle down. It's fair to say that if you don't understand this section, then you
228 won't "get" how FORTH works, and that would be a failure on my part for not explaining it well.
229 So if after reading this section a few times you don't understand it, please email me
232 Let's talk first about what "threaded code" means. Imagine a peculiar version of C where
233 you are only allowed to call functions without arguments. (Don't worry for now that such a
234 language would be completely useless!) So in our peculiar C, code would look like this:
243 and so on. How would a function, say 'f' above, be compiled by a standard C compiler?
244 Probably into assembly code like this. On the right hand side I've written the actual
248 CALL a E8 08 00 00 00
249 CALL b E8 1C 00 00 00
250 CALL c E8 2C 00 00 00
251 ; ignore the return from the function for now
253 "E8" is the x86 machine code to "CALL" a function. In the first 20 years of computing
254 memory was hideously expensive and we might have worried about the wasted space being used
255 by the repeated "E8" bytes. We can save 20% in code size (and therefore, in expensive memory)
256 by compressing this into just:
258 08 00 00 00 Just the function addresses, without
259 1C 00 00 00 the CALL prefix.
262 On a 16-bit machine like the ones which originally ran FORTH the savings are even greater - 33%.
264 [Historical note: If the execution model that FORTH uses looks strange from the following
265 paragraphs, then it was motivated entirely by the need to save memory on early computers.
266 This code compression isn't so important now when our machines have more memory in their L1
267 caches than those early computers had in total, but the execution model still has some
270 Of course this code won't run directly any more. Instead we need to write an interpreter
271 which takes each pair of bytes and calls it.
273 On an i386 machine it turns out that we can write this interpreter rather easily, in just
274 two assembly instructions which turn into just 3 bytes of machine code. Let's store the
275 pointer to the next word to execute in the %esi register:
277 08 00 00 00 <- We're executing this one now. %esi is the _next_ one to execute.
281 The all-important i386 instruction is called LODSL (or in Intel manuals, LODSW). It does
282 two things. Firstly it reads the memory at %esi into the accumulator (%eax). Secondly it
283 increments %esi by 4 bytes. So after LODSL, the situation now looks like this:
285 08 00 00 00 <- We're still executing this one
286 1C 00 00 00 <- %eax now contains this address (0x0000001C)
289 Now we just need to jump to the address in %eax. This is again just a single x86 instruction
290 written JMP *(%eax). And after doing the jump, the situation looks like:
293 1C 00 00 00 <- Now we're executing this subroutine.
296 To make this work, each subroutine is followed by the two instructions 'LODSL; JMP *(%eax)'
297 which literally make the jump to the next subroutine.
299 And that brings us to our first piece of actual code! Well, it's a macro.
308 /* The macro is called NEXT. That's a FORTH-ism. It expands to those two instructions.
310 Every FORTH primitive that we write has to be ended by NEXT. Think of it kind of like
313 The above describes what is known as direct threaded code.
315 To sum up: We compress our function calls down to a list of addresses and use a somewhat
316 magical macro to act as a "jump to next function in the list". We also use one register (%esi)
317 to act as a kind of instruction pointer, pointing to the next function in the list.
319 I'll just give you a hint of what is to come by saying that a FORTH definition such as:
321 : QUADRUPLE DOUBLE DOUBLE ;
323 actually compiles (almost, not precisely but we'll see why in a moment) to a list of
324 function addresses for DOUBLE, DOUBLE and a special function called EXIT to finish off.
326 At this point, REALLY EAGLE-EYED ASSEMBLY EXPERTS are saying "JONES, YOU'VE MADE A MISTAKE!".
328 I lied about JMP *(%eax).
330 INDIRECT THREADED CODE ----------------------------------------------------------------------
332 It turns out that direct threaded code is interesting but only if you want to just execute
333 a list of functions written in assembly language. So QUADRUPLE would work only if DOUBLE
334 was an assembly language function. In the direct threaded code, QUADRUPLE would look like:
337 | addr of DOUBLE --------------------> (assembly code to do the double)
338 +------------------+ NEXT
339 %esi -> | addr of DOUBLE |
342 We can add an extra indirection to allow us to run both words written in assembly language
343 (primitives written for speed) and words written in FORTH themselves as lists of addresses.
345 The extra indirection is the reason for the brackets in JMP *(%eax).
347 Let's have a look at how QUADRUPLE and DOUBLE really look in FORTH:
349 : QUADRUPLE DOUBLE DOUBLE ;
352 | codeword | : DOUBLE DUP + ;
354 | addr of DOUBLE ---------------> +------------------+
355 +------------------+ | codeword |
356 | addr of DOUBLE | +------------------+
357 +------------------+ | addr of DUP --------------> +------------------+
358 | addr of EXIT | +------------------+ | codeword -------+
359 +------------------+ %esi -> | addr of + --------+ +------------------+ |
360 +------------------+ | | assembly to <-----+
361 | addr of EXIT | | | implement DUP |
362 +------------------+ | | .. |
365 | +------------------+
367 +-----> +------------------+
369 +------------------+ |
370 | assembly to <------+
377 This is the part where you may need an extra cup of tea/coffee/favourite caffeinated
378 beverage. What has changed is that I've added an extra pointer to the beginning of
379 the definitions. In FORTH this is sometimes called the "codeword". The codeword is
380 a pointer to the interpreter to run the function. For primitives written in
381 assembly language, the "interpreter" just points to the actual assembly code itself.
382 They don't need interpreting, they just run.
384 In words written in FORTH (like QUADRUPLE and DOUBLE), the codeword points to an interpreter
387 I'll show you the interpreter function shortly, but let's recall our indirect
388 JMP *(%eax) with the "extra" brackets. Take the case where we're executing DOUBLE
389 as shown, and DUP has been called. Note that %esi is pointing to the address of +
391 The assembly code for DUP eventually does a NEXT. That:
393 (1) reads the address of + into %eax %eax points to the codeword of +
394 (2) increments %esi by 4
395 (3) jumps to the indirect %eax jumps to the address in the codeword of +,
396 ie. the assembly code to implement +
401 | addr of DOUBLE ---------------> +------------------+
402 +------------------+ | codeword |
403 | addr of DOUBLE | +------------------+
404 +------------------+ | addr of DUP --------------> +------------------+
405 | addr of EXIT | +------------------+ | codeword -------+
406 +------------------+ | addr of + --------+ +------------------+ |
407 +------------------+ | | assembly to <-----+
408 %esi -> | addr of EXIT | | | implement DUP |
409 +------------------+ | | .. |
412 | +------------------+
414 +-----> +------------------+
416 +------------------+ |
417 now we're | assembly to <-----+
418 executing | implement + |
424 So I hope that I've convinced you that NEXT does roughly what you'd expect. This is
425 indirect threaded code.
427 I've glossed over four things. I wonder if you can guess without reading on what they are?
433 My list of four things are: (1) What does "EXIT" do? (2) which is related to (1) is how do
434 you call into a function, ie. how does %esi start off pointing at part of QUADRUPLE, but
435 then point at part of DOUBLE. (3) What goes in the codeword for the words which are written
436 in FORTH? (4) How do you compile a function which does anything except call other functions
437 ie. a function which contains a number like : DOUBLE 2 * ; ?
439 THE INTERPRETER AND RETURN STACK ------------------------------------------------------------
441 Going at these in no particular order, let's talk about issues (3) and (2), the interpreter
442 and the return stack.
444 Words which are defined in FORTH need a codeword which points to a little bit of code to
445 give them a "helping hand" in life. They don't need much, but they do need what is known
446 as an "interpreter", although it doesn't really "interpret" in the same way that, say,
447 Java bytecode used to be interpreted (ie. slowly). This interpreter just sets up a few
448 machine registers so that the word can then execute at full speed using the indirect
449 threaded model above.
451 One of the things that needs to happen when QUADRUPLE calls DOUBLE is that we save the old
452 %esi ("instruction pointer") and create a new one pointing to the first word in DOUBLE.
453 Because we will need to restore the old %esi at the end of DOUBLE (this is, after all, like
454 a function call), we will need a stack to store these "return addresses" (old values of %esi).
456 As you will have read, when reading the background documentation, FORTH has two stacks,
457 an ordinary stack for parameters, and a return stack which is a bit more mysterious. But
458 our return stack is just the stack I talked about in the previous paragraph, used to save
459 %esi when calling from a FORTH word into another FORTH word.
461 In this FORTH, we are using the normal stack pointer (%esp) for the parameter stack.
462 We will use the i386's "other" stack pointer (%ebp, usually called the "frame pointer")
463 for our return stack.
465 I've got two macros which just wrap up the details of using %ebp for the return stack.
466 You use them as for example "PUSHRSP %eax" (push %eax on the return stack) or "POPRSP %ebx"
467 (pop top of return stack into %ebx).
470 /* Macros to deal with the return stack. */
472 lea -4(%ebp),%ebp // push reg on to return stack
477 mov (%ebp),\reg // pop top of return stack to reg
482 And with that we can now talk about the interpreter.
484 In FORTH the interpreter function is often called DOCOL (I think it means "DO COLON" because
485 all FORTH definitions start with a colon, as in : DOUBLE DUP + ;
487 The "interpreter" (it's not really "interpreting") just needs to push the old %esi on the
488 stack and set %esi to the first word in the definition. Remember that we jumped to the
489 function using JMP *(%eax)? Well a consequence of that is that conveniently %eax contains
490 the address of this codeword, so just by adding 4 to it we get the address of the first
491 data word. Finally after setting up %esi, it just does NEXT which causes that first word
495 /* DOCOL - the interpreter! */
499 PUSHRSP %esi // push %esi on to the return stack
500 addl $4,%eax // %eax points to codeword, so make
501 movl %eax,%esi // %esi point to first data word
505 Just to make this absolutely clear, let's see how DOCOL works when jumping from QUADRUPLE
511 +------------------+ DOUBLE:
512 | addr of DOUBLE ---------------> +------------------+
513 +------------------+ %eax -> | addr of DOCOL |
514 %esi -> | addr of DOUBLE | +------------------+
515 +------------------+ | addr of DUP |
516 | addr of EXIT | +------------------+
517 +------------------+ | etc. |
519 First, the call to DOUBLE calls DOCOL (the codeword of DOUBLE). DOCOL does this: It
520 pushes the old %esi on the return stack. %eax points to the codeword of DOUBLE, so we
521 just add 4 on to it to get our new %esi:
526 +------------------+ DOUBLE:
527 | addr of DOUBLE ---------------> +------------------+
528 top of return +------------------+ %eax -> | addr of DOCOL |
529 stack points -> | addr of DOUBLE | + 4 = +------------------+
530 +------------------+ %esi -> | addr of DUP |
531 | addr of EXIT | +------------------+
532 +------------------+ | etc. |
534 Then we do NEXT, and because of the magic of threaded code that increments %esi again
537 Well, it seems to work.
539 One minor point here. Because DOCOL is the first bit of assembly actually to be defined
540 in this file (the others were just macros), and because I usually compile this code with the
541 text segment starting at address 0, DOCOL has address 0. So if you are disassembling the
542 code and see a word with a codeword of 0, you will immediately know that the word is
543 written in FORTH (it's not an assembler primitive) and so uses DOCOL as the interpreter.
545 STARTING UP ----------------------------------------------------------------------
547 Now let's get down to nuts and bolts. When we start the program we need to set up
548 a few things like the return stack. But as soon as we can, we want to jump into FORTH
549 code (albeit much of the "early" FORTH code will still need to be written as
550 assembly language primitives).
552 This is what the set up code does. Does a tiny bit of house-keeping, sets up the
553 separate return stack (NB: Linux gives us the ordinary parameter stack already), then
554 immediately jumps to a FORTH word called COLD. COLD stands for cold-start. In ISO
555 FORTH (but not in this FORTH), COLD can be called at any time to completely reset
556 the state of FORTH, and there is another word called WARM which does a partial reset.
559 /* ELF entry point. */
564 mov %esp,var_S0 // Store the initial data stack pointer.
565 mov $return_stack,%ebp // Initialise the return stack.
567 mov $cold_start,%esi // Initialise interpreter.
568 NEXT // Run interpreter!
571 cold_start: // High-level code without a codeword.
575 We also allocate some space for the return stack and some space to store user
576 definitions. These are static memory allocations using fixed-size buffers, but it
577 wouldn't be a great deal of work to make them dynamic.
581 /* FORTH return stack. */
582 .set RETURN_STACK_SIZE,8192
584 .space RETURN_STACK_SIZE
585 return_stack: // Initial top of return stack.
587 /* The user definitions area: space for user-defined words and general memory allocations. */
588 .set USER_DEFS_SIZE,65536
591 .space USER_DEFS_SIZE
594 BUILT-IN WORDS ----------------------------------------------------------------------
596 Remember our dictionary entries (headers). Let's bring those together with the codeword
597 and data words to see how : DOUBLE DUP + ; really looks in memory.
599 pointer to previous word
602 +--|------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
603 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + | EXIT |
604 +---------+---+---+---+---+---+---+---+---+------------+--|---------+------------+------------+
607 LINK in next word points to codeword of DUP
609 Initially we can't just write ": DOUBLE DUP + ;" (ie. that literal string) here because we
610 don't yet have anything to read the string, break it up at spaces, parse each word, etc. etc.
611 So instead we will have to define built-in words using the GNU assembler data constructors
612 (like .int, .byte, .string, .ascii and so on -- look them up in the gas info page if you are
615 The long way would be:
616 .int <link to previous word>
618 .ascii "DOUBLE" // string
620 DOUBLE: .int DOCOL // codeword
621 .int DUP // pointer to codeword of DUP
622 .int PLUS // pointer to codeword of +
623 .int EXIT // pointer to codeword of EXIT
625 That's going to get quite tedious rather quickly, so here I define an assembler macro
626 so that I can just write:
628 defword "DOUBLE",6,,DOUBLE
631 and I'll get exactly the same effect.
633 Don't worry too much about the exact implementation details of this macro - it's complicated!
636 /* Flags - these are discussed later. */
639 .set F_LENMASK,0x1f // length mask
641 // Store the chain of links.
644 .macro defword name, namelen, flags=0, label
650 .set link,name_\label
651 .byte \flags+\namelen // flags + length byte
652 .ascii "\name" // the name
656 .int DOCOL // codeword - the interpreter
657 // list of word pointers follow
661 Similarly I want a way to write words written in assembly language. There will quite a few
662 of these to start with because, well, everything has to start in assembly before there's
663 enough "infrastructure" to be able to start writing FORTH words, but also I want to define
664 some common FORTH words in assembly language for speed, even though I could write them in FORTH.
666 This is what DUP looks like in memory:
668 pointer to previous word
671 +--|------+---+---+---+---+------------+
672 | LINK | 3 | D | U | P | code_DUP ---------------------> points to the assembly
673 +---------+---+---+---+---+------------+ code used to write DUP,
674 ^ len codeword which ends with NEXT.
678 Again, for brevity in writing the header I'm going to write an assembler macro called defcode.
681 .macro defcode name, namelen, flags=0, label
687 .set link,name_\label
688 .byte \flags+\namelen // flags + length byte
689 .ascii "\name" // the name
693 .int code_\label // codeword
697 code_\label : // assembler code follows
701 Now some easy FORTH primitives. These are written in assembly for speed. If you understand
702 i386 assembly language then it is worth reading these. However if you don't understand assembly
703 you can skip the details.
707 pop %eax // duplicate top of stack
712 defcode "DROP",4,,DROP
713 pop %eax // drop top of stack
716 defcode "SWAP",4,,SWAP
717 pop %eax // swap top of stack
723 defcode "OVER",4,,OVER
724 mov 4(%esp),%eax // get the second element of stack
725 push %eax // and push it on top
737 defcode "-ROT",4,,NROT
747 incl (%esp) // increment top of stack
751 decl (%esp) // decrement top of stack
754 defcode "4+",2,,INCR4
755 addl $4,(%esp) // add 4 to top of stack
758 defcode "4-",2,,DECR4
759 subl $4,(%esp) // subtract 4 from top of stack
763 pop %eax // get top of stack
764 addl %eax,(%esp) // and add it to next word on stack
768 pop %eax // get top of stack
769 subl %eax,(%esp) // and subtract it from next word on stack
776 push %eax // ignore overflow
784 push %eax // push quotient
792 push %edx // push remainder
795 defcode "=",1,,EQU // top two words are equal?
805 defcode "<>",2,,NEQU // top two words are not equal?
855 defcode "0=",2,,ZEQU // top of stack equals 0?
864 defcode "0<>",3,,ZNEQU // top of stack not 0?
924 defcode "INVERT",6,,INVERT // this is the FORTH bitwise "NOT" function
929 RETURNING FROM FORTH WORDS ----------------------------------------------------------------------
931 Time to talk about what happens when we EXIT a function. In this diagram QUADRUPLE has called
932 DOUBLE, and DOUBLE is about to exit (look at where %esi is pointing):
937 +------------------+ DOUBLE
938 | addr of DOUBLE ---------------> +------------------+
939 +------------------+ | codeword |
940 | addr of DOUBLE | +------------------+
941 +------------------+ | addr of DUP |
942 | addr of EXIT | +------------------+
943 +------------------+ | addr of + |
945 %esi -> | addr of EXIT |
948 What happens when the + function does NEXT? Well, the following code is executed.
951 defcode "EXIT",4,,EXIT
952 POPRSP %esi // pop return stack into %esi
956 EXIT gets the old %esi which we saved from before on the return stack, and puts it in %esi.
957 So after this (but just before NEXT) we get:
962 +------------------+ DOUBLE
963 | addr of DOUBLE ---------------> +------------------+
964 +------------------+ | codeword |
965 %esi -> | addr of DOUBLE | +------------------+
966 +------------------+ | addr of DUP |
967 | addr of EXIT | +------------------+
968 +------------------+ | addr of + |
973 And NEXT just completes the job by, well in this case just by calling DOUBLE again :-)
975 LITERALS ----------------------------------------------------------------------
977 The final point I "glossed over" before was how to deal with functions that do anything
978 apart from calling other functions. For example, suppose that DOUBLE was defined like this:
982 It does the same thing, but how do we compile it since it contains the literal 2? One way
983 would be to have a function called "2" (which you'd have to write in assembler), but you'd need
984 a function for every single literal that you wanted to use.
986 FORTH solves this by compiling the function using a special word called LIT:
988 +---------------------------+-------+-------+-------+-------+-------+
989 | (usual header of DOUBLE) | DOCOL | LIT | 2 | * | EXIT |
990 +---------------------------+-------+-------+-------+-------+-------+
992 LIT is executed in the normal way, but what it does next is definitely not normal. It
993 looks at %esi (which now points to the literal 2), grabs it, pushes it on the stack, then
994 manipulates %esi in order to skip the literal as if it had never been there.
996 What's neat is that the whole grab/manipulate can be done using a single byte single
997 i386 instruction, our old friend LODSL. Rather than me drawing more ASCII-art diagrams,
998 see if you can find out how LIT works:
1001 defcode "LIT",3,,LIT
1002 // %esi points to the next command, but in this case it points to the next
1003 // literal 32 bit integer. Get that literal into %eax and increment %esi.
1004 // On x86, it's a convenient single byte instruction! (cf. NEXT macro)
1006 push %eax // push the literal number on to stack
1010 MEMORY ----------------------------------------------------------------------
1012 As important point about FORTH is that it gives you direct access to the lowest levels
1013 of the machine. Manipulating memory directly is done frequently in FORTH, and these are
1014 the primitive words for doing it.
1017 defcode "!",1,,STORE
1018 pop %ebx // address to store at
1019 pop %eax // data to store there
1020 mov %eax,(%ebx) // store it
1023 defcode "@",1,,FETCH
1024 pop %ebx // address to fetch
1025 mov (%ebx),%eax // fetch it
1026 push %eax // push value onto stack
1029 defcode "+!",2,,ADDSTORE
1031 pop %eax // the amount to add
1032 addl %eax,(%ebx) // add it
1035 defcode "-!",2,,SUBSTORE
1037 pop %eax // the amount to subtract
1038 subl %eax,(%ebx) // add it
1041 /* ! and @ (STORE and FETCH) store 32-bit words. It's also useful to be able to read and write bytes.
1042 * I don't know whether FORTH has these words, so I invented my own, called !b and @b.
1043 * Byte-oriented operations only work on architectures which permit them (i386 is one of those).
1044 * UPDATE: writing a byte to the dictionary pointer is called C, in FORTH.
1046 defcode "!b",2,,STOREBYTE
1047 pop %ebx // address to store at
1048 pop %eax // data to store there
1049 movb %al,(%ebx) // store it
1052 defcode "@b",2,,FETCHBYTE
1053 pop %ebx // address to fetch
1055 movb (%ebx),%al // fetch it
1056 push %eax // push value onto stack
1060 BUILT-IN VARIABLES ----------------------------------------------------------------------
1062 These are some built-in variables and related standard FORTH words. Of these, the only one that we
1063 have discussed so far was LATEST, which points to the last (most recently defined) word in the
1064 FORTH dictionary. LATEST is also a FORTH word which pushes the address of LATEST (the variable)
1065 on to the stack, so you can read or write it using @ and ! operators. For example, to print
1066 the current value of LATEST (and this can apply to any FORTH variable) you would do:
1070 To make defining variables shorter, I'm using a macro called defvar, similar to defword and
1071 defcode above. (In fact the defvar macro uses defcode to do the dictionary header).
1074 .macro defvar name, namelen, flags=0, label, initial=0
1075 defcode \name,\namelen,\flags,\label
1085 The built-in variables are:
1087 STATE Is the interpreter executing code (0) or compiling a word (non-zero)?
1088 LATEST Points to the latest (most recently defined) word in the dictionary.
1089 HERE Points to the next free byte of memory. When compiling, compiled words go here.
1090 _X These are three scratch variables, used by some standard dictionary words.
1093 S0 Stores the address of the top of the parameter stack.
1094 BASE The current base for printing and reading numbers.
1097 defvar "STATE",5,,STATE
1098 defvar "HERE",4,,HERE,user_defs_start
1099 defvar "LATEST",6,,LATEST,name_SYSEXIT // SYSEXIT must be last in built-in dictionary
1104 defvar "BASE",4,,BASE,10
1107 BUILT-IN CONSTANTS ----------------------------------------------------------------------
1109 It's also useful to expose a few constants to FORTH. When the word is executed it pushes a
1110 constant value on the stack.
1112 The built-in constants are:
1114 VERSION Is the current version of this FORTH.
1115 R0 The address of the top of the return stack.
1116 DOCOL Pointer to DOCOL.
1117 F_IMMED The IMMEDIATE flag's actual value.
1118 F_HIDDEN The HIDDEN flag's actual value.
1119 F_LENMASK The length mask.
1122 .macro defconst name, namelen, flags=0, label, value
1123 defcode \name,\namelen,\flags,\label
1128 defconst "VERSION",7,,VERSION,JONES_VERSION
1129 defconst "R0",2,,RZ,return_stack
1130 defconst "DOCOL",5,,__DOCOL,DOCOL
1131 defconst "F_IMMED",7,,__F_IMMED,F_IMMED
1132 defconst "F_HIDDEN",8,,__F_HIDDEN,F_HIDDEN
1133 defconst "F_LENMASK",9,,__F_LENMASK,F_LENMASK
1136 RETURN STACK ----------------------------------------------------------------------
1138 These words allow you to access the return stack. Recall that the register %ebp always points to
1139 the top of the return stack.
1143 pop %eax // pop parameter stack into %eax
1144 PUSHRSP %eax // push it on to the return stack
1147 defcode "R>",2,,FROMR
1148 POPRSP %eax // pop return stack on to %eax
1149 push %eax // and push on to parameter stack
1152 defcode "RSP@",4,,RSPFETCH
1156 defcode "RSP!",4,,RSPSTORE
1160 defcode "RDROP",5,,RDROP
1161 lea 4(%ebp),%ebp // pop return stack and throw away
1165 PARAMETER (DATA) STACK ----------------------------------------------------------------------
1167 These functions allow you to manipulate the parameter stack. Recall that Linux sets up the parameter
1168 stack for us, and it is accessed through %esp.
1171 defcode "DSP@",4,,DSPFETCH
1176 defcode "DSP!",4,,DSPSTORE
1181 INPUT AND OUTPUT ----------------------------------------------------------------------
1183 These are our first really meaty/complicated FORTH primitives. I have chosen to write them in
1184 assembler, but surprisingly in "real" FORTH implementations these are often written in terms
1185 of more fundamental FORTH primitives. I chose to avoid that because I think that just obscures
1186 the implementation. After all, you may not understand assembler but you can just think of it
1187 as an opaque block of code that does what it says.
1189 Let's discuss input first.
1191 The FORTH word KEY reads the next byte from stdin (and pushes it on the parameter stack).
1192 So if KEY is called and someone hits the space key, then the number 32 (ASCII code of space)
1193 is pushed on the stack.
1195 In FORTH there is no distinction between reading code and reading input. We might be reading
1196 and compiling code, we might be reading words to execute, we might be asking for the user
1197 to type their name -- ultimately it all comes in through KEY.
1199 The implementation of KEY uses an input buffer of a certain size (defined at the end of the
1200 program). It calls the Linux read(2) system call to fill this buffer and tracks its position
1201 in the buffer using a couple of variables, and if it runs out of input buffer then it refills
1202 it automatically. The other thing that KEY does is if it detects that stdin has closed, it
1203 exits the program, which is why when you hit ^D the FORTH system cleanly exits.
1206 #include <asm-i386/unistd.h>
1208 defcode "KEY",3,,KEY
1210 push %eax // push return value on stack
1222 1: // out of input; use read(2) to fetch more input from stdin
1223 xor %ebx,%ebx // 1st param: stdin
1224 mov $buffer,%ecx // 2nd param: buffer
1226 mov $buffend-buffer,%edx // 3rd param: max length
1227 mov $__NR_read,%eax // syscall: read
1229 test %eax,%eax // If %eax <= 0, then exit.
1231 addl %eax,%ecx // buffer+%eax = bufftop
1235 2: // error or out of input: exit
1237 mov $__NR_exit,%eax // syscall: exit
1241 By contrast, output is much simpler. The FORTH word EMIT writes out a single byte to stdout.
1242 This implementation just uses the write system call. No attempt is made to buffer output, but
1243 it would be a good exercise to add it.
1246 defcode "EMIT",4,,EMIT
1251 mov $1,%ebx // 1st param: stdout
1253 // write needs the address of the byte to write
1255 mov $2f,%ecx // 2nd param: address
1257 mov $1,%edx // 3rd param: nbytes = 1
1259 mov $__NR_write,%eax // write syscall
1264 2: .space 1 // scratch used by EMIT
1267 Back to input, WORD is a FORTH word which reads the next full word of input.
1269 What it does in detail is that it first skips any blanks (spaces, tabs, newlines and so on).
1270 Then it calls KEY to read characters into an internal buffer until it hits a blank. Then it
1271 calculates the length of the word it read and returns the address and the length as
1272 two words on the stack (with address at the top).
1274 Notice that WORD has a single internal buffer which it overwrites each time (rather like
1275 a static C string). Also notice that WORD's internal buffer is just 32 bytes long and
1276 there is NO checking for overflow. 31 bytes happens to be the maximum length of a
1277 FORTH word that we support, and that is what WORD is used for: to read FORTH words when
1278 we are compiling and executing code. The returned strings are not NUL-terminated, so
1279 in some crazy-world you could define FORTH words containing ASCII NULs, although why
1280 you'd want to is a bit beyond me.
1282 WORD is not suitable for just reading strings (eg. user input) because of all the above
1283 peculiarities and limitations.
1285 Note that when executing, you'll see:
1287 which puts "FOO" and length 3 on the stack, but when compiling:
1289 is an error (or at least it doesn't do what you might expect). Later we'll talk about compiling
1290 and immediate mode, and you'll understand why.
1293 defcode "WORD",4,,WORD
1295 push %ecx // push length
1296 push %edi // push base address
1300 /* Search for first non-blank character. Also skip \ comments. */
1302 call _KEY // get next key, returned in %eax
1303 cmpb $'\\',%al // start of a comment?
1304 je 3f // if so, skip the comment
1306 jbe 1b // if so, keep looking
1308 /* Search for the end of the word, storing chars as we go. */
1309 mov $5f,%edi // pointer to return buffer
1311 stosb // add character to return buffer
1312 call _KEY // get next key, returned in %al
1313 cmpb $' ',%al // is blank?
1314 ja 2b // if not, keep looping
1316 /* Return the word (well, the static buffer) and length. */
1318 mov %edi,%ecx // return length of the word
1319 mov $5f,%edi // return address of the word
1322 /* Code to skip \ comments to end of the current line. */
1325 cmpb $'\n',%al // end of line yet?
1330 // A static buffer where WORD returns. Subsequent calls
1331 // overwrite this buffer. Maximum word length is 32 chars.
1335 . (also called DOT) prints the top of the stack as an integer in the current BASE.
1339 pop %eax // Get the number to print into %eax
1340 call _DOT // Easier to do this recursively ...
1343 mov var_BASE,%ecx // Get current BASE
1345 cmp %ecx,%eax // %eax < BASE? If so jump to print immediately.
1347 xor %edx,%edx // %edx:%eax / %ecx -> quotient %eax, remainder %edx
1349 pushl %edx // Print quotient (top half) first ...
1351 popl %eax // ... then loop to print remainder
1353 2: // %eax < BASE so print immediately.
1356 movb (%edx),%al // Note top bits are already zero.
1360 digits: .ascii "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1363 Almost the opposite of DOT (but not quite), SNUMBER parses a numeric string such as one returned
1364 by WORD and pushes the number on the parameter stack.
1366 This function does absolutely no error checking, and in particular the length of the string
1367 must be >= 1 bytes, and should contain only digits 0-9. If it doesn't you'll get random results.
1369 This function is only used when reading literal numbers in code, and shouldn't really be used
1370 in user code at all.
1372 defcode "SNUMBER",7,,SNUMBER
1382 imull $10,%eax // %eax *= 10
1385 subb $'0',%bl // ASCII -> digit
1392 DICTIONARY LOOK UPS ----------------------------------------------------------------------
1394 We're building up to our prelude on how FORTH code is compiled, but first we need yet more infrastructure.
1396 The FORTH word FIND takes a string (a word as parsed by WORD -- see above) and looks it up in the
1397 dictionary. What it actually returns is the address of the dictionary header, if it finds it,
1400 So if DOUBLE is defined in the dictionary, then WORD DOUBLE FIND returns the following pointer:
1406 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1407 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + | EXIT |
1408 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1410 See also >CFA and >DFA.
1412 FIND doesn't find dictionary entries which are flagged as HIDDEN. See below for why.
1415 defcode "FIND",4,,FIND
1416 pop %edi // %edi = address
1417 pop %ecx // %ecx = length
1423 push %esi // Save %esi so we can use it in string comparison.
1425 // Now we start searching backwards through the dictionary for this word.
1426 mov var_LATEST,%edx // LATEST points to name header of the latest word in the dictionary
1428 test %edx,%edx // NULL pointer? (end of the linked list)
1431 // Compare the length expected and the length of the word.
1432 // Note that if the F_HIDDEN flag is set on the word, then by a bit of trickery
1433 // this won't pick the word (the length will appear to be wrong).
1435 movb 4(%edx),%al // %al = flags+length field
1436 andb $(F_HIDDEN|F_LENMASK),%al // %al = name length
1437 cmpb %cl,%al // Length is the same?
1440 // Compare the strings in detail.
1441 push %ecx // Save the length
1442 push %edi // Save the address (repe cmpsb will move this pointer)
1443 lea 5(%edx),%esi // Dictionary string we are checking against.
1444 repe cmpsb // Compare the strings.
1447 jne 2f // Not the same.
1449 // The strings are the same - return the header pointer in %eax
1455 mov (%edx),%edx // Move back through the link field to the previous word
1456 jmp 1b // .. and loop.
1460 xor %eax,%eax // Return zero to indicate not found.
1464 FIND returns the dictionary pointer, but when compiling we need the codeword pointer (recall
1465 that FORTH definitions are compiled into lists of codeword pointers). The standard FORTH
1466 word >CFA turns a dictionary pointer into a codeword pointer.
1468 The example below shows the result of:
1470 WORD DOUBLE FIND >CFA
1472 FIND returns a pointer to this
1473 | >CFA converts it to a pointer to this
1476 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1477 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + | EXIT |
1478 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1482 Because names vary in length, this isn't just a simple increment.
1484 In this FORTH you cannot easily turn a codeword pointer back into a dictionary entry pointer, but
1485 that is not true in most FORTH implementations where they store a back pointer in the definition
1486 (with an obvious memory/complexity cost). The reason they do this is that it is useful to be
1487 able to go backwards (codeword -> dictionary entry) in order to decompile FORTH definitions.
1489 What does CFA stand for? My best guess is "Code Field Address".
1492 defcode ">CFA",4,,TCFA
1499 add $4,%edi // Skip link pointer.
1500 movb (%edi),%al // Load flags+len into %al.
1501 inc %edi // Skip flags+len byte.
1502 andb $F_LENMASK,%al // Just the length, not the flags.
1503 add %eax,%edi // Skip the name.
1504 addl $3,%edi // The codeword is 4-byte aligned.
1509 Related to >CFA is >DFA which takes a dictionary entry address as returned by FIND and
1510 returns a pointer to the first data field.
1512 FIND returns a pointer to this
1513 | >CFA converts it to a pointer to this
1515 | | >DFA converts it to a pointer to this
1518 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1519 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + | EXIT |
1520 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1522 (Note to those following the source of FIG-FORTH / ciforth: My >DFA definition is
1523 different from theirs, because they have an extra indirection).
1525 You can see that >DFA is easily defined in FORTH just by adding 4 to the result of >CFA.
1528 defword ">DFA",4,,TDFA
1529 .int TCFA // >CFA (get code field address)
1530 .int INCR4 // 4+ (add 4 to it to get to next word)
1531 .int EXIT // EXIT (return from FORTH word)
1534 COMPILING ----------------------------------------------------------------------
1536 Now we'll talk about how FORTH compiles words. Recall that a word definition looks like this:
1540 and we have to turn this into:
1542 pointer to previous word
1545 +--|------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1546 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + | EXIT |
1547 +---------+---+---+---+---+---+---+---+---+------------+--|---------+------------+------------+
1548 ^ len pad codeword |
1550 LATEST points here points to codeword of DUP
1552 There are several problems to solve. Where to put the new word? How do we read words? How
1553 do we define the words : (COLON) and ; (SEMICOLON)?
1555 FORTH solves this rather elegantly and as you might expect in a very low-level way which
1556 allows you to change how the compiler works on your own code.
1558 FORTH has an INTERPRETER function (a true interpreter this time, not DOCOL) which runs in a
1559 loop, reading words (using WORD), looking them up (using FIND), turning them into codeword
1560 pointers (using >CFA) and deciding what to do with them.
1562 What it does depends on the mode of the interpreter (in variable STATE).
1564 When STATE is zero, the interpreter just runs each word as it looks them up. This is known as
1567 The interesting stuff happens when STATE is non-zero -- compiling mode. In this mode the
1568 interpreter appends the codeword pointer to user memory (the HERE variable points to the next
1569 free byte of user memory).
1571 So you may be able to see how we could define : (COLON). The general plan is:
1573 (1) Use WORD to read the name of the function being defined.
1575 (2) Construct the dictionary entry -- just the header part -- in user memory:
1577 pointer to previous word (from LATEST) +-- Afterwards, HERE points here, where
1578 ^ | the interpreter will start appending
1580 +--|------+---+---+---+---+---+---+---+---+------------+
1581 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL |
1582 +---------+---+---+---+---+---+---+---+---+------------+
1585 (3) Set LATEST to point to the newly defined word, ...
1587 (4) .. and most importantly leave HERE pointing just after the new codeword. This is where
1588 the interpreter will append codewords.
1590 (5) Set STATE to 1. This goes into compile mode so the interpreter starts appending codewords to
1591 our partially-formed header.
1593 After : has run, our input is here:
1598 Next byte returned by KEY will be the 'D' character of DUP
1600 so the interpreter (now it's in compile mode, so I guess it's really the compiler) reads "DUP",
1601 looks it up in the dictionary, gets its codeword pointer, and appends it:
1603 +-- HERE updated to point here.
1606 +---------+---+---+---+---+---+---+---+---+------------+------------+
1607 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP |
1608 +---------+---+---+---+---+---+---+---+---+------------+------------+
1611 Next we read +, get the codeword pointer, and append it:
1613 +-- HERE updated to point here.
1616 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+
1617 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + |
1618 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+
1621 The issue is what happens next. Obviously what we _don't_ want to happen is that we
1622 read ";" and compile it and go on compiling everything afterwards.
1624 At this point, FORTH uses a trick. Remember the length byte in the dictionary definition
1625 isn't just a plain length byte, but can also contain flags. One flag is called the
1626 IMMEDIATE flag (F_IMMED in this code). If a word in the dictionary is flagged as
1627 IMMEDIATE then the interpreter runs it immediately _even if it's in compile mode_.
1629 This is how the word ; (SEMICOLON) works -- as a word flagged in the dictionary as IMMEDIATE.
1630 And all it does is append the codeword for EXIT on to the current definition and switch
1631 back to immediate mode (set STATE back to 0). Shortly we'll see the actual definition
1632 of ; and we'll see that it's really a very simple definition, declared IMMEDIATE.
1634 After the interpreter reads ; and executes it 'immediately', we get this:
1636 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1637 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL | DUP | + | EXIT |
1638 +---------+---+---+---+---+---+---+---+---+------------+------------+------------+------------+
1645 And that's it, job done, our new definition is compiled, and we're back in immediate mode
1646 just reading and executing words, perhaps including a call to test our new word DOUBLE.
1648 The only last wrinkle in this is that while our word was being compiled, it was in a
1649 half-finished state. We certainly wouldn't want DOUBLE to be called somehow during
1650 this time. There are several ways to stop this from happening, but in FORTH what we
1651 do is flag the word with the HIDDEN flag (F_HIDDEN in this code) just while it is
1652 being compiled. This prevents FIND from finding it, and thus in theory stops any
1653 chance of it being called.
1655 The above explains how compiling, : (COLON) and ; (SEMICOLON) works and in a moment I'm
1656 going to define them. The : (COLON) function can be made a little bit more general by writing
1657 it in two parts. The first part, called CREATE, makes just the header:
1659 +-- Afterwards, HERE points here.
1662 +---------+---+---+---+---+---+---+---+---+
1663 | LINK | 6 | D | O | U | B | L | E | 0 |
1664 +---------+---+---+---+---+---+---+---+---+
1667 and the second part, the actual definition of : (COLON), calls CREATE and appends the
1668 DOCOL codeword, so leaving:
1670 +-- Afterwards, HERE points here.
1673 +---------+---+---+---+---+---+---+---+---+------------+
1674 | LINK | 6 | D | O | U | B | L | E | 0 | DOCOL |
1675 +---------+---+---+---+---+---+---+---+---+------------+
1678 CREATE is a standard FORTH word and the advantage of this split is that we can reuse it to
1679 create other types of words (not just ones which contain code, but words which contain variables,
1680 constants and other data).
1683 defcode "CREATE",6,,CREATE
1686 call _WORD // Returns %ecx = length, %edi = pointer to word.
1687 mov %edi,%ebx // %ebx = address of the word
1690 movl var_HERE,%edi // %edi is the address of the header
1691 movl var_LATEST,%eax // Get link pointer
1692 stosl // and store it in the header.
1694 // Length byte and the word itself.
1695 mov %cl,%al // Get the length.
1696 stosb // Store the length/flags byte.
1698 mov %ebx,%esi // %esi = word
1699 rep movsb // Copy the word
1701 addl $3,%edi // Align to next 4 byte boundary.
1704 // Update LATEST and HERE.
1706 movl %eax,var_LATEST
1711 Because I want to define : (COLON) in FORTH, not assembler, we need a few more FORTH words
1714 The first is , (COMMA) which is a standard FORTH word which appends a 32 bit integer to the user
1715 data area pointed to by HERE, and adds 4 to HERE. So the action of , (COMMA) is:
1717 previous value of HERE
1720 +---------+---+---+---+---+---+---+---+---+-- - - - - --+------------+
1721 | LINK | 6 | D | O | U | B | L | E | 0 | | <data> |
1722 +---------+---+---+---+---+---+---+---+---+-- - - - - --+------------+
1727 and <data> is whatever 32 bit integer was at the top of the stack.
1729 , (COMMA) is quite a fundamental operation when compiling. It is used to append codewords
1730 to the current word that is being compiled.
1733 defcode ",",1,,COMMA
1734 pop %eax // Code pointer to store.
1738 movl var_HERE,%edi // HERE
1740 movl %edi,var_HERE // Update HERE (incremented)
1744 Our definitions of : (COLON) and ; (SEMICOLON) will need to switch to and from compile mode.
1746 Immediate mode vs. compile mode is stored in the global variable STATE, and by updating this
1747 variable we can switch between the two modes.
1749 For various reasons which may become apparent later, FORTH defines two standard words called
1750 [ and ] (LBRAC and RBRAC) which switch between modes:
1752 Word Assembler Action Effect
1753 [ LBRAC STATE := 0 Switch to immediate mode.
1754 ] RBRAC STATE := 1 Switch to compile mode.
1756 [ (LBRAC) is an IMMEDIATE word. The reason is as follows: If we are in compile mode and the
1757 interpreter saw [ then it would compile it rather than running it. We would never be able to
1758 switch back to immediate mode! So we flag the word as IMMEDIATE so that even in compile mode
1759 the word runs immediately, switching us back to immediate mode.
1762 defcode "[",1,F_IMMED,LBRAC
1764 movl %eax,var_STATE // Set STATE to 0.
1767 defcode "]",1,,RBRAC
1768 movl $1,var_STATE // Set STATE to 1.
1772 Now we can define : (COLON) using CREATE. It just calls CREATE, appends DOCOL (the codeword), sets
1773 the word HIDDEN and goes into compile mode.
1776 defword ":",1,,COLON
1777 .int CREATE // CREATE the dictionary entry / header
1778 .int LIT, DOCOL, COMMA // Append DOCOL (the codeword).
1779 .int LATEST, FETCH, HIDDEN // Make the word hidden (see below for definition).
1780 .int RBRAC // Go into compile mode.
1781 .int EXIT // Return from the function.
1784 ; (SEMICOLON) is also elegantly simple. Notice the F_IMMED flag.
1787 defword ";",1,F_IMMED,SEMICOLON
1788 .int LIT, EXIT, COMMA // Append EXIT (so the word will return).
1789 .int LATEST, FETCH, HIDDEN // Toggle hidden flag -- unhide the word (see below for definition).
1790 .int LBRAC // Go back to IMMEDIATE mode.
1791 .int EXIT // Return from the function.
1794 EXTENDING THE COMPILER ----------------------------------------------------------------------
1796 Words flagged with IMMEDIATE (F_IMMED) aren't just for the FORTH compiler to use. You can define
1797 your own IMMEDIATE words too, and this is a crucial aspect when extending basic FORTH, because
1798 it allows you in effect to extend the compiler itself. Does gcc let you do that?
1800 Standard FORTH words like IF, WHILE, ." and so on are all written as extensions to the basic
1801 compiler, and are all IMMEDIATE words.
1803 The IMMEDIATE word toggles the F_IMMED (IMMEDIATE flag) on the most recently defined word,
1804 or on the current word if you call it in the middle of a definition.
1808 : MYIMMEDWORD IMMEDIATE
1812 but some FORTH programmers write this instead:
1818 The two usages are equivalent, to a first approximation.
1821 defcode "IMMEDIATE",9,F_IMMED,IMMEDIATE
1822 movl var_LATEST,%edi // LATEST word.
1823 addl $4,%edi // Point to name/flags byte.
1824 xorb $F_IMMED,(%edi) // Toggle the IMMED bit.
1828 'addr HIDDEN' toggles the hidden flag (F_HIDDEN) of the word defined at addr. To hide the
1829 most recently defined word (used above in : and ; definitions) you would do:
1833 Setting this flag stops the word from being found by FIND, and so can be used to make 'private'
1834 words. For example, to break up a large word into smaller parts you might do:
1836 : SUB1 ... subword ... ;
1837 : SUB2 ... subword ... ;
1838 : SUB3 ... subword ... ;
1839 : MAIN ... defined in terms of SUB1, SUB2, SUB3 ... ;
1840 WORD SUB1 FIND HIDDEN \ Hide SUB1
1841 WORD SUB2 FIND HIDDEN \ Hide SUB2
1842 WORD SUB3 FIND HIDDEN \ Hide SUB3
1844 After this, only MAIN is 'exported' or seen by the rest of the program.
1847 defcode "HIDDEN",6,,HIDDEN
1848 pop %edi // Dictionary entry.
1849 addl $4,%edi // Point to name/flags byte.
1850 xorb $F_HIDDEN,(%edi) // Toggle the HIDDEN bit.
1854 ' (TICK) is a standard FORTH word which returns the codeword pointer of the next word.
1856 The common usage is:
1860 which appends the codeword of FOO to the current word we are defining (this only works in compiled code).
1862 You tend to use ' in IMMEDIATE words. For example an alternate (and rather useless) way to define
1863 a literal 2 might be:
1866 ' LIT , \ Appends LIT to the currently-being-defined word
1867 2 , \ Appends the number 2 to the currently-being-defined word
1874 (If you don't understand how LIT2 works, then you should review the material about compiling words
1875 and immediate mode).
1877 This definition of ' uses a cheat which I copied from buzzard92. As a result it only works in
1878 compiled code. It is possible to write a version of ' based on WORD, FIND, >CFA which works in
1882 lodsl // Get the address of the next word and skip it.
1883 pushl %eax // Push it on the stack.
1887 BRANCHING ----------------------------------------------------------------------
1889 It turns out that all you need in order to define looping constructs, IF-statements, etc.
1892 BRANCH is an unconditional branch. 0BRANCH is a conditional branch (it only branches if the
1893 top of stack is zero).
1895 The diagram below shows how BRANCH works in some imaginary compiled word. When BRANCH executes,
1896 %esi starts by pointing to the offset field (compare to LIT above):
1898 +---------------------+-------+---- - - ---+------------+------------+---- - - - ----+------------+
1899 | (Dictionary header) | DOCOL | | BRANCH | offset | (skipped) | word |
1900 +---------------------+-------+---- - - ---+------------+-----|------+---- - - - ----+------------+
1903 | +-----------------------+
1904 %esi added to offset
1906 The offset is added to %esi to make the new %esi, and the result is that when NEXT runs, execution
1907 continues at the branch target. Negative offsets work as expected.
1909 0BRANCH is the same except the branch happens conditionally.
1911 Now standard FORTH words such as IF, THEN, ELSE, WHILE, REPEAT, etc. can be implemented entirely
1912 in FORTH. They are IMMEDIATE words which append various combinations of BRANCH or 0BRANCH
1913 into the word currently being compiled.
1915 As an example, code written like this:
1917 condition-code IF true-part THEN rest-code
1921 condition-code 0BRANCH OFFSET true-part rest-code
1927 defcode "BRANCH",6,,BRANCH
1928 add (%esi),%esi // add the offset to the instruction pointer
1931 defcode "0BRANCH",7,,ZBRANCH
1933 test %eax,%eax // top of stack is zero?
1934 jz code_BRANCH // if so, jump back to the branch function above
1935 lodsl // otherwise we need to skip the offset
1939 PRINTING STRINGS ----------------------------------------------------------------------
1941 LITSTRING and EMITSTRING are primitives used to implement the ." and S" operators
1942 (which are written in FORTH). See the definition of those operators below.
1945 defcode "LITSTRING",9,,LITSTRING
1946 lodsl // get the length of the string
1947 push %eax // push it on the stack
1948 push %esi // push the address of the start of the string
1949 addl %eax,%esi // skip past the string
1950 addl $3,%esi // but round up to next 4 byte boundary
1954 defcode "EMITSTRING",10,,EMITSTRING
1955 mov $1,%ebx // 1st param: stdout
1956 pop %ecx // 2nd param: address of string
1957 pop %edx // 3rd param: length of string
1958 mov $__NR_write,%eax // write syscall
1963 COLD START AND INTERPRETER ----------------------------------------------------------------------
1965 COLD is the first FORTH function called, almost immediately after the FORTH system "boots".
1967 INTERPRETER is the FORTH interpreter ("toploop", "toplevel" or "REPL" might be a more accurate
1968 description -- see: http://en.wikipedia.org/wiki/REPL).
1971 // COLD must not return (ie. must not call EXIT).
1972 defword "COLD",4,,COLD
1973 .int INTERPRETER // call the interpreter loop (never returns)
1974 .int LIT,1,SYSEXIT // hmmm, but in case it does, exit(1).
1976 /* This interpreter is pretty simple, but remember that in FORTH you can always override
1977 * it later with a more powerful one!
1979 defword "INTERPRETER",11,,INTERPRETER
1980 .int INTERPRET,RDROP,INTERPRETER
1982 defcode "INTERPRET",9,,INTERPRET
1983 call _WORD // Returns %ecx = length, %edi = pointer to word.
1985 // Is it in the dictionary?
1987 movl %eax,interpret_is_lit // Not a literal number (not yet anyway ...)
1988 call _FIND // Returns %eax = pointer to header or 0 if not found.
1989 test %eax,%eax // Found?
1992 // In the dictionary. Is it an IMMEDIATE codeword?
1993 mov %eax,%edi // %edi = dictionary entry
1994 movb 4(%edi),%al // Get name+flags.
1995 push %ax // Just save it for now.
1996 call _TCFA // Convert dictionary entry (in %edi) to codeword pointer.
1998 andb $F_IMMED,%al // Is IMMED flag set?
2000 jnz 4f // If IMMED, jump straight to executing.
2004 1: // Not in the dictionary (not a word) so assume it's a literal number.
2005 incl interpret_is_lit
2006 call _SNUMBER // Returns the parsed number in %eax
2008 mov $LIT,%eax // The word is LIT
2010 2: // Are we compiling or executing?
2013 jz 4f // Jump if executing.
2015 // Compiling - just append the word to the current dictionary definition.
2017 mov interpret_is_lit,%ecx // Was it a literal?
2020 mov %ebx,%eax // Yes, so LIT is followed by a number.
2024 4: // Executing - run it!
2025 mov interpret_is_lit,%ecx // Literal?
2026 test %ecx,%ecx // Literal?
2029 // Not a literal, execute it now. This never returns, but the codeword will
2030 // eventually call NEXT which will reenter the loop in INTERPRETER.
2033 5: // Executing a literal, which means push it on the stack.
2040 .int 0 // Flag used to record if reading a literal
2043 ODDS AND ENDS ----------------------------------------------------------------------
2045 CHAR puts the ASCII code of the first character of the following word on the stack. For example
2046 CHAR A puts 65 on the stack.
2048 SYSEXIT exits the process using Linux exit syscall.
2050 In this FORTH, SYSEXIT must be the last word in the built-in (assembler) dictionary because we
2051 initialise the LATEST variable to point to it. This means that if you want to extend the assembler
2052 part, you must put new words before SYSEXIT, or else change how LATEST is initialised.
2055 defcode "CHAR",4,,CHAR
2056 call _WORD // Returns %ecx = length, %edi = pointer to word.
2058 movb (%edi),%al // Get the first character of the word.
2059 push %eax // Push it onto the stack.
2062 // NB: SYSEXIT must be the last entry in the built-in dictionary.
2063 defcode SYSEXIT,7,,SYSEXIT
2069 START OF FORTH CODE ----------------------------------------------------------------------
2071 We've now reached the stage where the FORTH system is running and self-hosting. All further
2072 words can be written as FORTH itself, including words like IF, THEN, .", etc which in most
2073 languages would be considered rather fundamental.
2075 As a kind of trick, I prefill the input buffer with the initial FORTH code. Once this code
2076 has run (when we get to the "OK" prompt), this input buffer is reused for reading any further
2079 Some notes about the code:
2081 \ (backslash) is the FORTH way to start a comment which goes up to the next newline. However
2082 because this is a C-style string, I have to escape the backslash, which is why they appear as
2085 Similarly, any backslashes in the code are doubled, and " becomes \" (eg. the definition of ."
2086 is written as : .\" ... ;)
2088 I use indenting to show structure. The amount of whitespace has no meaning to FORTH however
2089 except that you must use at least one whitespace character between words, and words themselves
2090 cannot contain whitespace.
2092 FORTH is case-sensitive. Use capslock!
2100 // Multi-line constant gives 'Warning: unterminated string; newline inserted' messages which you can ignore.
2102 \\ Define some character constants
2106 \\ CR prints a carriage return
2109 \\ SPACE prints a space
2110 : SPACE 'SPACE' EMIT ;
2112 \\ DUP, DROP are defined in assembly for speed, but this is how you might define them
2113 \\ in FORTH. Notice use of the scratch variables _X and _Y.
2114 \\ : DUP _X ! _X @ _X @ ;
2117 \\ The built-in . (DOT) function doesn't print a space after the number (unlike the real FORTH word).
2118 \\ However this is very easily fixed by redefining . (DOT). Any built-in word can be redefined.
2120 . \\ this refers back to the previous definition (but see also RECURSE below)
2124 \\ The 2... versions of the standard operators work on pairs of stack entries. They're not used
2125 \\ very commonly so not really worth writing in assembler. Here is how they are defined in FORTH.
2129 \\ More standard FORTH words.
2133 \\ Standard words for manipulating BASE.
2134 : DECIMAL 10 BASE ! ;
2137 \\ Standard words for booleans.
2142 \\ LITERAL takes whatever is on the stack and compiles LIT <foo>
2144 ' LIT , \\ compile LIT
2145 , \\ compile the literal itself (from the stack)
2148 \\ Now we can use [ and ] to insert literals which are calculated at compile time.
2149 \\ Within definitions, use [ ... ] LITERAL anywhere that '...' is a constant expression which you
2150 \\ would rather only compute once (at compile time, rather than calculating it each time your word runs).
2152 [ \\ go into immediate mode temporarily
2153 CHAR : \\ push the number 58 (ASCII code of colon) on the stack
2154 ] \\ go back to compile mode
2155 LITERAL \\ compile LIT 58 as the definition of ':' word
2158 \\ A few more character constants defined the same way as above.
2159 : '(' [ CHAR ( ] LITERAL ;
2160 : ')' [ CHAR ) ] LITERAL ;
2161 : '\"' [ CHAR \" ] LITERAL ;
2163 \\ So far we have defined only very simple definitions. Before we can go further, we really need to
2164 \\ make some control structures, like IF ... THEN and loops. Luckily we can define arbitrary control
2165 \\ structures directly in FORTH.
2167 \\ Please note that the control structures as I have defined them here will only work inside compiled
2168 \\ words. If you try to type in expressions using IF, etc. in immediate mode, then they won't work.
2169 \\ Making these work in immediate mode is left as an exercise for the reader.
2171 \\ condition IF true-part THEN rest
2172 \\ -- compiles to: --> condition 0BRANCH OFFSET true-part rest
2173 \\ where OFFSET is the offset of 'rest'
2174 \\ condition IF true-part ELSE false-part THEN
2175 \\ -- compiles to: --> condition 0BRANCH OFFSET true-part BRANCH OFFSET2 false-part rest
2176 \\ where OFFSET if the offset of false-part and OFFSET2 is the offset of rest
2178 \\ IF is an IMMEDIATE word which compiles 0BRANCH followed by a dummy offset, and places
2179 \\ the address of the 0BRANCH on the stack. Later when we see THEN, we pop that address
2180 \\ off the stack, calculate the offset, and back-fill the offset.
2182 ' 0BRANCH , \\ compile 0BRANCH
2183 HERE @ \\ save location of the offset on the stack
2184 0 , \\ compile a dummy offset
2189 HERE @ SWAP - \\ calculate the offset from the address saved on the stack
2190 SWAP ! \\ store the offset in the back-filled location
2194 ' BRANCH , \\ definite branch to just over the false-part
2195 HERE @ \\ save location of the offset on the stack
2196 0 , \\ compile a dummy offset
2197 SWAP \\ now back-fill the original (IF) offset
2198 DUP \\ same as for THEN word above
2203 \\ BEGIN loop-part condition UNTIL
2204 \\ -- compiles to: --> loop-part condition 0BRANCH OFFSET
2205 \\ where OFFSET points back to the loop-part
2206 \\ This is like do { loop-part } while (condition) in the C language
2208 HERE @ \\ save location on the stack
2212 ' 0BRANCH , \\ compile 0BRANCH
2213 HERE @ - \\ calculate the offset from the address saved on the stack
2214 , \\ compile the offset here
2217 \\ BEGIN loop-part AGAIN
2218 \\ -- compiles to: --> loop-part BRANCH OFFSET
2219 \\ where OFFSET points back to the loop-part
2220 \\ In other words, an infinite loop which can only be returned from with EXIT
2222 ' BRANCH , \\ compile BRANCH
2223 HERE @ - \\ calculate the offset back
2224 , \\ compile the offset here
2227 \\ BEGIN condition WHILE loop-part REPEAT
2228 \\ -- compiles to: --> condition 0BRANCH OFFSET2 loop-part BRANCH OFFSET
2229 \\ where OFFSET points back to condition (the beginning) and OFFSET2 points to after the whole piece of code
2230 \\ So this is like a while (condition) { loop-part } loop in the C language
2232 ' 0BRANCH , \\ compile 0BRANCH
2233 HERE @ \\ save location of the offset2 on the stack
2234 0 , \\ compile a dummy offset2
2238 ' BRANCH , \\ compile BRANCH
2239 SWAP \\ get the original offset (from BEGIN)
2240 HERE @ - , \\ and compile it after BRANCH
2242 HERE @ SWAP - \\ calculate the offset2
2243 SWAP ! \\ and back-fill it in the original location
2246 \\ FORTH allows ( ... ) as comments within function definitions. This works by having an IMMEDIATE
2247 \\ word called ( which just drops input characters until it hits the corresponding ).
2249 1 \\ allowed nested parens by keeping track of depth
2251 KEY \\ read next character
2252 DUP '(' = IF \\ open paren?
2253 DROP \\ drop the open paren
2254 1+ \\ depth increases
2256 ')' = IF \\ close paren?
2257 1- \\ depth decreases
2260 DUP 0= UNTIL \\ continue until we reach matching close paren, depth 0
2261 DROP \\ drop the depth counter
2265 From now on we can use ( ... ) for comments.
2267 In FORTH style we can also use ( ... -- ... ) to show the effects that a word has on the
2268 parameter stack. For example:
2270 ( n -- ) means that the word consumes an integer (n) from the parameter stack.
2271 ( b a -- c ) means that the word uses two integers (a and b, where a is at the top of stack)
2272 and returns a single integer (c).
2273 ( -- ) means the word has no effect on the stack
2276 ( With the looping constructs, we can now write SPACES, which writes n spaces to stdout. )
2279 DUP 0> ( while n > 0 )
2281 SPACE ( print a space )
2282 1- ( until we count down to 0 )
2287 ( c a b WITHIN returns true if a <= c and c < b )
2303 ( .S prints the contents of the stack. Very useful for debugging. )
2305 DSP@ ( get current stack pointer )
2309 DUP @ . ( print the stack element )
2315 ( DEPTH returns the depth of the stack. )
2318 4- ( adjust because S0 was on the stack when we pushed DSP )
2322 [NB. The following may be a bit confusing because of the need to use backslash before
2323 each double quote character. The backslashes are there to keep the assembler happy.
2324 They are NOT part of the final output. So here we are defining a function called
2325 'S double-quote' (not 'S backslash double-quote').]
2327 S\" string\" is used in FORTH to define strings. It leaves the address of the string and
2328 its length on the stack with the address at the top.
2330 In compile mode we append
2331 LITSTRING <string length> <string rounded up 4 bytes>
2332 to the current word. The primitive LITSTRING does the right thing when the current
2335 In immediate mode there isn't a particularly good place to put the string, but in this
2336 case we put the string at HERE (but we _don't_ change HERE). This is meant as a temporary
2337 location, likely to be overwritten soon after.
2339 : S\" IMMEDIATE ( -- len addr )
2340 STATE @ IF ( compiling? )
2341 ' LITSTRING , ( compile LITSTRING )
2342 HERE @ ( save the address of the length word on the stack )
2343 0 , ( dummy length - we don't know what it is yet )
2345 KEY ( get next character of the string )
2348 HERE @ !b ( store the character in the compiled image )
2349 1 HERE +! ( increment HERE pointer by 1 byte )
2351 DROP ( drop the double quote character at the end )
2352 DUP ( get the saved address of the length word )
2353 HERE @ SWAP - ( calculate the length )
2354 4- ( subtract 4 (because we measured from the start of the length word) )
2355 SWAP ! ( and back-fill the length location )
2356 HERE @ ( round up to next multiple of 4 bytes for the remaining code )
2360 ELSE ( immediate mode )
2361 HERE @ ( get the start address of the temporary space )
2366 OVER !b ( save next character )
2367 1+ ( increment address )
2369 HERE @ - ( calculate the length )
2370 HERE @ ( push the start address )
2375 .\" is the print string operator in FORTH. Example: .\" Something to print\"
2376 The space after the operator is the ordinary space required between words.
2378 This is tricky to define because it has to do different things depending on whether
2379 we are compiling or in immediate mode. (Thus the word is marked IMMEDIATE so it can
2380 detect this and do different things).
2382 In immediate mode we just keep reading characters and printing them until we get to
2383 the next double quote.
2385 In compile mode we have the problem of where we're going to store the string (remember
2386 that the input buffer where the string comes from may be overwritten by the time we
2387 come round to running the function). We store the string in the compiled function
2389 ..., LITSTRING, string length, string rounded up to 4 bytes, EMITSTRING, ...
2391 : .\" IMMEDIATE ( -- )
2392 STATE @ IF ( compiling? )
2393 ' LITSTRING , ( compile LITSTRING )
2394 HERE @ ( save the address of the length word on the stack )
2395 0 , ( dummy length - we don't know what it is yet )
2397 KEY ( get next character of the string )
2400 HERE @ !b ( store the character in the compiled image )
2401 1 HERE +! ( increment HERE pointer by 1 byte )
2403 DROP ( drop the double quote character at the end )
2404 DUP ( get the saved address of the length word )
2405 HERE @ SWAP - ( calculate the length )
2406 4- ( subtract 4 (because we measured from the start of the length word) )
2407 SWAP ! ( and back-fill the length location )
2408 HERE @ ( round up to next multiple of 4 bytes for the remaining code )
2412 ' EMITSTRING , ( compile the final EMITSTRING )
2414 ( In immediate mode, just read characters and print them until we get
2415 to the ending double quote. Much simpler than the above code! )
2419 DROP ( drop the double quote character )
2420 EXIT ( return from this function )
2428 In FORTH, global constants and variables are defined like this:
2430 10 CONSTANT TEN when TEN is executed, it leaves the integer 10 on the stack
2431 VARIABLE VAR when VAR is executed, it leaves the address of VAR on the stack
2433 Constants can be read by not written, eg:
2437 You can read a variable (in this example called VAR) by doing:
2439 VAR @ leaves the value of VAR on the stack
2440 VAR @ . CR prints the value of VAR
2442 and update the variable by doing:
2444 20 VAR ! sets VAR to 20
2446 Note that variables are uninitialised (but see VALUE later on which provides initialised
2447 variables with a slightly simpler syntax).
2449 How can we define the words CONSTANT and VARIABLE?
2451 The trick is to define a new word for the variable itself (eg. if the variable was called
2452 'VAR' then we would define a new word called VAR). This is easy to do because we exposed
2453 dictionary entry creation through the CREATE word (part of the definition of : above).
2454 A call to CREATE TEN leaves the dictionary entry:
2459 +---------+---+---+---+---+
2460 | LINK | 3 | T | E | N |
2461 +---------+---+---+---+---+
2464 For CONSTANT we can continue by appending DOCOL (the codeword), then LIT followed by
2465 the constant itself and then EXIT, forming a little word definition that returns the
2468 +---------+---+---+---+---+------------+------------+------------+------------+
2469 | LINK | 3 | T | E | N | DOCOL | LIT | 10 | EXIT |
2470 +---------+---+---+---+---+------------+------------+------------+------------+
2473 Notice that this word definition is exactly the same as you would have got if you had
2477 CREATE ( make the dictionary entry (the name follows CONSTANT) )
2478 DOCOL , ( append DOCOL (the codeword field of this word) )
2479 ' LIT , ( append the codeword LIT )
2480 , ( append the value on the top of the stack )
2481 ' EXIT , ( append the codeword EXIT )
2485 VARIABLE is a little bit harder because we need somewhere to put the variable. There is
2486 nothing particularly special about the 'user definitions area' (the area of memory pointed
2487 to by HERE where we have previously just stored new word definitions). We can slice off
2488 bits of this memory area to store anything we want, so one possible definition of
2489 VARIABLE might create this:
2491 +--------------------------------------------------------------+
2494 +---------+---------+---+---+---+---+------------+------------+---|--------+------------+
2495 | <var> | LINK | 3 | V | A | R | DOCOL | LIT | <addr var> | EXIT |
2496 +---------+---------+---+---+---+---+------------+------------+------------+------------+
2499 where <var> is the place to store the variable, and <addr var> points back to it.
2501 To make this more general let's define a couple of words which we can use to allocate
2502 arbitrary memory from the user definitions area.
2504 First ALLOT, where n ALLOT allocates n bytes of memory. (Note when calling this that
2505 it's a very good idea to make sure that n is a multiple of 4, or at least that next time
2506 a word is compiled that n has been left as a multiple of 4).
2508 : ALLOT ( n -- addr )
2509 HERE @ SWAP ( here n -- )
2510 HERE +! ( adds n to HERE, after this the old value of HERE is still on the stack )
2514 Second, CELLS. In FORTH the phrase 'n CELLS ALLOT' means allocate n integers of whatever size
2515 is the natural size for integers on this machine architecture. On this 32 bit machine therefore
2516 CELLS just multiplies the top of stack by 4.
2518 : CELLS ( n -- n ) 4 * ;
2521 So now we can define VARIABLE easily in much the same way as CONSTANT above. Refer to the
2522 diagram above to see what the word that this creates will look like.
2525 1 CELLS ALLOT ( allocate 1 cell of memory, push the pointer to this memory )
2526 CREATE ( make the dictionary entry (the name follows VARIABLE) )
2527 DOCOL , ( append DOCOL (the codeword field of this word) )
2528 ' LIT , ( append the codeword LIT )
2529 , ( append the pointer to the new memory )
2530 ' EXIT , ( append the codeword EXIT )
2534 VALUEs are like VARIABLEs but with a simpler syntax. You would generally use them when you
2535 want a variable which is read often, and written infrequently.
2537 20 VALUE VAL creates VAL with initial value 20
2538 VAL pushes the value directly on the stack
2539 30 TO VAL updates VAL, setting it to 30
2541 Notice that 'VAL' on its own doesn't return the address of the value, but the value itself,
2542 making values simpler and more obvious to use than variables (no indirection through '@').
2543 The price is a more complicated implementation, although despite the complexity there is no
2544 particular performance penalty at runtime.
2546 A naive implementation of 'TO' would be quite slow, involving a dictionary search each time.
2547 But because this is FORTH we have complete control of the compiler so we can compile TO more
2548 efficiently, turning:
2552 and calculating <addr> (the address of the value) at compile time.
2554 Now this is the clever bit. We'll compile our value like this:
2556 +---------+---+---+---+---+------------+------------+------------+------------+
2557 | LINK | 3 | V | A | L | DOCOL | LIT | <value> | EXIT |
2558 +---------+---+---+---+---+------------+------------+------------+------------+
2561 where <value> is the actual value itself. Note that when VAL executes, it will push the
2562 value on the stack, which is what we want.
2564 But what will TO use for the address <addr>? Why of course a pointer to that <value>:
2566 code compiled - - - - --+------------+------------+------------+-- - - - -
2567 by TO VAL | LIT | <addr> | ! |
2568 - - - - --+------------+-----|------+------------+-- - - - -
2571 +---------+---+---+---+---+------------+------------+------------+------------+
2572 | LINK | 3 | V | A | L | DOCOL | LIT | <value> | EXIT |
2573 +---------+---+---+---+---+------------+------------+------------+------------+
2576 In other words, this is a kind of self-modifying code.
2578 (Note to the people who want to modify this FORTH to add inlining: values defined this
2579 way cannot be inlined).
2582 CREATE ( make the dictionary entry (the name follows VALUE) )
2583 DOCOL , ( append DOCOL )
2584 ' LIT , ( append the codeword LIT )
2585 , ( append the initial value )
2586 ' EXIT , ( append the codeword EXIT )
2589 : TO IMMEDIATE ( n -- )
2590 WORD ( get the name of the value )
2591 FIND ( look it up in the dictionary )
2592 >DFA ( get a pointer to the first data field (the 'LIT') )
2593 4+ ( increment to point at the value )
2594 STATE @ IF ( compiling? )
2595 ' LIT , ( compile LIT )
2596 , ( compile the address of the value )
2598 ELSE ( immediate mode )
2599 ! ( update it straightaway )
2603 ( x +TO VAL adds x to VAL )
2605 WORD ( get the name of the value )
2606 FIND ( look it up in the dictionary )
2607 >DFA ( get a pointer to the first data field (the 'LIT') )
2608 4+ ( increment to point at the value )
2609 STATE @ IF ( compiling? )
2610 ' LIT , ( compile LIT )
2611 , ( compile the address of the value )
2612 ' +! , ( compile +! )
2613 ELSE ( immediate mode )
2614 +! ( update it straightaway )
2619 ID. takes an address of a dictionary entry and prints the word's name.
2621 For example: LATEST @ ID. would print the name of the last word that was defined.
2624 4+ ( skip over the link pointer )
2625 DUP @b ( get the flags/length byte )
2626 F_LENMASK AND ( mask out the flags - just want the length )
2629 DUP 0> ( length > 0? )
2631 SWAP 1+ ( addr len -- len addr+1 )
2632 DUP @b ( len addr -- len addr char | get the next character)
2633 EMIT ( len addr char -- len addr | and print it)
2634 SWAP 1- ( len addr -- addr len-1 | subtract one from length )
2636 2DROP ( len addr -- )
2640 'WORD word FIND ?HIDDEN' returns true if 'word' is flagged as hidden.
2642 'WORD word FIND ?IMMEDIATE' returns true if 'word' is flagged as immediate.
2645 4+ ( skip over the link pointer )
2646 @b ( get the flags/length byte )
2647 F_HIDDEN AND ( mask the F_HIDDEN flag and return it (as a truth value) )
2650 4+ ( skip over the link pointer )
2651 @b ( get the flags/length byte )
2652 F_IMMED AND ( mask the F_IMMED flag and return it (as a truth value) )
2656 WORDS prints all the words defined in the dictionary, starting with the word defined most recently.
2657 However it doesn't print hidden words.
2659 The implementation simply iterates backwards from LATEST using the link pointers.
2662 LATEST @ ( start at LATEST dictionary entry )
2664 DUP 0<> ( while link pointer is not null )
2667 DUP ID. ( print the word )
2670 @ ( dereference the link pointer - go to previous word )
2677 So far we have only allocated words and memory. FORTH provides a rather primitive method
2680 'FORGET word' deletes the definition of 'word' from the dictionary and everything defined
2681 after it, including any variables and other memory allocated after.
2683 The implementation is very simple - we look up the word (which returns the dictionary entry
2684 address). Then we set HERE to point to that address, so in effect all future allocations
2685 and definitions will overwrite memory starting at the word. We also need to set LATEST to
2686 point to the previous word.
2688 Note that you cannot FORGET built-in words (well, you can try but it will probably cause
2691 XXX: Because we wrote VARIABLE to store the variable in memory allocated before the word,
2692 in the current implementation VARIABLE FOO FORGET FOO will leak 1 cell of memory.
2695 WORD FIND ( find the word, gets the dictionary entry address )
2696 DUP @ LATEST ! ( set LATEST to point to the previous word )
2697 HERE ! ( and store HERE with the dictionary address )
2701 While compiling, '[COMPILE] word' compiles 'word' if it would otherwise be IMMEDIATE.
2703 : [COMPILE] IMMEDIATE
2704 WORD ( get the next word )
2705 FIND ( find it in the dictionary )
2706 >CFA ( get its codeword )
2707 , ( and compile that )
2711 RECURSE makes a recursive call to the current word that is being compiled.
2713 Normally while a word is being compiled, it is marked HIDDEN so that references to the
2714 same word within are calls to the previous definition of the word. However we still have
2715 access to the word which we are currently compiling through the LATEST pointer so we
2716 can use that to compile a recursive call.
2719 LATEST @ >CFA ( LATEST points to the word being compiled at the moment )
2724 DUMP is used to dump out the contents of memory, in the 'traditional' hexdump format.
2726 : DUMP ( addr len -- )
2727 BASE @ ROT ( save the current BASE at the bottom of the stack )
2728 HEX ( and switch the hexadecimal mode )
2731 DUP 0> ( while len > 0 )
2733 OVER . ( print the address )
2736 ( print up to 16 words on this line )
2737 2DUP ( addr len addr len )
2738 1- 15 AND 1+ ( addr len addr linelen )
2740 DUP 0> ( while linelen > 0 )
2742 SWAP ( addr len linelen addr )
2743 DUP @b ( addr len linelen addr byte )
2744 . SPACE ( print the byte )
2745 1+ SWAP 1- ( addr len linelen addr -- addr len addr+1 linelen-1 )
2749 ( print the ASCII equivalents )
2750 2DUP 1- 15 AND 1+ ( addr len addr linelen )
2752 DUP 0> ( while linelen > 0)
2754 SWAP ( addr len linelen addr )
2755 DUP @b ( addr len linelen addr byte )
2756 DUP 32 128 WITHIN IF ( 32 <= c < 128? )
2759 DROP [ CHAR ? ] LITERAL EMIT
2761 1+ SWAP 1- ( addr len linelen addr -- addr len addr+1 linelen-1 )
2766 DUP 1- 15 AND 1+ ( addr len linelen )
2767 DUP ( addr len linelen linelen )
2768 ROT ( addr linelen len linelen )
2769 - ( addr linelen len-linelen )
2770 ROT ( len-linelen addr linelen )
2771 + ( len-linelen addr+linelen )
2772 SWAP ( addr-linelen len-linelen )
2775 2DROP ( restore stack )
2776 BASE ! ( restore saved BASE )
2779 ( Finally print the welcome prompt. )
2780 .\" JONESFORTH VERSION \" VERSION . CR
2793 /* END OF jonesforth.S */
git.annexia.org / jonesforth.git / blob